[gentoo-commits] repo/gentoo:master commit in: media-plugins/audacious-plugins/, media-plugins/audacious-plugins/files/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a3702a269470f337543c71211f788fc39bd989ec
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 24 23:41:05 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Nov 24 23:43:33 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a3702a26

media-plugins/audacious-plugins: Revert drop 3.9

Required by media-libs/freeverb3[audacious].
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-plugins/audacious-plugins/Manifest           |   2 +
 .../audacious-plugins-3.9-r1.ebuild                | 180 +++++++++++++++++++++
 .../files/audacious-plugins-3.9-qt-5.10.patch      |  26 +++
 media-plugins/audacious-plugins/metadata.xml       |   3 +
 4 files changed, 211 insertions(+)

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index 740575e95ad..607c7195c5e 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1 +1,3 @@
 DIST audacious-plugins-3.10.tar.bz2 1701877 BLAKE2B 4db7351af494ff5b7d2a7968524e2480f321505759f4a6532dd86f8fd87f43ab0a66e9f1fc75cfcbc8c59d35c1071048b61a8452fa6e041cd1667872f5b5699e SHA512 88dd93b5a7f6582ec42cf539d1000de0900cce683f4de85d8a17f57c7ba34545c6277882cad1505cb6682ee7b885ffcd1fe5675f7e24dc3e2a650615789d9d52
+DIST audacious-plugins-3.9-gtk3.tar.bz2 1842950 BLAKE2B 55f373be204a9b4c9cff41d41d43c4776f680ab203643e90e5d338bec2e7f8a4c60cda9caa08e461089a475f3ec1bc237538f781718eb0d26a4365743337e977 SHA512 e2529af761bc97e589cac08689b16db657096b1bbfcc802789726ae1b472746025bec1b492de52eef755d7b50574d09b9250761bf701b1ca37f8a0e8db0f207b
+DIST audacious-plugins-3.9.tar.bz2 1843084 BLAKE2B fa3a8433a869a2df0589f59e12513adcc0da0545b53ee441db4b18be7e12334b4125bd60b48902c37041041555859ab19df814c483f7d971214077e9980148b6 SHA512 00c8c53d69995ca1fedb91c7df609cc6c65b13e1af23b98a2fbda143c02ac554cc2c42c01f1c593af252e36bfb85b6324f2daca8632d3b672c69fb4dead2e3fa

diff --git a/media-plugins/audacious-plugins/audacious-plugins-3.9-r1.ebuild b/media-plugins/audacious-plugins/audacious-plugins-3.9-r1.ebuild
new file mode 100644
index 00000000000..21da7bb77a8
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-3.9-r1.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="https://audacious-media-player.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
+else
+	SRC_URI="
+		!gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+		gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac +adplug alsa ampache aosd bs2b cdda cue ffmpeg flac fluidsynth gnome hotkeys http gme gtk gtk3 jack lame libav
+	libnotify libsamplerate lirc mms modplug mp3 nls pulseaudio qt5 scrobbler sdl sid sndfile soxr speedpitch vorbis wavpack"
+REQUIRED_USE="
+	^^ ( gtk gtk3 qt5 )
+	qt5? ( !libnotify )
+	|| ( alsa jack pulseaudio sdl )
+	ampache? ( qt5 http )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+RDEPEND="
+	app-arch/unzip
+	dev-libs/dbus-glib
+	dev-libs/glib
+	dev-libs/libxml2:2
+	~media-sound/audacious-${PV}[gtk?,gtk3?,qt5?]
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1* )
+	aosd? (
+		x11-libs/libXrender
+		x11-libs/libXcomposite
+	)
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		>=media-libs/libcddb-1.2.1
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+	flac? (
+		>=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.2.1-r1
+	)
+	fluidsynth? ( media-sound/fluidsynth )
+	http? ( >=net-libs/neon-0.26.4 )
+	gtk? ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtwidgets:5
+		media-libs/adplug
+	)
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl2[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	vorbis? (
+		>=media-libs/libvorbis-1.2.0
+		>=media-libs/libogg-1.1.3
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"
+
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/${P}-qt-5.10.patch" )
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]]; then
+		git-r3_src_unpack
+	else
+		default
+		if use gtk3; then
+			mv "${MY_P}"{-gtk3,} || die
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	if ! use mp3 ; then
+		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+	fi
+
+	econf \
+		--enable-mpris2 \
+		--enable-songchange \
+		--disable-oss4 \
+		--disable-qtaudio \
+		--disable-qtglspectrum \
+		--disable-coreaudio \
+		--disable-sndio \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable ampache) \
+		$(use_enable aosd) \
+		$(use_enable bs2b) \
+		$(use_enable cdda cdaudio) \
+		$(use_enable cue) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth amidiplug) \
+		$(use_enable flac filewriter) \
+		$(use_enable gme console) \
+		$(use_enable $(usex gtk gtk gtk3) gtk) \
+		$(use_enable hotkeys hotkey) \
+		$(use_enable http neon) \
+		$(use_enable jack) \
+		$(use_enable gnome gnomeshortcuts) \
+		$(use_enable lame filewriter_mp3) \
+		$(use_enable libnotify notify) \
+		$(use_enable libsamplerate resample) \
+		$(use_enable lirc) \
+		$(use_enable mms) \
+		$(use_enable modplug) \
+		$(use_enable mp3 mpg123) \
+		$(use_enable nls) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable qt5 qt) \
+		$(use_enable scrobbler scrobbler2) \
+		$(use_enable sdl sdlout) \
+		$(use_enable sid) \
+		$(use_enable sndfile) \
+		$(use_enable soxr) \
+		$(use_enable speedpitch) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack) \
+		$(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
+}

diff --git a/media-plugins/audacious-plugins/files/audacious-plugins-3.9-qt-5.10.patch b/media-plugins/audacious-plugins/files/audacious-plugins-3.9-qt-5.10.patch
new file mode 100644
index 00000000000..64122bf9198
--- /dev/null
+++ b/media-plugins/audacious-plugins/files/audacious-plugins-3.9-qt-5.10.patch
@@ -0,0 +1,26 @@
+From 971f7ff7c3d8a0b9b420bf4fd19ab97755607637 Mon Sep 17 00:00:00 2001
+From: ilovezfs <ilovezfs@icloud.com>
+Date: Mon, 11 Dec 2017 00:17:26 -0800
+Subject: [PATCH] qtui: fix build with Qt 5.10
+
+Fixes "info_bar.cc:258:21: error: no viable overloaded '='"
+---
+ src/qtui/info_bar.cc | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/src/qtui/info_bar.cc b/src/qtui/info_bar.cc
+index 2789f93c5..eb29ef78e 100644
+--- a/src/qtui/info_bar.cc
++++ b/src/qtui/info_bar.cc
+@@ -257,8 +257,8 @@ void InfoBar::paintEvent (QPaintEvent *)
+         if (d.title.text ().isNull () && ! d.orig_title.isNull ())
+         {
+             QFontMetrics metrics = p.fontMetrics ();
+-            d.title = metrics.elidedText (d.orig_title, Qt::ElideRight,
+-             width () - ps.VisWidth - ps.Height - ps.Spacing);
++            d.title = QStaticText(metrics.elidedText (d.orig_title, Qt::ElideRight,
++             width () - ps.VisWidth - ps.Height - ps.Spacing));
+         }
+ 
+         p.setPen (QColor (255, 255, 255));
+

diff --git a/media-plugins/audacious-plugins/metadata.xml b/media-plugins/audacious-plugins/metadata.xml
index cdc6bec65c6..bf0fc38a66a 100644
--- a/media-plugins/audacious-plugins/metadata.xml
+++ b/media-plugins/audacious-plugins/metadata.xml
@@ -12,10 +12,13 @@
 	<use>
 		<flag name="adplug">Build with AdPlug (Adlib sound card emulation) support</flag>
 		<flag name="ampache">Support controlling audacious via <pkg>www-apps/ampache</pkg></flag>
+		<flag name="aosd">Enable support for Audacious OSD</flag>
 		<flag name="bs2b">Enable Bauer Bauer stereophonic-to-binaural headphone filter</flag>
 		<flag name="cue">Support CUE sheets using the libcue library</flag>
 		<flag name="fluidsynth">Support FluidSynth as MIDI synth backend</flag>
 		<flag name="gme">Support various gaming console music formats</flag>
+		<flag name="gtk3">Link against version 3 of the GIMP Toolkit instead of version 2 (x11-libs/gtk+)</flag>
+		<flag name="hotkeys">Enable support for controlling via hotkeys</flag>
 		<flag name="http">Support HTTP streams through neon</flag>
 		<flag name="qt5">Build with Qt5 interface instead Gtk+</flag>
 		<flag name="qtmedia">Enable playback via <pkg>dev-qt/qtmultimedia</pkg></flag>