[gentoo-commits] repo/gentoo:master commit in: sys-power/suspend/

["Andrew Savchenko" <bircoph@gentoo.org>]

commit:     f9e3aebba785f595c12cb62db62985b609160b28
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 11 15:08:42 2018 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Sun Nov 11 15:09:30 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9e3aebb

sys-power/suspend: remove fbsplash support

- Drop USE=fbsplash due to media-gfx/splashutils tree cleaning.
- Update to EAPI 7.

Closes: https://bugs.gentoo.org/650084
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 sys-power/suspend/suspend-1.0_p20150810-r1.ebuild | 59 +++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild b/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild
new file mode 100644
index 00000000000..eedae70926c
--- /dev/null
+++ b/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+BASE_PV="1.0_p20120915"
+
+DESCRIPTION="Userspace Software Suspend and S2Ram"
+HOMEPAGE="http://suspend.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~bircoph/distfiles/${PN}-${BASE_PV}.tar.xz
+	https://dev.gentoo.org/~bircoph/patches/${P}.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt +lzo threads"
+
+RDEPEND="
+	dev-libs/libx86
+	>=sys-apps/pciutils-2.2.4
+	crypt? (
+		>=dev-libs/libgcrypt-1.6.3:0[static-libs]
+		dev-libs/libgpg-error[static-libs] )
+	lzo? ( >=dev-libs/lzo-2[static-libs] ) "
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-lang/perl-5.10
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=( "${WORKDIR}/${P}.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--disable-fbsplash \
+		$(use_enable crypt encrypt) \
+		$(use_enable lzo compress) \
+		$(use_enable threads)
+}
+
+src_install() {
+	dodir etc
+	emake DESTDIR="${D}" install
+	rm "${D}/usr/share/doc/${PF}"/COPYING* || die
+}
+
+pkg_postinst() {
+	elog "In order to make this package work with genkernel see:"
+	elog "https://bugs.gentoo.org/show_bug.cgi?id=156445"
+}