[gentoo-commits] repo/gentoo:master commit in: net-wireless/linssid/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     d6f3a2a455194343dd0768cfea5f8a9012e39eac
Author:     Conrad Kostecki <conrad <AT> kostecki <DOT> com>
AuthorDate: Sun Nov  4 16:54:07 2018 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Sat Nov 10 04:51:45 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d6f3a2a4

net-wireless/linssid: disable optional gksu support

Also bumped to EAPI=7.

Closes: https://bugs.gentoo.org/670268

Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Conrad Kostecki <conrad <AT> kostecki.com>
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 net-wireless/linssid/linssid-3.6-r1.ebuild | 61 ++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/net-wireless/linssid/linssid-3.6-r1.ebuild b/net-wireless/linssid/linssid-3.6-r1.ebuild
new file mode 100644
index 00000000000..8dc533ea7ce
--- /dev/null
+++ b/net-wireless/linssid/linssid-3.6-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="Graphical wireless scanning for Linux"
+HOMEPAGE="https://sourceforge.net/projects/linssid/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-qt/qtcore:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	x11-libs/qwt:6[opengl,qt5(+),svg]
+"
+
+RDEPEND="
+	${DEPEND}
+	net-wireless/iw
+	sys-auth/polkit
+	x11-libs/libxkbcommon[X]
+"
+
+S="${WORKDIR}/${P}/${PN}-app"
+
+DOCS=( README_${PV} )
+
+src_prepare() {
+	default
+
+	# Fix lib path for x11-libs/qwt and use system qwt for compiling
+	sed -e '/libqwt-qt5.so.6/c\LIBS += -lqwt6-qt5' -e 's/CONFIG += release/& qwt/' -i linssid-app.pro || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}