[gentoo-commits] repo/gentoo:master commit in: dev-python/wsgiproxy2/

["Alexey Shvetsov" <alexxy@gentoo.org>]

commit:     8f8196abdb33d33e41f2ddea7b84647da136fec1
Author:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
AuthorDate: Fri Nov  9 14:10:28 2018 +0000
Commit:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
CommitDate: Fri Nov  9 14:20:20 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f8196ab

dev-python/wsgiproxy2: eapi7 + py3_7

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Alexey Shvetsov <alexxy <AT> gentoo.org>

 dev-python/wsgiproxy2/wsgiproxy2-0.4.4-r1.ebuild | 50 ++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/wsgiproxy2/wsgiproxy2-0.4.4-r1.ebuild b/dev-python/wsgiproxy2/wsgiproxy2-0.4.4-r1.ebuild
new file mode 100644
index 00000000000..3fa947ce702
--- /dev/null
+++ b/dev-python/wsgiproxy2/wsgiproxy2-0.4.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="WSGIProxy2"
+
+DESCRIPTION="HTTP proxying tools for WSGI apps"
+HOMEPAGE="https://pypi.org/project/WSGIProxy2/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/webob[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		>=dev-python/webtest-2.0.17[${PYTHON_USEDEP}]
+		dev-python/socketpool[${PYTHON_USEDEP}]
+		dev-python/restkit[$(python_gen_usedep python2_7)] )"
+# Tests needing restkit are skipped under py3
+# Testing also revealed the suite needs latest webtest
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build -b html -d _build/doctrees   . _build/html
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}