[gentoo-commits] repo/gentoo:master commit in: games-rpg/arx-fatalis-demo/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     325f6f3be1983165b76dfd5fce96cfd3ec37c04d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 14 23:25:09 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Oct 14 23:36:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=325f6f3b

games-rpg/arx-fatalis-demo: EAPI-7 bump, drop games.eclass

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 .../arx-fatalis-demo/arx-fatalis-demo-0-r1.ebuild  | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/games-rpg/arx-fatalis-demo/arx-fatalis-demo-0-r1.ebuild b/games-rpg/arx-fatalis-demo/arx-fatalis-demo-0-r1.ebuild
new file mode 100644
index 00000000000..f249e93678b
--- /dev/null
+++ b/games-rpg/arx-fatalis-demo/arx-fatalis-demo-0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop
+
+DESCRIPTION="Arx Fatalis demo"
+HOMEPAGE="https://www.arkane-studios.com/uk/arx.php"
+SRC_URI="arx_demo_english.zip"
+
+LICENSE="ArxFatalisDemo"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="fetch"
+
+RDEPEND="games-rpg/arx-libertatis"
+DEPEND="
+	app-arch/cabextract
+	app-arch/unzip
+"
+
+S="${WORKDIR}"
+
+pkg_nofetch() {
+	einfo "Please find and download ${SRC_URI} and put it into ${DISTDIR}."
+	einfo "There is a list of possible download locations at"
+	einfo "http://wiki.arx-libertatis.org/Getting_the_game_data#Demo"
+}
+
+src_unpack() {
+	unpack ${A}
+	cabextract Setup1.cab || die "cabextract failed"
+	cabextract Setup2.cab || die "cabextract failed"
+	cabextract Setup3.cab || die "cabextract failed"
+}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r *.pak bin/*.pak
+	insinto /usr/share/${PN}/misc
+	doins bin/Logo.bmp bin/Arx.ttf
+
+	# convert to lowercase
+	cd "${D}"
+	find . -type f -exec sh -c 'echo "${1}"
+	lower="`echo "${1}" | tr [:upper:] [:lower:]`"
+	[ "${1}" = "${lower}" ] || mv "${1}" "${lower}"' - {} \;
+
+	make_desktop_entry "arx --data-dir=/usr/share/arx-fatalis-demo" \
+		"Arx Fatalis Demo" arx-libertatis
+}