From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1050087-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 102D8138335
	for <garchives@archives.gentoo.org>; Wed,  3 Oct 2018 16:24:58 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id ED631E0A8C;
	Wed,  3 Oct 2018 16:24:54 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id B3EE8E0A8C
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Oct 2018 16:24:54 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 1D308335D24
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Oct 2018 16:24:53 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id EFF64397
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Oct 2018 16:24:50 +0000 (UTC)
From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Mart Raudsepp" <leio@gentoo.org>
Message-ID: <1538583473.7bf0b6e7e7ba1ef2cdc036b4482f3b9d26ca15ca.leio@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/gstreamer/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/gstreamer/Manifest media-libs/gstreamer/gstreamer-1.14.4.ebuild
X-VCS-Directories: media-libs/gstreamer/
X-VCS-Committer: leio
X-VCS-Committer-Name: Mart Raudsepp
X-VCS-Revision: 7bf0b6e7e7ba1ef2cdc036b4482f3b9d26ca15ca
X-VCS-Branch: master
Date: Wed,  3 Oct 2018 16:24:50 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 7b9c74e6-e7b5-46e3-b3c3-208a5ce3d309
X-Archives-Hash: f7e5edb2f27d931bd628bf2bd0f99c76

commit:     7bf0b6e7e7ba1ef2cdc036b4482f3b9d26ca15ca
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  3 12:20:15 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Oct  3 16:17:53 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7bf0b6e7

media-libs/gstreamer: bump to 1.14.4, no code changes from 1.14.3

Includes the gstsegment 32bit test fix patch upstream, but we had that
patched in in 1.14.3. Bump still needed for satisfying deps of all other
gstreamer packages.

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

 media-libs/gstreamer/Manifest                |   1 +
 media-libs/gstreamer/gstreamer-1.14.4.ebuild | 111 +++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)

diff --git a/media-libs/gstreamer/Manifest b/media-libs/gstreamer/Manifest
index 461f3b76b2a..a0a6a3781b0 100644
--- a/media-libs/gstreamer/Manifest
+++ b/media-libs/gstreamer/Manifest
@@ -2,3 +2,4 @@ DIST gstreamer-0.10.36.tar.xz 3025876 BLAKE2B f0f70f483e8ccb2a294fb3bc8b51aac089
 DIST gstreamer-1.14.1.tar.xz 3252440 BLAKE2B c2142621b126926dd9ec886f0478154b3f0d9b7adebc6169200b8bc7e4cd089dfe77cab2b436bf3c74cbcae5f84c95afbd05ba282d0afe3e8e226e6bc0f33e33 SHA512 9cf16d79774293dd7fa10c08f6628b83f4e77f0386bebbfd47ded0498e4abd48eee1aee164af53d59fbea2d395e42eb5a12ef4b8f631bc4fd5d4f69545191f9b
 DIST gstreamer-1.14.2.tar.xz 3255404 BLAKE2B 290e8fec3eb6629a0e6e8f01c7c027fcc085f632afeac1ffe7bd4f1d8a9a3d3b78145334a11c91fcabea40b9f202a3b451ca55db13fd23be66c7167c76614932 SHA512 270dba318d15b54fff6e09d09d77dea13be55bbf82a5bb510efb43f954e234230505366cc6f19f5431e2dd24f5a7734daf5a89d9bd94de8302ed722df0e1eb84
 DIST gstreamer-1.14.3.tar.xz 3263036 BLAKE2B 20170b831064ea49565d7a4529563e4e9273def28d33eda779c7e3f4a60989b64844c271da529bdbbaebf80a8a86c37b97af4a18c4d0aae6182be608f3dcf345 SHA512 bfbf76219b5275b00253797323c4fc7b4edb8513d5441c80a8f778b418837c68e9ff37a72a78ac2431a051e813397fb01464bebddd1522b9e4a225ed505342b7
+DIST gstreamer-1.14.4.tar.xz 3264324 BLAKE2B d51febcd7c317964a09dadb4d3bd3ee7a60ac38bef28cdd7d42f49a7b710d6f6180ca7edee1765c8d146f7e3e852e93d0d5f69962089a653cfc3e6bd4ab42f89 SHA512 7ece9f01d40df7c8358482eac94536c5e15261e9568962008e2029e1ee1b3ebb220d2e4802ed1c81c40d897576fafe52234065e273724bfb4df3a3ddf2711abe

diff --git a/media-libs/gstreamer/gstreamer-1.14.4.ebuild b/media-libs/gstreamer/gstreamer-1.14.4.ebuild
new file mode 100644
index 00000000000..a35a13f8437
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-1.14.4.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1 multilib-minimal pax-utils
+
+DESCRIPTION="Open source multimedia framework"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+SRC_URI="https://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+caps +introspection nls +orc test unwind"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	caps? ( sys-libs/libcap[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	unwind? (
+		>=sys-libs/libunwind-1.2_rc1[${MULTILIB_USEDEP}]
+		dev-libs/elfutils[${MULTILIB_USEDEP}]
+	)
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	sys-devel/bison
+	sys-devel/flex
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )
+"
+# gtk-doc-am to install API docs
+
+src_configure() {
+	if [[ ${CHOST} == *-interix* ]] ; then
+		export ac_cv_lib_dl_dladdr=no
+		export ac_cv_func_poll=no
+	fi
+	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
+		# GCC groks this, but then refers to an implementation (___multi3,
+		# ___udivti3) that don't exist (at least I can't find it), so force
+		# this one to be off, such that we use 2x64bit emulation code.
+		export gst_cv_uint128_t=no
+	fi
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local completiondir=$(get_bashcompdir)
+	# Set 'libexecdir' to ABI-specific location for the library spawns
+	# helpers from there.
+	# Disable static archives and examples to speed up build time
+	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
+	local myconf=(
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		--disable-benchmarks
+		--disable-debug
+		--disable-examples
+		--disable-static
+		--disable-valgrind
+		--enable-check
+		$(use_with unwind)
+		$(use_with unwind dw)
+		$(multilib_native_use_enable introspection)
+		$(use_enable nls)
+		$(use_enable test tests)
+		--with-bash-completion-dir="${completiondir%/*}"
+		--with-package-name="GStreamer ebuild for Gentoo"
+		--with-package-origin="https://packages.gentoo.org/package/media-libs/gstreamer"
+	)
+
+	if use caps ; then
+		myconf+=( --with-ptp-helper-permissions=capabilities )
+	else
+		myconf+=(
+			--with-ptp-helper-permissions=setuid-root
+			--with-ptp-helper-setuid-user=nobody
+			--with-ptp-helper-setuid-group=nobody
+		)
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		local x
+		for x in gst libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install() {
+	# can't do "default", we want to install docs in multilib_src_install_all
+	emake DESTDIR="${D}" install
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/$(get_libdir)/gstreamer-${SLOT}/gst-plugin-scanner"
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}"
+}