[gentoo-commits] repo/gentoo:master commit in: net-libs/davix/

["Guilherme Amadio" <amadio@gentoo.org>]

commit:     0761c62101b612b189b3c1205b69df571923af6e
Author:     Guilherme Amadio <amadio <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 24 16:04:50 2018 +0000
Commit:     Guilherme Amadio <amadio <AT> gentoo <DOT> org>
CommitDate: Mon Sep 24 16:05:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0761c621

net-libs/davix: version bump to 0.6.8

Package-Manager: Portage-2.3.50, Repoman-2.3.10

 net-libs/davix/Manifest           |  1 +
 net-libs/davix/davix-0.6.8.ebuild | 65 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-libs/davix/Manifest b/net-libs/davix/Manifest
index 4b0c3a49ff1..a7a885c0cfc 100644
--- a/net-libs/davix/Manifest
+++ b/net-libs/davix/Manifest
@@ -1 +1,2 @@
 DIST davix-0.6.7.tar 3346429 BLAKE2B 7510c628cd1d346ed5f4dca6100207e5e2efa3a98d0caf63dbe3ba39f58a9b11c330c95cd2d40d60d8f2497355d4cb2f2d7537babfef287a5905f32322363d90 SHA512 5cb830e415a4ab87b7b046fbd8ba615379766f4fa4b886a271b0c248c05968b9a3cb144751b44d5fd62f5e07bdb7610c0505e44f2702147f6f006b49a4b3d8ce
+DIST davix-0.6.8.tar 3461829 BLAKE2B 96e23b3d099262b577a078aad9c6ac3adb6a0ab5dd410573a1886a886f828e46af2d6df9904236ae9f1aff5c75e7bec93c81e02bd173d67a13e9f9bfce3225c1 SHA512 7c0e2a427b2a9ad807d104e8ada732a6e806818e0b7b53caf965ce6238637e4c6f5c67e56e7ef89a23004531c62bc1ba6cb7ce1dd0d1aefdc46bdd7b8c48c9c4

diff --git a/net-libs/davix/davix-0.6.8.ebuild b/net-libs/davix/davix-0.6.8.ebuild
new file mode 100644
index 00000000000..943d50f9fb9
--- /dev/null
+++ b/net-libs/davix/davix-0.6.8.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="High-performance file management over WebDAV/HTTP"
+HOMEPAGE="https://dmc.web.cern.ch/projects/davix"
+SRC_URI="http://grid-deployment.web.cern.ch/grid-deployment/dms/lcgutil/tar/${PN}/${PV}/${P}.tar.gz -> ${P}.tar"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ipv6 kernel_linux test tools"
+
+CDEPEND="
+		dev-libs/libxml2:2=
+		dev-libs/openssl:0=
+		kernel_linux? ( sys-apps/util-linux )
+"
+
+DEPEND="${CDEPEND}
+		doc? (
+			app-doc/doxygen[dot]
+			dev-python/sphinx
+		)
+		virtual/pkgconfig
+"
+
+RDEPEND="${CDEPEND}"
+
+REQUIRED_USE="test? ( tools )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DDOC_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}"
+		-DENABLE_HTML_DOCS=$(usex doc)
+		-DENABLE_IPV6=$(usex ipv6)
+		-DENABLE_TOOLS=$(usex tools)
+		-DHTML_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}/html"
+		-DSOUND_INSTALL_DIR="${EPREFIX}/usr/share/${PN}/sounds"
+		-DSTATIC_LIBRARY=OFF
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}/etc"
+		-DBUILD_TESTING=$(usex test)
+		-DUNIT_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	if use doc; then
+		cmake-utils_src_compile doc
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if ! use tools; then
+		rm -rf "${ED}/usr/share/man/man1"
+	fi
+}