[gentoo-commits] repo/gentoo:master commit in: media-video/gnome-mplayer/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     20777ad8fcee2e5734826d1c23b0ea1c292b1ec7
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 15 23:14:30 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Sep 16 08:03:12 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20777ad8

media-video/gnome-mplayer: Drop USE musicbrainz

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 .../gnome-mplayer/gnome-mplayer-1.0.9-r1.ebuild    | 75 ++++++++++++++++++++++
 1 file changed, 75 insertions(+)

diff --git a/media-video/gnome-mplayer/gnome-mplayer-1.0.9-r1.ebuild b/media-video/gnome-mplayer/gnome-mplayer-1.0.9-r1.ebuild
new file mode 100644
index 00000000000..bd9fa8ca7f6
--- /dev/null
+++ b/media-video/gnome-mplayer/gnome-mplayer-1.0.9-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="A GTK+ interface to MPlayer"
+HOMEPAGE="https://code.google.com/p/gnome-mplayer/"
+SRC_URI="https://${PN}.googlecode.com/svn/packages/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~ppc ~ppc64 x86 ~x86-fbsd"
+IUSE="alsa +dbus +dconf gda gnome ipod libnotify pulseaudio"
+
+COMMON_DEPEND=">=dev-libs/glib-2.30
+	>=media-libs/gmtk-${PV}[dconf=]
+	>=x11-libs/gtk+-3.2:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	gda? ( gnome-extra/libgda:5 )
+	gnome? ( gnome-base/nautilus )
+	ipod? ( >=media-libs/libgpod-0.7 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/gnome-icon-theme-symbolic
+	>=media-video/mplayer-1.0_rc4_p20100101[libass]"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS="ChangeLog README DOCS/*.txt DOCS/tech/*.txt"
+
+src_configure() {
+	# TODO: temporarily --disable-nemo only because it's untested and new feature in 1.0.9
+	econf \
+		--enable-gtk3 \
+		$(use_enable gnome nautilus) \
+		--disable-nemo \
+		--with-gio \
+		$(use_with dbus) \
+		$(use_with gda libgda) \
+		$(use_with alsa) \
+		$(use_with pulseaudio) \
+		$(use_with libnotify) \
+		$(use_with ipod libgpod) \
+		--without-libmusicbrainz3
+}
+
+src_install() {
+	default
+	rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}