[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     23e3bef716c6c4a7020f3755874adb7faa6964c4
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  9 16:34:43 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Sep  9 17:51:54 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23e3bef7

gnome-extra/evolution-data-server: bump to 3.26.6

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 gnome-extra/evolution-data-server/Manifest         |   1 +
 .../evolution-data-server-3.26.6.ebuild            | 152 +++++++++++++++++++++
 2 files changed, 153 insertions(+)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 96e25e1abbb..330d7a535f0 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,2 +1,3 @@
 DIST evolution-data-server-3.22.7.tar.xz 5564924 BLAKE2B 8107a13ef46a4457e122c5d719c0d29ccbf5ec61424fb6b4810b1e165bb68cb8c1c87ec9ab34446458321c0c56ba5a5408f45ae9fc95bcee965c21caaad6a230 SHA512 53648c0b893982b3577008aeae57e213e084aa5ba4663ca109f200b268635fd1544408c1ace065e91e5eaf48a20f59609c8e895a1907501ea5e64119d1590d44
 DIST evolution-data-server-3.24.7.tar.xz 4253252 BLAKE2B ca435a4e6c3a003c5166bd06f0308766686cc9e02f1eb6a15a521c58805bafdfd39cbc7ee058339ba383329ab34a11ed2b0eeebd9b545219c4b3d8f51de8df60 SHA512 3e83cb0e87ec822ebf6c81963693e7c701d20266e0811bd261a78073c75724e2c24ac5d5561e997ed8567e9e519c175b3104fa6e2e28158854c8c3ec39a8e9df
+DIST evolution-data-server-3.26.6.tar.xz 4406676 BLAKE2B d12fcc412736b505a30254a55763ffec68c1d8cd810fe62c82d7dd5947047caf7c296ccf8103b4a06496dbae38aa55ba9d071dc02442872274e2955d662be4cf SHA512 17522a19d9b4d19f89ccb67c76a89d599377eba36cf6dbe9fbc88fb162947b0208eaf1b4b6b5c4e9850dadf7e6ffea5161ba149b308415e94afc745bc1a448a7

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.26.6.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.26.6.ebuild
new file mode 100644
index 00000000000..c48dbec871b
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.26.6.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake-utils db-use flag-o-matic gnome2 python-any-r1 systemd vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/60" # subslot = libcamel-1.2 soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc google +introspection ipv6 ldap kerberos vala +weather"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# sys-libs/db is only required for migrating from <3.13 versions
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old calendar data, bug #519512
+gdata_depend=">=dev-libs/libgdata-0.17.7:="
+RDEPEND="
+	>=app-crypt/gcr-3.4
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:=
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/libical-2.0:=
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4:=
+	>=dev-libs/nss-3.9:=
+	>=net-libs/libsoup-2.42:2.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=app-crypt/gcr-3.4[gtk]
+		>=x11-libs/gtk+-3.10:3
+	)
+	google? (
+		>=dev-libs/json-glib-1.0.4
+		>=net-libs/webkit-gtk-2.11.91:4
+		${gdata_depend}
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.8:=
+		${gdata_depend} )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-3.10:2= )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake-utils_src_prepare call, if that works
+
+src_prepare() {
+	use vala && vala_src_prepare
+	cmake-utils_src_prepare
+	gnome2_src_prepare
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+		-e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+		-i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	local google_auth_enable
+	if use google || use gnome-online-accounts; then
+		google_auth_enable="ON"
+	else
+		google_auth_enable="OFF"
+	fi
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_GOOGLE_AUTH=${google_auth_enable}
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DENABLE_UOA=OFF
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=$(usex ipv6)
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_GOOGLE=$(usex google)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	virtx cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}