From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1045908-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 972F2138335
	for <garchives@archives.gentoo.org>; Sat,  8 Sep 2018 13:28:34 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 91EC4E083E;
	Sat,  8 Sep 2018 13:28:33 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 51689E083E
	for <gentoo-commits@lists.gentoo.org>; Sat,  8 Sep 2018 13:28:33 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 44769335D8E
	for <gentoo-commits@lists.gentoo.org>; Sat,  8 Sep 2018 13:28:31 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 71DFC3A4
	for <gentoo-commits@lists.gentoo.org>; Sat,  8 Sep 2018 13:28:29 +0000 (UTC)
From: "Jeroen Roovers" <jer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Jeroen Roovers" <jer@gentoo.org>
Message-ID: <1536413300.8f822fc8ba8764227639bc86be76f72c9e3d85d0.jer@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-misc/youtube-dl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-misc/youtube-dl/Manifest net-misc/youtube-dl/youtube-dl-2018.09.08.ebuild
X-VCS-Directories: net-misc/youtube-dl/
X-VCS-Committer: jer
X-VCS-Committer-Name: Jeroen Roovers
X-VCS-Revision: 8f822fc8ba8764227639bc86be76f72c9e3d85d0
X-VCS-Branch: master
Date: Sat,  8 Sep 2018 13:28:29 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: c8c9c28a-817e-49c0-a68b-992787b52c2c
X-Archives-Hash: 25d16f8d312b4e8f3bcc738a2b221f0c

commit:     8f822fc8ba8764227639bc86be76f72c9e3d85d0
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  8 13:15:13 2018 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Sep  8 13:28:20 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f822fc8

net-misc/youtube-dl: Version 2018.09.08.

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 net-misc/youtube-dl/Manifest                     |   1 +
 net-misc/youtube-dl/youtube-dl-2018.09.08.ebuild | 115 +++++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index b4b8946d7db..d1fe640799f 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -2,3 +2,4 @@ DIST youtube-dl-2017.11.15.tar.gz 2834012 BLAKE2B fd93e3923f99874be58681a886c09e
 DIST youtube-dl-2018.08.22.tar.gz 3025389 BLAKE2B e8d2d8bccab8c169d08de35544e5efb05c65799c26894807e075edfe090d36de30fea787f54d59e4fc8b671356ce2e1d9002627948fb05becc9d2e3bc634164c SHA512 ef17c744ac27b3bf547124f18a155908a66ee75f3f6fb5d7dd8a1d8da61a5a598bbade6cf0362e8c93c337dcf47750db5f56357919226430f02d0b764011ffb5
 DIST youtube-dl-2018.08.28.tar.gz 3027906 BLAKE2B dde156395f40aa91247341ab46e909536b3a4f53acea071b543ab8a548608655f2072280c9d927e7845ef79e4b0d7a0c150bafa477fb46df9ff11979cf344c5e SHA512 311abf4410a4e59df9b6941ee7cf03afda1c2e959eac8c1be182a31854d2f4dac9cd016a5103828d4860dce3db0671a8937c296eac2f24364acc67271f8ffd14
 DIST youtube-dl-2018.09.01.tar.gz 3032563 BLAKE2B c1535f1311b03ea5f3b20aba3a14487515427aad7d16e52ddca9d974050fe955405ba05fbac5c91e6e3ac830176b537d44d039a1d1e13fedc32a665610cc2af7 SHA512 172f65f48e81f335e959c119ca13f40f32cca7fc57c123d17e7be836aef2fa072cc20a1255bb5d9584c8cd1d8f8fa4c88d3f2ed5b3fa94075d3f97e7285f30af
+DIST youtube-dl-2018.09.08.tar.gz 3034241 BLAKE2B a388c707c771abd57814de119edc4a12c2fc569f72ed2881cc1906a30c2148d44b97c9866513eb8db0d95ce4c25e2275e41002bda796463eaeaeb0c99cdf6b31 SHA512 c1cbf38a185d6ba1525eb08064f95aa252cf8d461f140cb48dc4a795e209f5d31bc1583f4d52c2ea9f1c15dac46c563603e46f72cc896a7fec54dcb2d0a49c0b

diff --git a/net-misc/youtube-dl/youtube-dl-2018.09.08.ebuild b/net-misc/youtube-dl/youtube-dl-2018.09.08.ebuild
new file mode 100644
index 00000000000..1c433fb38ec
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2018.09.08.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="+offensive test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-python/nose[coverage(+)] )
+"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	if ! use offensive; then
+		sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
+			youtube_dl/version.py || die
+		# these have single line import statements
+		local xxx=(
+			alphaporno anysex behindkink camwithher chaturbate eporner
+			eroprofile extremetube foxgay goshgay hellporno hentaistigma
+			hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
+			pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
+			slutload spankbang spankwire sunporno thisav vporn watchindianporn
+			xbef xnxx xtube xvideos xxxymovies youjizz youporn
+		)
+		# these have multi-line import statements
+		local mxxx=(
+			drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
+		)
+		# do single line imports
+		sed -i \
+			-e $( printf '/%s/d;' ${xxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		# do multiple line imports
+		sed -i \
+			-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		sed -i \
+			-e $( printf '/%s/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/generic.py \
+			|| die
+
+		rm \
+			$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
+			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
+			test/test_age_restriction.py \
+			|| die
+	fi
+
+	eapply_user
+
+	distutils-r1_python_prepare_all
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins youtube-dl.zsh _youtube-dl
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins youtube-dl.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "youtube-dl(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/youtube-dl/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+}