[gentoo-commits] repo/gentoo:master commit in: media-video/bino/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     cf7f3d42d79ca94eb40bb83cf08dc2fb1f574d05
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  2 09:38:13 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Sep  2 09:39:26 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf7f3d42

media-video/bino: 1.6.7 version bump, improve everywhere

https, use if instead ugly && chains, sort/missing deps, xdg-utils

Package-Manager: Portage-2.3.48, Repoman-2.3.10

 media-video/bino/Manifest          |  1 +
 media-video/bino/bino-1.6.7.ebuild | 73 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/media-video/bino/Manifest b/media-video/bino/Manifest
index 5666c546f2f..44a1084a061 100644
--- a/media-video/bino/Manifest
+++ b/media-video/bino/Manifest
@@ -1 +1,2 @@
 DIST bino-1.6.6.tar.xz 822680 BLAKE2B c863e16a4f576bffb3abf3ab03d8e4cd4ab9db0b0cc73ef2c255b18f103294a9f7e2bf382b286bb7d1d3cb9278c06965772cfc6241a7f23d2f4edc0a47059d92 SHA512 43a17f390881fcc8b7721b21ff8524b89992cd7fb0cfc467769bdddd0ad0c0d2536d161475a7fce6d4d3e758e017a38f671648dfaa4a345dc02127b7b192c8c0
+DIST bino-1.6.7.tar.xz 825068 BLAKE2B d9019a793838f33ea1315849aa994b20a1c6127995315dc03972fe6c64a742c73434c07ba06402a1e2bd5357781d18aaf3d19ab2d61788745b2aa99ad3f4c6f4 SHA512 ae8f72b200100664b9fd55963371ce64a2f39e240676494d69b422d662f2295560ba458eb04707b82f88d3c6b3fab98a1ecb40d74799300f96b8eb8be680c9b8

diff --git a/media-video/bino/bino-1.6.7.ebuild b/media-video/bino/bino-1.6.7.ebuild
new file mode 100644
index 00000000000..5a98d40353a
--- /dev/null
+++ b/media-video/bino/bino-1.6.7.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic xdg-utils
+
+DESCRIPTION="Stereoscopic and multi-display media player"
+HOMEPAGE="https://bino3d.org/"
+SRC_URI="https://bino3d.org/releases/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc libav lirc video_cards_nvidia"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtwidgets:5
+	>=media-libs/glew-1.6.0:0=
+	>=media-libs/libass-0.9.9
+	>=media-libs/openal-1.15.1
+	virtual/libintl
+	libav? ( >=media-video/libav-0.7:0= )
+	!libav? ( >=media-video/ffmpeg-0.7:0= )
+	lirc? ( app-misc/lirc )
+	video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	if use video_cards_nvidia; then
+		append-cppflags "-I/usr/include/NVCtrl"
+		append-ldflags "-L/usr/$(get_libdir)/opengl/nvidia/lib -L/usr/$(get_libdir)"
+		append-libs "Xext"
+	fi
+	if use lirc; then
+		append-cppflags "-I/usr/include/lirc"
+		append-libs "lirc_client"
+	fi
+
+	# Fix a compilation error because of a multiple definitions in glew
+	append-ldflags "-zmuldefs"
+
+	econf \
+		$(use_with video_cards_nvidia xnvctrl) \
+		$(use_with lirc) \
+		$(use_enable debug) \
+		--without-equalizer \
+		--with-qt-version=5 \
+		--htmldir=/usr/share/doc/${PF}/html
+
+}
+
+src_install() {
+	default
+	if ! use doc; then
+		rm -rf "${D}"/usr/share/doc/${PF}/html || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}