[gentoo-commits] repo/gentoo:master commit in: www-plugins/lightspark/

["Chí-Thanh Christopher Nguyễn" <chithanh@gentoo.org>]

commit:     bab2d2b7a8dad2b107cb48fe83027e859c2e1caa
Author:     Chí-Thanh Christopher Nguyễn <chithanh <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 29 00:40:49 2018 +0000
Commit:     Chí-Thanh Christopher Nguyễn <chithanh <AT> gentoo <DOT> org>
CommitDate: Wed Aug 29 00:40:49 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bab2d2b7

www-plugins/lightspark: version bump to 0.8.1

Also prevent building against incompatible ffmpeg/libav versions

Bug: https://bugs.gentoo.org/654332
Closes: https://bugs.gentoo.org/657788
Package-Manager: Portage-2.3.40, Repoman-2.3.9

 www-plugins/lightspark/Manifest                |  1 +
 www-plugins/lightspark/lightspark-0.8.1.ebuild | 97 ++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 579cbb8a401..67f0d0f0528 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1 +1,2 @@
+DIST lightspark-0.8.1.tar.gz 1899466 BLAKE2B d057deccc8ee03f16bfd384c9aee94ee70b7f6674bb0d46c2965f27868a2177c2985f791801975aab1608b4e59d9d40a51e327ec4b00e60eb6714f610b4c319f SHA512 ee9f02e4aa160d8e68cab743eddce5f4f5de0bb78f5daaaf69890b442701dc42094a59433cef136f6dc85e6fbce989bc8ff7ce8ad1ed1929c8501b13e24f2646
 DIST lightspark-f6ed8284810ad91c277ed5d0835b215e7329450e.tar.gz 1880249 BLAKE2B 031dc48f40956fcfb5a8b0fd825da8a2a0dba6daa4646296a385d5f90f13027d44cbb09562f6bf57b8d5d415a278fa06974624aee42e14b75892c36798dceda0 SHA512 a75ebf5e666daec0f244285bfd1029feb6fcfa2aeba800f175bb07bc148d39e76435d77868c964b2e149019b763498990bf0db25ba632cf21b91ad0958412332

diff --git a/www-plugins/lightspark/lightspark-0.8.1.ebuild b/www-plugins/lightspark/lightspark-0.8.1.ebuild
new file mode 100644
index 00000000000..6106645e322
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.8.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils gnome2-utils nsplugins toolchain-funcs xdg-utils
+
+EGIT_COMMIT="f6ed8284810ad91c277ed5d0835b215e7329450e"
+DESCRIPTION="High performance flash player"
+HOMEPAGE="http://lightspark.github.io/"
+SRC_URI="https://github.com/lightspark/lightspark/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles libav nsplugin ppapi profile rtmp"
+
+RDEPEND="app-arch/xz-utils:0=
+	dev-cpp/glibmm:2=
+	>=dev-libs/boost-1.42:0=
+	dev-libs/glib:2=
+	dev-libs/libpcre:3=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:2=
+	media-libs/libpng:0=
+	media-libs/libsdl2:0=
+	media-libs/sdl2-mixer:0=
+	>=sys-devel/llvm-3.4:=
+	sys-libs/zlib:0=
+	x11-libs/cairo:0=
+	x11-libs/libX11:0=
+	x11-libs/pango:0=
+	virtual/jpeg:0=
+	curl? ( net-misc/curl:0= )
+	ffmpeg? (
+		libav? ( <media-video/libav-13_pre:0= )
+		!libav? ( <media-video/ffmpeg-4:0= )
+	)
+	gles? ( media-libs/mesa:0=[gles2] )
+	!gles? (
+		>=media-libs/glew-1.5.3:0=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:0= )"
+DEPEND="${RDEPEND}
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_rc*/}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	if use nsplugin && ! has_version www-plugins/gnash; then
+		elog "Lightspark now supports gnash fallback for its browser plugin."
+		elog "Install www-plugins/gnash to take advantage of it."
+	fi
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}