[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     dcc7e916fc9597dd2f62bb8538abf1662724c57f
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 14 12:49:23 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Aug 14 12:49:23 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dcc7e916

sys-apps/fwupd: Bump to version 1.1.1

Package-Manager: Portage-2.3.46, Repoman-2.3.10

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.1.1.ebuild | 121 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 122 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index a46369abfcf..035461c44d0 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,2 +1,3 @@
 DIST fwupd-1.0.8.tar.gz 1584132 BLAKE2B 7744d14a02bd9847c0c1efe8ff8365abccf9d5213150687815d3e1236844ec71dbf161e5f5d7be32103c3613640680b5b2a017f1a60a30df93fc55bf5d765f74 SHA512 11bdc1dd77697b690e849bde59e54cf289cde32f410f9f7e8911a874f0a265b091ac2e335f784f54b64f835f2750a63a74092cc5eaf7a6c70eaa6d06995d131e
 DIST fwupd-1.1.0.tar.gz 1636214 BLAKE2B 492c33eb54852dd7d73f511dd6e5aa222b35e1898105bbfb291e1095c3968101597185cff2a1889e9da5728fdd0c8d4638e7e2102b12cf7659a1b6612ca0e9b7 SHA512 058d4564cf922b5056f6197261d77b97db7238a1658d69d9b29bec70a44542a5a131071935747e0cc963661a61b242ca98375ed8da920f819d37a706aec0c2ae
+DIST fwupd-1.1.1.tar.gz 1669430 BLAKE2B 92073f1e3b6c6b68da48de792d58d218c0b0bfce2a3765c257253d6fb93974dccadc2ae71ab6275d0e9ad6775642eba1e2613ad2a3f11cd4d4225affdedc7561 SHA512 b825b565b6c85bbf703352eb0aff40de8e348c96537316373de718faf82bbdd425ba1b8091d1ab4b5403f2fbe46ceda45a502a5fea4ad3bd51e6cc5a2aad6ddc

diff --git a/sys-apps/fwupd/fwupd-1.1.1.ebuild b/sys-apps/fwupd/fwupd-1.1.1.ebuild
new file mode 100644
index 00000000000..0b779394a53
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.1.1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Package requires newer meson than eclass provides
+MESON_AUTO_DEPEND="no"
+PYTHON_COMPAT=( python3_4 python3_5 python3_6 )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colorhug dell doc gpg +man pkcs7 redfish systemd test uefi"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	dell? ( uefi )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/appstream-glib-0.7.4:=[introspection]
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.2.9[introspection]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=net-libs/libsoup-2.51.92:2.4[introspection]
+	>=sys-auth/polkit-0.103
+	virtual/libelf:0=
+	colorhug? ( >=x11-misc/colord-1.2.12:0= )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+	redfish? (
+		dev-libs/json-glib
+		sys-libs/efivar
+	)
+	systemd? ( >=sys-apps/systemd-211 )
+	!systemd? ( >=sys-auth/consolekit-1.0.0 )
+	uefi? (
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+DEPEND="
+	${RDEPEND}
+	app-arch/gcab
+	app-arch/libarchive
+	>=dev-util/meson-0.41.0
+	>=dev-util/ninja-1.7.2
+	virtual/pkgconfig
+	$(vala_depend)
+	doc? ( dev-util/gtk-doc )
+	man? ( app-text/docbook-sgml-utils )
+	test? ( net-libs/gnutls[tools] )
+"
+
+# required for fwupd daemon to run.
+# NOT a build time dependency. The build system does not check for dbus.
+PDEPEND="sys-apps/dbus"
+
+src_prepare() {
+	default
+	sed -e "s/'--create'/'--absolute-name', '--create'/" \
+		-i data/tests/builder/meson.build || die
+	sed -e "/'-Werror',/d" \
+		-i plugins/uefi/efi/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	xdg_environment_reset
+	local emesonargs=(
+		-Dconsolekit="$(usex systemd false true)"
+		-Dgpg="$(usex gpg true false)"
+		-Dgtkdoc="$(usex doc true false)"
+		-Dman="$(usex man true false)"
+		-Dpkcs7="$(usex pkcs7 true false)"
+		-Dplugin_dell="$(usex dell true false)"
+		-Dplugin_redfish="$(usex redfish true false)"
+		-Dplugin_synaptics="$(usex dell true false)"
+		# requires libtbtfwu which is not packaged (yet?)
+		-Dplugin_thunderbolt=false
+		-Dplugin_uefi="$(usex uefi true false)"
+		-Dsystemd="$(usex systemd true false)"
+		-Dtests="$(usex test true false)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	doinitd "${FILESDIR}"/${PN}
+}
+
+pkg_postinst() {
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}