From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1040034-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 0F616138334
for <garchives@archives.gentoo.org>; Thu, 2 Aug 2018 08:09:55 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A7C1BE0828;
Thu, 2 Aug 2018 08:09:46 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 283FDE0829
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Aug 2018 08:09:46 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id D9617335CED
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Aug 2018 08:09:43 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 494E1397
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Aug 2018 08:09:40 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1533196612.6a191ec71243fdb10027bc75af8e4f97cbb23bfd.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/harfbuzz/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/harfbuzz/Manifest media-libs/harfbuzz/harfbuzz-1.8.5.ebuild
X-VCS-Directories: media-libs/harfbuzz/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 6a191ec71243fdb10027bc75af8e4f97cbb23bfd
X-VCS-Branch: master
Date: Thu, 2 Aug 2018 08:09:40 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: c1a8e4ae-b818-4deb-b6be-594ac4d65894
X-Archives-Hash: 7cc223bba11b2b310300a269da3094f8
commit: 6a191ec71243fdb10027bc75af8e4f97cbb23bfd
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 2 07:56:52 2018 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Aug 2 07:56:52 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a191ec7
media-libs/harfbuzz: Bump to version 1.8.5
Package-Manager: Portage-2.3.44, Repoman-2.3.10
media-libs/harfbuzz/Manifest | 1 +
media-libs/harfbuzz/harfbuzz-1.8.5.ebuild | 109 ++++++++++++++++++++++++++++++
2 files changed, 110 insertions(+)
diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
index 76dda821d0d..f97205a404d 100644
--- a/media-libs/harfbuzz/Manifest
+++ b/media-libs/harfbuzz/Manifest
@@ -2,3 +2,4 @@ DIST harfbuzz-1.7.6.tar.bz2 2586909 BLAKE2B 0ae5902b9fe00a4f05a5dc407d6981959204
DIST harfbuzz-1.8.1.tar.bz2 3804867 BLAKE2B 9687b35bbdb74a42c28764a7b026a46ff90640b84bc40702bdbfadc79bbe3c393de837d4cdbbb8798f28aa8c75687c4f07e1c79e98bf9bd506403d89b4baf6a5 SHA512 7ef27232b294883b0c7404c8412837acfba95f12677f226d764f87e22cd169fe037e7bf13a9309e78c9aa905225fb332b3a143a01b13308b05fcccaeddb0c931
DIST harfbuzz-1.8.3.tar.bz2 3828043 BLAKE2B 038a714480f10b05b2b31ba46667ce563598b43d122f64ab4adc6f267b2b99ea23ba92a1ae0df173be13f29da8960d55a5c5fdee25aa9fc4541a109c5e76946d SHA512 d3ec8f31ff51315fb35f6b5c69b3fbf29e1dff710fb11158801990fbeb99be5fce691f3c06df1c295a08bfb6c14021c511993b0d22ca96e76d8212ddfda198b6
DIST harfbuzz-1.8.4.tar.bz2 3829479 BLAKE2B df4116945a00130b83198044665c4f0f0da497cf7d198a39632bbbe6b95327f8189dc7486262eb4d03b181c0151d89bea41223e092613c2f8fec9566eb6f9434 SHA512 8ec72b065b3f5d227b0af1486ab8019414bbdfaafce2f99d5a8bbf7d37a2709cadb545efcc46c5a5c44ce405966f01d8f3e8607f31907f8ed7ebe10150c9dcaf
+DIST harfbuzz-1.8.5.tar.bz2 3859514 BLAKE2B 6e44de23d81e68ccbe69008f852f5d29fbac8c255808a8330c47d47703035065cf4b48e4d3ce06b50d83d5d3412c3300d0010806b5fed251450d7a7dd0d1395d SHA512 81e4df32d848d52b27413ddf4551bbaa16c04e2cc98f4e2318359b611a725cd55099138106344babcc912a662e6c70354370615452b0d69c38bfa419e063b1a9
diff --git a/media-libs/harfbuzz/harfbuzz-1.8.5.ebuild b/media-libs/harfbuzz/harfbuzz-1.8.5.ebuild
new file mode 100644
index 00000000000..c723137a7e5
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-1.8.5.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit flag-o-matic libtool multilib-minimal python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+
+if [[ ${PV} = 9999 ]] ; then
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/harfbuzz.git"
+ inherit git-r3 autotools
+else
+ SRC_URI="https://www.freedesktop.org/software/${PN}/release/${P}.tar.bz2"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+fi
+
+LICENSE="Old-MIT ISC icu"
+SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
+
+IUSE="+cairo debug fontconfig +glib +graphite icu +introspection static-libs test +truetype"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+ cairo? ( x11-libs/cairo:= )
+ fontconfig? ( media-libs/fontconfig:1.0[${MULTILIB_USEDEP}] )
+ glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+ graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+ icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+ introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+ truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+ dev-util/gtk-doc-am
+ virtual/pkgconfig
+ test? ( ${PYTHON_DEPS} )
+"
+# eautoreconf requires gobject-introspection-common
+# ragel needed if regenerating *.hh files from *.rl
+if [[ ${PV} = 9999 ]] ; then
+ DEPEND+="
+ >=dev-libs/gobject-introspection-common-1.34
+ dev-util/ragel
+ "
+fi
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+ if ! use debug ; then
+ append-cppflags -DHB_NDEBUG
+ fi
+}
+
+src_prepare() {
+ default
+
+ xdg_environment_reset
+
+ if [[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] ; then
+ # on Darwin/Solaris we need to link with g++, like automake defaults
+ # to, but overridden by upstream because on Linux this is not
+ # necessary, bug #449126
+ sed -i \
+ -e 's/\<LINK\>/CXXLINK/' \
+ src/Makefile.am || die
+ sed -i \
+ -e '/libharfbuzz_la_LINK = /s/\<LINK\>/CXXLINK/' \
+ src/Makefile.in || die
+ sed -i \
+ -e '/AM_V_CCLD/s/\<LINK\>/CXXLINK/' \
+ test/api/Makefile.in || die
+ fi
+
+ [[ ${PV} == 9999 ]] && eautoreconf
+ elibtoolize # for Solaris
+
+ # bug 618772
+ append-cxxflags -std=c++14
+}
+
+multilib_src_configure() {
+ # harfbuzz-gobject only used for instrospection, bug #535852
+ local myeconfargs=(
+ --without-coretext
+ --without-uniscribe
+ $(use_enable static-libs static)
+ $(multilib_native_use_with cairo)
+ $(use_with fontconfig)
+ $(use_with glib)
+ $(use_with introspection gobject)
+ $(use_with graphite graphite2)
+ $(use_with icu)
+ $(multilib_native_use_enable introspection)
+ $(use_with truetype freetype)
+ )
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+
+ if multilib_is_native_abi; then
+ ln -s "${S}"/docs/html docs/html || die
+ fi
+}
+
+multilib_src_install_all() {
+ einstalldocs
+ find "${ED}" -name "*.la" -delete || die
+}