[gentoo-commits] repo/gentoo:master commit in: net-libs/gupnp/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     99a3f258d96538c37cdee2de6680ccc414c93add
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 30 14:04:22 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Jul 30 14:04:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=99a3f258

net-libs/gupnp: bump to 1.0.3

Package-Manager: Portage-2.3.43, Repoman-2.3.10

 net-libs/gupnp/Manifest           |  1 +
 net-libs/gupnp/gupnp-1.0.3.ebuild | 73 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-libs/gupnp/Manifest b/net-libs/gupnp/Manifest
index 535c8699a45..bb88072d42f 100644
--- a/net-libs/gupnp/Manifest
+++ b/net-libs/gupnp/Manifest
@@ -1 +1,2 @@
 DIST gupnp-1.0.2.tar.xz 421792 BLAKE2B f89bd5f345637718a90fcd90bb4b0a17cf143042018d6a529a6cbac9c411218f1b014b5eee2a09e888e0dba195a1a8a31c078f0be749bb1b6d059a665c4ca2fa SHA512 a22082b10725abe233a8b3212a988a7c7e52a617aefe2029f25572d371560264cddd15eab2ad4637880b4be3b4bdb85dbc5c47c8da338667152c86eaecd7e165
+DIST gupnp-1.0.3.tar.xz 422912 BLAKE2B 900a2a81982a50239b26ddd5df3f57caac1ee66103e857b9014db7dc694e303c1eaa0633cb467887f3370e97058abc221bd0175c9df11ca4af31e3f802145a66 SHA512 f256757ddf1a31f1dc93dc138401329e40aa063e7452dccaabe53682eebcb1b98cb6429c01d806290587ca9d01d91afce0603627d2d8675ddb68ef919efb6448

diff --git a/net-libs/gupnp/gupnp-1.0.3.ebuild b/net-libs/gupnp/gupnp-1.0.3.ebuild
new file mode 100644
index 00000000000..02c1369b673
--- /dev/null
+++ b/net-libs/gupnp/gupnp-1.0.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+# FIXME: Claims to works with python3 but appears to be wishful thinking
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 multilib-minimal python-r1 vala
+
+DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="connman +introspection kernel_linux networkmanager"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	?? ( connman networkmanager )
+"
+
+# prefix: uuid dependency can be adapted to non-linux platforms
+RDEPEND="${PYTHON_DEPS}
+	>=net-libs/gssdp-0.14.15:0=[introspection?,${MULTILIB_USEDEP}]
+	>=net-libs/libsoup-2.48.0:2.4[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
+	>=sys-apps/util-linux-2.24.1-r3[${MULTILIB_USEDEP}]
+	introspection? (
+			>=dev-libs/gobject-introspection-1.36:=
+			$(vala_depend) )
+	connman? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	networkmanager? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	!net-libs/gupnp-vala
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.14
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	use introspection && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	local backend=unix
+	use kernel_linux && backend=linux
+	use connman && backend=connman
+	use networkmanager && backend=network-manager
+
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		$(multilib_native_use_enable introspection) \
+		--disable-static \
+		--with-context-manager=${backend}
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	python_foreach_impl python_doscript tools/gupnp-binding-tool
+}