[gentoo-commits] repo/gentoo:master commit in: media-video/unifi-video/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     860427f97bf7fd81a897008bb0bed630ea5fee6a
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 30 12:33:18 2018 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Mon Jul 30 12:33:42 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=860427f9

media-video/unifi-video: revbump for conf permission issue

Also restrict jre dep to :1.8

Package-Manager: Portage-2.3.44, Repoman-2.3.10

 .../unifi-video/unifi-video-3.9.7-r1.ebuild        | 83 ++++++++++++++++++++++
 1 file changed, 83 insertions(+)

diff --git a/media-video/unifi-video/unifi-video-3.9.7-r1.ebuild b/media-video/unifi-video/unifi-video-3.9.7-r1.ebuild
new file mode 100644
index 00000000000..c186c92adee
--- /dev/null
+++ b/media-video/unifi-video/unifi-video-3.9.7-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit systemd user
+
+MY_PV="${PV/_beta/-beta.}"
+DESCRIPTION="UniFi Video Server"
+HOMEPAGE="https://www.ubnt.com/download/unifi-video/"
+SRC_URI="https://dl.ubnt.com/firmwares/ufv/v${MY_PV}/unifi-video.Ubuntu16.04_amd64.v${MY_PV}.deb"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+RESTRICT="mirror"
+
+DEPEND=""
+RDEPEND="dev-db/mongodb
+	dev-java/commons-daemon
+	sys-apps/lsb-release
+	sys-libs/libcap
+	virtual/jre:1.8"
+
+S=${WORKDIR}
+QA_PREBUILT="/usr/lib*/${PN}/lib/*.so /usr/lib*/${PN}/bin/*"
+
+pkg_setup() {
+	enewuser ${PN}
+	enewgroup ${PN}
+}
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}"/data.tar.gz
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/commons-daemon-move.patch
+	sed -i usr/sbin/${PN} \
+		-e '/require_root$/d' \
+		-e '/update_limits$/d' \
+		-e '/ulimit/d' \
+		-e '/coredump_filter/d' || die
+	default
+}
+
+src_install() {
+	static_dir="/usr/$(get_libdir)/${PN}"
+	#install static data
+	insinto ${static_dir}
+	doins -r usr/lib/${PN}/*
+	fperms -R +x ${static_dir}/bin
+	fowners -R ${PN}:${PN} ${static_dir}/conf/evostream/
+
+	#wrapper to work around mongodb-3.6 compat issue
+	exeinto ${static_dir}/bin/
+	newexe "${FILESDIR}"/mongod-wrapper mongod
+
+	#prepare runtime-data dirs which live in /var but are symlinked from static
+	#data dir, and are writable by non-root user
+	dodir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+	dosym ../../../var/log/${PN} ${static_dir}/logs
+
+	dodir /var/lib/${PN}/work
+	fowners ${PN}:${PN} /var/lib/${PN}/work
+	dosym ../../../var/lib/${PN}/work ${static_dir}/work
+
+	keepdir /var/lib/${PN}/data
+	fowners ${PN}:${PN} /var/lib/${PN}/data
+	dosym ../../../var/lib/${PN}/data ${static_dir}/data
+
+	echo "CONFIG_PROTECT=\"/var/lib/${PN}/data/system.properties\"" > "${T}"/99${PN}
+	doenvd "${T}"/99${PN}
+
+	into /usr
+	dosbin usr/sbin/${PN}
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}