From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1039515-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id C3CB6138334
	for <garchives@archives.gentoo.org>; Mon, 30 Jul 2018 09:15:46 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 8075BE09E4;
	Mon, 30 Jul 2018 09:15:45 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 1A3C9E09E4
	for <gentoo-commits@lists.gentoo.org>; Mon, 30 Jul 2018 09:15:44 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id B3FA6335C5D
	for <gentoo-commits@lists.gentoo.org>; Mon, 30 Jul 2018 09:15:42 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 84895386
	for <gentoo-commits@lists.gentoo.org>; Mon, 30 Jul 2018 09:15:40 +0000 (UTC)
From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Mart Raudsepp" <leio@gentoo.org>
Message-ID: <1532942039.8de2e61013ce30fcbbeaf6283d8258cb5eb74184.leio@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/gstreamer/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/gstreamer/Manifest media-libs/gstreamer/gstreamer-1.14.2.ebuild
X-VCS-Directories: media-libs/gstreamer/
X-VCS-Committer: leio
X-VCS-Committer-Name: Mart Raudsepp
X-VCS-Revision: 8de2e61013ce30fcbbeaf6283d8258cb5eb74184
X-VCS-Branch: master
Date: Mon, 30 Jul 2018 09:15:40 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: fc9e64b4-099f-4d8e-b626-519e5e9ef4bd
X-Archives-Hash: 39706a12d464f553e17067150a7099b7

commit:     8de2e61013ce30fcbbeaf6283d8258cb5eb74184
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 30 07:16:02 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Jul 30 09:13:59 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8de2e610

media-libs/gstreamer: bump to 1.14.2 for upstream bug fixes

Package-Manager: Portage-2.3.43, Repoman-2.3.10

 media-libs/gstreamer/Manifest                |   1 +
 media-libs/gstreamer/gstreamer-1.14.2.ebuild | 110 +++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/media-libs/gstreamer/Manifest b/media-libs/gstreamer/Manifest
index 72e0a83d2ce..6d32992eabb 100644
--- a/media-libs/gstreamer/Manifest
+++ b/media-libs/gstreamer/Manifest
@@ -1,3 +1,4 @@
 DIST gstreamer-0.10.36.tar.xz 3025876 BLAKE2B f0f70f483e8ccb2a294fb3bc8b51aac089f5e76522249b64e3e60e7b488a9e03b9300617e2c137bdcc0e3e61668b7b203e899f270f004e2dfcee0927fa7dfc3c SHA512 7468abb578398681d2adb0e9bbc9ee8ae25aaef72369d45a66ada6c67d1759afdce606cb32e68d9e30ae813196bdfef3d4d33202bc77839cc1fbf5fc436c1bd8
 DIST gstreamer-1.12.4.tar.xz 3177208 BLAKE2B cb859503edbe09cebbbfa70cb4edc5d433bbaa5b299e05921d30e6096f8765e17d449c45bd7d5ea3e4603ae46d337d4e3291b1d0456c7b72a7ebb41faad9e73a SHA512 849aa4ddf8ef465f2915e05d36fc0c31c2e31ae28be2fa38f8069a64a91b7347020fac5b881b7f3ee54c2198c3596138d49f27b09f258303834164a5d68b38a2
 DIST gstreamer-1.14.1.tar.xz 3252440 BLAKE2B c2142621b126926dd9ec886f0478154b3f0d9b7adebc6169200b8bc7e4cd089dfe77cab2b436bf3c74cbcae5f84c95afbd05ba282d0afe3e8e226e6bc0f33e33 SHA512 9cf16d79774293dd7fa10c08f6628b83f4e77f0386bebbfd47ded0498e4abd48eee1aee164af53d59fbea2d395e42eb5a12ef4b8f631bc4fd5d4f69545191f9b
+DIST gstreamer-1.14.2.tar.xz 3255404 BLAKE2B 290e8fec3eb6629a0e6e8f01c7c027fcc085f632afeac1ffe7bd4f1d8a9a3d3b78145334a11c91fcabea40b9f202a3b451ca55db13fd23be66c7167c76614932 SHA512 270dba318d15b54fff6e09d09d77dea13be55bbf82a5bb510efb43f954e234230505366cc6f19f5431e2dd24f5a7734daf5a89d9bd94de8302ed722df0e1eb84

diff --git a/media-libs/gstreamer/gstreamer-1.14.2.ebuild b/media-libs/gstreamer/gstreamer-1.14.2.ebuild
new file mode 100644
index 00000000000..ed4c8f8861f
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-1.14.2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1 multilib-minimal pax-utils
+
+DESCRIPTION="Open source multimedia framework"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+SRC_URI="https://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+caps +introspection nls +orc test unwind"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	caps? ( sys-libs/libcap[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	unwind? (
+		>=sys-libs/libunwind-1.2_rc1[${MULTILIB_USEDEP}]
+		dev-libs/elfutils[${MULTILIB_USEDEP}]
+	)
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	sys-devel/bison
+	sys-devel/flex
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )
+"
+# gtk-doc-am to install API docs
+
+src_configure() {
+	if [[ ${CHOST} == *-interix* ]] ; then
+		export ac_cv_lib_dl_dladdr=no
+		export ac_cv_func_poll=no
+	fi
+	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
+		# GCC groks this, but then refers to an implementation (___multi3,
+		# ___udivti3) that don't exist (at least I can't find it), so force
+		# this one to be off, such that we use 2x64bit emulation code.
+		export gst_cv_uint128_t=no
+	fi
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local completiondir=$(get_bashcompdir)
+	# Set 'libexecdir' to ABI-specific location for the library spawns
+	# helpers from there.
+	# Disable static archives and examples to speed up build time
+	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
+	local myconf=(
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		--disable-benchmarks
+		--disable-debug
+		--disable-examples
+		--disable-static
+		--disable-valgrind
+		--enable-check
+		$(use_with unwind)
+		$(use_with unwind dw)
+		$(multilib_native_use_enable introspection)
+		$(use_enable nls)
+		$(use_enable test tests)
+		--with-bash-completion-dir="${completiondir%/*}"
+		--with-package-name="GStreamer ebuild for Gentoo"
+		--with-package-origin="https://packages.gentoo.org/package/media-libs/gstreamer"
+	)
+
+	if use caps ; then
+		myconf+=( --with-ptp-helper-permissions=capabilities )
+	else
+		myconf+=(
+			--with-ptp-helper-permissions=setuid-root
+			--with-ptp-helper-setuid-user=nobody
+			--with-ptp-helper-setuid-group=nobody
+		)
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		local x
+		for x in gst libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install() {
+	# can't do "default", we want to install docs in multilib_src_install_all
+	emake DESTDIR="${D}" install
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/$(get_libdir)/gstreamer-${SLOT}/gst-plugin-scanner"
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}"
+}