[gentoo-commits] repo/gentoo:master commit in: media-libs/gegl/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     126677e3c0c35cb8151ded1d3802bb98e2e0455f
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 23 14:24:48 2018 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Mon Jul 23 14:27:25 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=126677e3

media-libs/gegl: 0.4.6

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 media-libs/gegl/Manifest          |   1 +
 media-libs/gegl/gegl-0.4.6.ebuild | 189 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 190 insertions(+)

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 17a8d2c45d4..c37c0e08687 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -6,3 +6,4 @@ DIST gegl-0.3.8.tar.bz2 5876259 BLAKE2B 24199148ffbef6454ea460d126c29f1cc8581e54
 DIST gegl-0.4.0.tar.bz2 6762190 BLAKE2B c138ee79806178f60eab2fae492fcf441dc49b54364abcf023f6ade0cb08d216200ae14a289af8b6da2f0eec97dc81d376469245d0aa6d6cabf269d42c0a83c0 SHA512 4e319e861f6a27f52d0d4920942abe3734e6015eaa76491ab55179d8c677ccf8eb7f4296ef43f55a5e77ae9e99bb2ba6f5bd20aa08f194e9d42a1159fae20c6e
 DIST gegl-0.4.2.tar.bz2 6781136 BLAKE2B 522d4e7b2ace519423a66b7e65faab49bd0740173be6a8e108ec95b65c0359937df7b142e0a68589a4d773b839689ad6cf2ee67c5ea5b89267d46199b23e3f15 SHA512 8d842f5e192d279529615e09da8a76b051baa9c257ac699eba5f8ce46b4511554949e35f494e99c190b1477a700e018e2243a9e84c3c79e331824ca364b6cefd
 DIST gegl-0.4.4.tar.bz2 6817195 BLAKE2B 928e91e61bfee8b9954992e1ad4dbc874a5f53ef5a8274a6805b2c7d9bb007e3ff9ab5e8fc0a767f7e7d05c327581231b42eebcc6f9781f9feb5abe17c22bbdf SHA512 6953bf7df225914ce9c8166f5a0490615664c69d5a66cf8ca805f75cfbe272186c7745d273fcde29c685e22a66d4483dbdf45064ec9c0007fd6d0b8aa3ebb164
+DIST gegl-0.4.6.tar.bz2 6931774 BLAKE2B c8fabc8efbcc21a3663c8a3a698e6bc072506a66a21b81e6696c37c81aec1458c695f773c554b6d98c2fd21a3d3ab7fcca4b2f6567ec9d4f94b1e925b9bc9ce5 SHA512 6df34b6e76318a375820bccac6efeb2792c737e47154902fcc08ef93cb45b978992ee263260c99f8e865964d80cd1fac6dc2d6c8e4453174df64a9044b57325e

diff --git a/media-libs/gegl/gegl-0.4.6.ebuild b/media-libs/gegl/gegl-0.4.6.ebuild
new file mode 100644
index 00000000000..c4ca39c3b74
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.6.ebuild
@@ -0,0 +1,189 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.gnome.org/gegl"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg2k lcms lensfun openexr raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	vala? ( introspection )
+"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.54
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.32:2
+	x11-libs/pango
+
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? (
+		>=media-video/ffmpeg-2.8:0=
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	virtual/jpeg:0=
+	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	>=media-libs/libpng-1.6.0:0=
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	dev-lang/perl
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	test? ( ffmpeg? ( media-libs/gexiv2 )
+		introspection? (
+		$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]') ) )
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.3.12-failing-tests.patch
+)
+
+src_prepare() {
+	default
+
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	eautoreconf
+
+	gnome2_environment_reset
+
+	use vala && vala_src_prepare
+}
+
+_use_with_both() {
+	if use "$1" && use "$2"; then
+		echo "--with-$3"
+	else
+		echo "--without-$3"
+	fi
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+
+	# Also please note that:
+	#
+	#  - Some auto-detections are not patched away since the docs are
+	#    not built (--disable-docs, lack of --enable-gtk-doc) and these
+	#    tools affect re-generation of docs, only
+	#    (e.g. ruby, asciidoc, dot (of graphviz), enscript)
+	#
+	#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+	#    but needed during testing
+	#
+	#  - Parameter --disable-workshop disables any use of Lua, effectivly
+	#
+	#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+	#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+	#
+	#  - There are two checks for dot, one controllable by --with(out)-graphviz
+	#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+	#
+	#  - mrg is not in tree and gexiv2 support only has effect when mrg support
+	#    is enabled
+	#
+	# So that's why USE="exif graphviz lua v4l" got resolved.  More at:
+	# https://bugs.gentoo.org/show_bug.cgi?id=451136
+	#
+	econf \
+		--disable-docs \
+		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--program-suffix=-${SLOT} \
+		--with-gdk-pixbuf \
+		--with-pango \
+		--without-libspiro \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		--without-exiv2 \
+		$(use_with ffmpeg libavformat) \
+		$(_use_with_both ffmpeg test gexiv2) \
+		--without-graphviz \
+		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
+		--without-lua \
+		--without-mrg \
+		$(use_with openexr) \
+		$(use_with raw libraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
+}
+
+src_compile() {
+	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}