[gentoo-commits] repo/gentoo:master commit in: net-mail/notmuch/

["Amadeusz Piotr Żołnowski" <aidecoe@gentoo.org>]

commit:     0710463545023d0d2979c80dd51572d923d2ee77
Author:     Amadeusz Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 22 22:33:07 2018 +0000
Commit:     Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Sun Jul 22 22:34:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07104635

net-mail/notmuch: Bump version

 net-mail/notmuch/Manifest            |   1 +
 net-mail/notmuch/notmuch-0.27.ebuild | 215 +++++++++++++++++++++++++++++++++++
 2 files changed, 216 insertions(+)

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index 68c90ff0c56..1875daaf322 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -7,3 +7,4 @@ DIST notmuch-0.25.3.tar.gz 883151 BLAKE2B 511f93c310e8b82f1b629735cbe626ab1ba8ea
 DIST notmuch-0.25.tar.gz 882093 BLAKE2B ea0f5568ec0bf6a1d2c177468f4ec25fabfd416162c01a0d861e78164f15f2cc0176e1a012250a2a6bb45a6c7c2f6ffa651ad15776d44fed8ec191026b0f04c7 SHA512 5f4961818c8c0350e3fbbedd86f407a55fecf211971003a770d99ea2db89bb6b98c2294e114d6abff4d40985f506b7f4b52736a7ee5c78390eb4f2363a65c6f5
 DIST notmuch-0.26.1.tar.gz 906523 BLAKE2B da0b06361d586d84bea5c6e28adf7850dcb119e9f70ae67e06ff1438b9d20f4b04707d3e6ee6e755d569d15b8a720506b4c242c0c84258e8f5c8996caa62fc47 SHA512 f0d95a0f03535495037c73ab18d1251ece505284736efa5a535fe9bc8aea33954b5c87e5dcdfd30670c8df53178294be520a63e5b19beac7d90f166e616d19dd
 DIST notmuch-0.26.2.tar.gz 907187 BLAKE2B 81212555d729bd05be2edfb0f3dfd604de9d5f3e99e79ebd24a195441bd3778c7c72abe0b6b569dc1cf2ad9d94af1cbe3ca3aff77f521888b7be2eb08444dde1 SHA512 ebd8460c5f08cb8c79dabc1bc1bc32e1f2e1f123d304bb20205d4dedb982186336fd43d0e39acf020ea2563278bee0a063ceb3bf276f1251c099d8fcdd5098e7
+DIST notmuch-0.27.tar.gz 912583 BLAKE2B 75bb13e9666bd2898f58e5ecdd6a180d0da21188665f107857e6729f057525bb7c94832d140de8ff7b3fd31b51e33bcbe5b59d3fc09ba9a854c1c05499df762e SHA512 7c58c6fe5c3b43a979c3a439a24106417120726fd688b456d9084388ddd7c88ab1b6d99cd4676101f085d60bb37099631caa286b76588fcb041bb004ff325515

diff --git a/net-mail/notmuch/notmuch-0.27.ebuild b/net-mail/notmuch/notmuch-0.27.ebuild
new file mode 100644
index 00000000000..84ffe93ca8d
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.27.ebuild
@@ -0,0 +1,215 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+	distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="https://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
+	test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y.  Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~x86 ~x64-solaris"
+REQUIRED_USE="
+	nmbug? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( crypt emacs python valgrind )
+	"
+IUSE="crypt doc emacs mutt nmbug python test valgrind"
+
+CDEPEND="
+	!!<app-shells/bash-completion-1.9
+	>=dev-libs/glib-2.22:2
+	|| (
+		>=dev-libs/gmime-3.0.3:3.0
+		>=dev-libs/gmime-2.6.21:2.6
+	)
+	>=dev-libs/xapian-1.2.7-r2:=
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	sys-apps/texinfo
+	>=sys-libs/zlib-1.2.5.2
+	sys-libs/talloc
+	crypt? ( || (
+		>=dev-libs/gmime-3.0.3:3.0[crypt]
+		>=dev-libs/gmime-2.6.21:2.6[smime]
+	) )
+	emacs? ( >=virtual/emacs-23 )
+	python? ( ${PYTHON_DEPS} )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
+		>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
+		crypt? ( app-crypt/gnupg dev-libs/openssl ) )
+	valgrind? ( dev-util/valgrind )
+	"
+RDEPEND="${CDEPEND}
+	crypt? ( app-crypt/gnupg )
+	nmbug? ( dev-vcs/git )
+	mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
+		dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
+		virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
+		virtual/perl-Pod-Parser )
+	"
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+
+bindings() {
+	local ret=0
+
+	if use $1; then
+		pushd bindings/$1 || die
+		shift
+		"$@"
+		ret=$?
+		popd || die
+	fi
+
+	return $ret
+}
+
+pkg_pretend() {
+	if has_version '<net-mail/notmuch-0.18'; then
+		ewarn
+		ewarn "There are few not backward compatible changes between"
+		ewarn "<notmuch-0.18 and >=notmuch-0.18.  See NEWS file"
+		ewarn "(0.18 section) for details before first use!"
+		ewarn
+	fi
+}
+
+pkg_setup() {
+	if use emacs; then
+		elisp-need-emacs 23 || die "Emacs version too low"
+	fi
+}
+
+src_unpack() {
+	unpack "${P}".tar.gz
+	if use test; then
+		mkdir -p "${S}"/test/test-databases || die
+		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	bindings python distutils-r1_src_prepare
+	bindings python mv README README-python || die
+	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+	# assure that new Makefile.config will be generated
+	rm -f Makefile.config || die
+
+	if use test; then
+		append-cflags -g
+		append-cxxflags -g
+	fi
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bashcompletiondir="$(get_bashcompdir)"
+		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+		--without-desktop
+		--without-ruby
+		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+		$(use_with emacs)
+		$(use_with doc api-docs)
+	)
+	tc-export CC CXX
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	V=1 default
+	bindings python distutils-r1_src_compile
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		emake notmuch-mutt.1
+		popd || die
+	fi
+
+	if use doc; then
+		pydocs() {
+			pushd docs || die
+			emake html
+			rm -r html/_sources || die
+			rm html/{objects.inv,.buildinfo} || die
+			mkdir -p ../html && mv html ../html/python || die
+			popd || die
+		}
+		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+	fi
+}
+
+src_test() {
+	pax-mark -m notmuch
+	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
+	pax-mark -ze notmuch
+}
+
+src_install() {
+	default
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+	fi
+
+	if use nmbug; then
+		dobin devel/nmbug/nmbug
+		dobin devel/nmbug/notmuch-report
+	fi
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		dobin notmuch-mutt
+		doman notmuch-mutt.1
+		insinto /etc/mutt
+		doins notmuch-mutt.rc
+		dodoc README-mutt
+		popd || die
+	fi
+
+	DOCS="" bindings python distutils-r1_src_install
+	use doc && bindings python dodoc -r html
+}
+
+pkg_preinst() {
+	if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+		elog "To enable notmuch support in mutt, add the following line into"
+		elog "your mutt config file, please:"
+		elog ""
+		elog "  source /etc/mutt/notmuch-mutt.rc"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	if has_version '<dev-libs/xapian-1.4'; then
+		elog "Regular expression searches supported for from: and subject:"
+		elog "require >=dev-libs/xapian-1.4."
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}