[gentoo-commits] repo/gentoo:master commit in: sci-electronics/puff/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     cc10cf6b5886ab8d72b2fb098e4ee761635bca11
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Mon Jul  9 18:22:38 2018 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Sun Jul 22 11:39:39 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc10cf6b

sci-electronics/puff: EAPI7, improve ebuild

Closes: https://github.com/gentoo/gentoo/pull/9162

 sci-electronics/puff/puff-20100127-r1.ebuild | 47 ++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/sci-electronics/puff/puff-20100127-r1.ebuild b/sci-electronics/puff/puff-20100127-r1.ebuild
new file mode 100644
index 00000000000..9ea282b9822
--- /dev/null
+++ b/sci-electronics/puff/puff-20100127-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+DESCRIPTION="microwave CAD software"
+HOMEPAGE="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/puff/"
+SRC_URI="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/${PN}/${P}.tgz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="x11-libs/libX11"
+DEPEND="${RDEPEND}
+	dev-lang/fpc"
+
+src_prepare() {
+	default
+	# fix lib path for X11 and dont ignore LDFLAGS
+	sed -i -e "s#lib\\\/#$(get_libdir)\\\/#" \
+		-e 's/CFLAGS/#CFLAGS/' \
+		-e 's/link.res pu/link.res $(LDFLAGS) pu/' Makefile || die
+}
+
+src_compile() {
+	LDFLAGS="$(raw-ldflags)"
+	emake -j1
+}
+
+src_install() {
+	dobin puff
+
+	dodoc changelog.txt README.txt
+	newdoc "Puff Manual.pdf" Puff_Manual.pdf
+
+	insinto /usr/share/${PN}
+	doins setup.puf
+	doins -r orig_dev_and_puf_files
+}
+
+pkg_postinst() {
+	elog "You must copy /usr/share/${PN}/setup.puf into your working directory"
+	elog "before using the program."
+}