[gentoo-commits] repo/gentoo:master commit in: x11-drivers/xf86-video-amdgpu/

["Matt Turner" <mattst88@gentoo.org>]

commit:     568eca2a556b1f5ba09d5486374cec7346ab1fce
Author:     Marty E. Plummer <hanetzer <AT> startmail <DOT> com>
AuthorDate: Tue Jul 17 00:32:31 2018 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Jul 17 14:15:21 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=568eca2a

x11-drivers/xf86-video-amdgpu: port to EAPI 7

Package-Manager: Portage-2.3.41, Repoman-2.3.9

 .../xf86-video-amdgpu-18.0.1-r1.ebuild             | 51 ++++++++++++++++++++++
 .../xf86-video-amdgpu-9999.ebuild                  | 50 ++++++++++++++++-----
 2 files changed, 90 insertions(+), 11 deletions(-)

diff --git a/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-18.0.1-r1.ebuild b/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-18.0.1-r1.ebuild
new file mode 100644
index 00000000000..f3cb6236644
--- /dev/null
+++ b/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-18.0.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Accelerated Open Source driver for AMDGPU cards"
+HOMEPAGE="https://www.x.org/wiki/ https://cgit.freedesktop.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/xorg/driver/xf86-video-amdgpu.git"
+	inherit autotools git-r3
+	LIVE_DEPEND=">=x11-misc/util-macros-1.18"
+else
+	SRC_URI="mirror://xorg/driver/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=x11-libs/libdrm-2.4.78[video_cards_amdgpu]
+	x11-libs/libpciaccess
+	x11-base/xorg-server[glamor(-),-minimal]
+"
+DEPEND="
+	${LIVE_DEPEND}
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		--enable-glamor
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}

diff --git a/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-9999.ebuild b/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-9999.ebuild
index 90a06199708..f3cb6236644 100644
--- a/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-9999.ebuild
+++ b/x11-drivers/xf86-video-amdgpu/xf86-video-amdgpu-9999.ebuild
@@ -1,23 +1,51 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-XORG_DRI="always"
-inherit xorg-2
+EAPI=7
 
-if [[ ${PV} == 9999* ]]; then
-	SRC_URI=""
+DESCRIPTION="Accelerated Open Source driver for AMDGPU cards"
+HOMEPAGE="https://www.x.org/wiki/ https://cgit.freedesktop.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/xorg/driver/xf86-video-amdgpu.git"
+	inherit autotools git-r3
+	LIVE_DEPEND=">=x11-misc/util-macros-1.18"
 else
+	SRC_URI="mirror://xorg/driver/${P}.tar.bz2"
 	KEYWORDS="~amd64 ~x86"
 fi
 
-DESCRIPTION="Accelerated Open Source driver for AMDGPU cards"
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=x11-libs/libdrm-2.4.78[video_cards_amdgpu]
+	x11-libs/libpciaccess
+	x11-base/xorg-server[glamor(-),-minimal]
+"
+DEPEND="
+	${LIVE_DEPEND}
+	${RDEPEND}
+"
 
-RDEPEND=">=x11-libs/libdrm-2.4.78[video_cards_amdgpu]
-	x11-base/xorg-server[glamor(-)]"
-DEPEND="${RDEPEND}"
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
 
 src_configure() {
-	XORG_CONFIGURE_OPTIONS="--enable-glamor"
-	xorg-2_src_configure
+	local econfargs=(
+		--enable-glamor
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
 }