[gentoo-commits] repo/gentoo:master commit in: media-libs/lilv/

["Matt Thode" <prometheanfire@gentoo.org>]

commit:     6d0bfbcf4988e474a5c31ea2485501e66f95680b
Author:     nado <nado <AT> troglodyte <DOT> be>
AuthorDate: Wed Jul 11 07:50:17 2018 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Thu Jul 12 18:59:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6d0bfbcf

media-libs/lilv: add env file to ease prefix support

LV2_PATH is checked by lilv tools to find lv2 plugins
It is necessary to specify its path in prefix installs

Package-Manager: Portage-2.3.41, Repoman-2.3.9
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 media-libs/lilv/lilv-0.24.2-r3.ebuild | 60 +++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/media-libs/lilv/lilv-0.24.2-r3.ebuild b/media-libs/lilv/lilv-0.24.2-r3.ebuild
new file mode 100644
index 00000000000..9b5c50d8fcf
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.2-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit python-any-r1 waf-utils bash-completion-r1 multilib-build multilib-minimal
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="http://drobilla.net/software/lilv/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~x86"
+IUSE="doc +dyn-manifest static-libs test"
+
+RDEPEND=">=media-libs/lv2-1.14.0-r1[${MULTILIB_USEDEP}]
+	>=media-libs/sratom-0.6.0-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/serd-0.28.0-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/sord-0.16.0-r1[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+
+DOCS=( "AUTHORS" "NEWS" "README" )
+
+src_prepare() {
+	eapply "${FILESDIR}/includedir.patch"
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--no-bash-completion \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "") \
+		$(usex dyn-manifest --dyn-manifest "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	newbashcomp utils/lilv.bash_completion ${PN}
+	dodir /etc/env.d
+	echo "LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2" > "${ED}/etc/env.d/60lv2"
+}