[gentoo-commits] repo/gentoo:master commit in: dev-python/python-efl/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     df17cad85c24d2c88be928d7cecc443080ceab15
Author:     Joonas Niilola <juippis <AT> gmail <DOT> com>
AuthorDate: Sat Jul  7 11:19:45 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jul  7 13:53:51 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=df17cad8

dev-python/python-efl: 1.20.0 depends on =dev-libs/efl-1.20*

Package-Manager: Portage[mgorny]-2.3.36.1

 dev-python/python-efl/python-efl-1.20.0-r1.ebuild | 71 +++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/dev-python/python-efl/python-efl-1.20.0-r1.ebuild b/dev-python/python-efl/python-efl-1.20.0-r1.ebuild
new file mode 100644
index 00000000000..df7efa876ce
--- /dev/null
+++ b/dev-python/python-efl/python-efl-1.20.0-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for Enlightenment Foundation Libraries"
+HOMEPAGE="https://phab.enlightenment.org/w/projects/python_bindings_for_efl/"
+SRC_URI="https://download.enlightenment.org/rel/bindings/python/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	=dev-libs/efl-1.20*
+	>=dev-python/dbus-python-0.83[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-python/cython-0.21[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		>=dev-python/sphinx-1.1[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+"
+
+python_compile_all() {
+	if use doc ; then
+		# Point sphinx to right location with built sources
+		sed -i 's|"../build/"+d|"'"${BUILD_DIR}"'/lib"|g' doc/conf.py || die
+
+		esetup.py build_doc --build-dir "${S}"/build/doc/
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${S}"/tests || die
+
+	# Tries to download a file under /tmp
+	rm -f ecore/test_09_file_download.py || die
+
+	# Tries to use that file which failed to download
+	rm -f ecore/test_10_file_monitor.py || die
+
+	# Seems to need connman up and running during the test, requires:
+	# net-misc/connman
+	# dev-libs/efl[connman]
+	rm -f ecore/test_11_con.py || die
+
+	# Test fails because of deleted files above
+	sed -i 's/>= 13/>= 10/g' ecore/test_08_exe.py || die
+
+	sed -i 's:verbosity=1:verbosity=3:' 00_run_all_tests.py || die
+	${PYTHON} 00_run_all_tests.py --verbose || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc ; then
+		local HTML_DOCS=( build/doc/html/. )
+	fi
+
+	distutils-r1_python_install_all
+}