[gentoo-commits] proj/gnome:master commit in: app-accessibility/orca/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     cc6f4919d4e880249a3a342ec81a74e33a6fd881
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 24 19:25:22 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Jun 24 19:33:23 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=cc6f4919

app-accessibility/orca: 3.24.0 → 3.26.0

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Manifest-Sign-Key: 0x5A56C8CD0C13248A

 app-accessibility/orca/metadata.xml       | 18 ++++++++
 app-accessibility/orca/orca-3.26.0.ebuild | 72 +++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/app-accessibility/orca/metadata.xml b/app-accessibility/orca/metadata.xml
new file mode 100644
index 00000000..81828abc
--- /dev/null
+++ b/app-accessibility/orca/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+<use>
+	<flag name="braille">Enable braille support</flag>
+</use>
+<longdescription>
+	Orca is a flexible, extensible, and powerful assistive technology
+	for people with visual impairments. Using various combinations of
+	speech synthesis, braille, and magnification, Orca helps provide
+	access to applications and toolkits that support the AT-SPI (e.g.,
+	the GNOME desktop).
+</longdescription>
+</pkgmetadata>

diff --git a/app-accessibility/orca/orca-3.26.0.ebuild b/app-accessibility/orca/orca-3.26.0.ebuild
new file mode 100644
index 00000000..fc9d9b12
--- /dev/null
+++ b/app-accessibility/orca/orca-3.26.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="threads"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.18:2
+	>=app-accessibility/at-spi2-core-2.18:2[introspection]
+	>=dev-libs/atk-2.10
+	>=dev-libs/glib-2.28:2
+	dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.18:3[${PYTHON_USEDEP}]
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	braille? (
+		>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+		dev-libs/liblouis[python,${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+	dev-libs/atk[introspection]
+	dev-python/pyatspi[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	dev-util/itstool
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
+			-i src/orca/orca || die
+		python_doscript src/orca/orca
+	}
+	python_foreach_impl run_in_build_dir installing
+}