[gentoo-commits] repo/gentoo:master commit in: media-sound/cantata/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     4d244ad3a4e4fb453abcb6dae1967f1125c1d96d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 23 19:18:38 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jun 23 19:56:11 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d244ad3

media-sound/cantata: 2.3.1 version bump

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 media-sound/cantata/Manifest             |   1 +
 media-sound/cantata/cantata-2.3.1.ebuild | 124 +++++++++++++++++++++++++++++++
 2 files changed, 125 insertions(+)

diff --git a/media-sound/cantata/Manifest b/media-sound/cantata/Manifest
index 672a3131729..28f944978e8 100644
--- a/media-sound/cantata/Manifest
+++ b/media-sound/cantata/Manifest
@@ -1 +1,2 @@
 DIST cantata-2.2.0.tar.bz2 2251649 BLAKE2B 9b28a4e3a77245fcf00f81780adecdc51e066f068798f92300ef8527872313f5fb56d4b90a6f5511caf951ba9fcd5c094dd5e9062fe3d314b75412b3e8e03d37 SHA512 519a2e24c8b2a1c98a2006a1f590945e1bd5e98a2c3a1b5da23e40f2297f1477d48d69b48ec669219f5ab8fdc955486fe29db6914abeef1fba2a47377f694ecd
+DIST cantata-2.3.1.tar.bz2 2414702 BLAKE2B c44f7e95091dd4f84e630236e7f681d2ea47cd90705cdeeb17d3e892d4e0b978f88d4cb648841543494670c5dbc1a00ba9e2377dfd684b2fdee9223d4b6b28e3 SHA512 8199b08b1f3d2111fc50fbc4e5b1edced6ac480fd213a11eee569deeebf3a3f1167c2b53c3117bb90b2b81b46792c56b99b65eae5d2b290c0f3b3f90736108e5

diff --git a/media-sound/cantata/cantata-2.3.1.ebuild b/media-sound/cantata/cantata-2.3.1.ebuild
new file mode 100644
index 00000000000..4bc76c731c1
--- /dev/null
+++ b/media-sound/cantata/cantata-2.3.1.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="cs da de en_GB es fr hu it ja ko pl ru zh_CN"
+inherit cmake-utils gnome2-utils l10n qmake-utils xdg-utils
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI="https://github.com/CDrummond/cantata/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cdda cddb cdio http-server mtp musicbrainz replaygain streaming taglib udisks zeroconf"
+REQUIRED_USE="
+	?? ( cdda cdio )
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( || ( cdio cdda ) taglib )
+	cdio? ( udisks || ( cddb musicbrainz ) )
+	mtp? ( taglib udisks )
+	musicbrainz? ( || ( cdio cdda ) taglib )
+	replaygain? ( taglib )
+"
+
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+	sys-libs/zlib
+	virtual/libudev:=
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	cdio? ( dev-libs/libcdio-paranoia )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5= )
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	streaming? ( media-video/vlc:0= )
+	taglib? (
+		media-libs/taglib[asf(+),mp4(+)]
+		udisks? ( sys-fs/udisks:2 )
+	)
+	zeroconf? ( net-dns/avahi )
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-lang/perl[ithreads]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/linguist-tools:5
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.2.0-headers.patch"
+)
+
+src_prepare() {
+	remove_locale() {
+		rm "translations/${PN}_${1}".ts || die
+	}
+
+	cmake-utils_src_prepare
+
+	# Unbundle 3rd party libs
+	rm -r 3rdparty/{ebur128,qtsingleapplication} || die
+
+	l10n_find_plocales_changes "translations" "${PN}_" ".ts"
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCANTATA_HELPERS_LIB_DIR="$(get_libdir)"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_CDIOPARANOIA=$(usex cdio)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_HTTP_STREAM_PLAYBACK=$(usex streaming)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	has_version media-sound/mpd || \
+		elog "An instance of media-sound/mpd, local or remote, is required to set up Cantata."
+
+	if ! has_version app-misc/media-player-info; then
+		elog "Install app-misc/media-player-info to enable identification"
+		elog "and querying of portable media players"
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}