[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-stream/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     7da8d14b06a199dc1cf7e69de9a83455bfb4829f
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 20 20:52:58 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Jun 20 20:52:58 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7da8d14b

dev-python/jaraco-stream: bump to 1.2, Python 3.6, PyPy{,3}

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 dev-python/jaraco-stream/Manifest                 |  1 +
 dev-python/jaraco-stream/jaraco-stream-1.2.ebuild | 58 +++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/jaraco-stream/Manifest b/dev-python/jaraco-stream/Manifest
index f7f05e9432c..0f2a55a3ac9 100644
--- a/dev-python/jaraco-stream/Manifest
+++ b/dev-python/jaraco-stream/Manifest
@@ -1,2 +1,3 @@
 DIST jaraco.stream-1.1.1.tar.gz 6115 BLAKE2B 0994abe3c9688722c76e656e87166fa60d4bf45fb22ccc826227629bffb60fe0be78bb7a5f9f00b8766b5ce26d641d4b347d6c0fc73c426b424c230cb7d625b6 SHA512 65c8d1652a0d63506cc3cadee590664e6a99e2f770d26f0cea1dce07c54ffe308e1df8619bc728ea81c5ac43c9c6731fe9f71e5d38d2674c4e0d63d635bb5112
 DIST jaraco.stream-1.1.tar.gz 4887 BLAKE2B 6942db399e3821b176e5c966647aa9337e31dbfe533cbd790b9531fb943b1e5fdb05fa350e9dabdff00817e59b434a0770de32f871176dea34042acf6e2f368a SHA512 5af385084623fbdfe86e9fb620f49b097dee164638bc99622ba557a26cda591e856f1fc4134bc7b73b8f7b61afaf2607686fe20c59c582324a65c22f39d74a13
+DIST jaraco.stream-1.2.tar.gz 7696 BLAKE2B fcc1aa8d26da17635b9ee7c68c278ae572cbe36a108cb30f5eb98c7ebfd2255aad499bed38ea044b28e820646b92e64602db0e2cdfc430169035882f7b6abe9b SHA512 47a96c1de12eb64e250c85d97429218606dc9bb212cf7b97e579763dd901ee063711c00307b7442be400856d3fd4e5994afbe1cb91a99e233541ffd7ff4024b9

diff --git a/dev-python/jaraco-stream/jaraco-stream-1.2.ebuild b/dev-python/jaraco-stream/jaraco-stream-1.2.ebuild
new file mode 100644
index 00000000000..9c05682fdec
--- /dev/null
+++ b/dev-python/jaraco-stream/jaraco-stream-1.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Routines for handling streaming data"
+HOMEPAGE="https://github.com/jaraco/jaraco.stream"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Skip one test which requires network access
+	# Override pytest options to skip flake8
+	PYTHONPATH=. py.test --ignore=jaraco/stream/test_gzip.py \
+		--override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}