[gentoo-commits] repo/gentoo:master commit in: net-libs/mbedtls/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     24fbfc8bae85954873e8edcb141a3eddf6004cc4
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 19 00:02:31 2018 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Tue Jun 19 00:02:31 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24fbfc8b

net-libs/mbedtls: version bumps to 2.7.4 and 2.11.0

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 net-libs/mbedtls/Manifest              |  2 +
 net-libs/mbedtls/mbedtls-2.11.0.ebuild | 93 ++++++++++++++++++++++++++++++++++
 net-libs/mbedtls/mbedtls-2.7.4.ebuild  | 93 ++++++++++++++++++++++++++++++++++
 3 files changed, 188 insertions(+)

diff --git a/net-libs/mbedtls/Manifest b/net-libs/mbedtls/Manifest
index 6d49624dea5..58022f1eae9 100644
--- a/net-libs/mbedtls/Manifest
+++ b/net-libs/mbedtls/Manifest
@@ -1,5 +1,7 @@
 DIST mbedtls-2.10.0.tar.gz 2190139 BLAKE2B f4e6da0bc433992a79088a86c7bad48564e5d8eca110633960c8197becf1fb64b77e36f2bd63e241ff0a3eb86aae1b6b538de2043e1bb6626b9b18fa9951db91 SHA512 a1dcb46d3e27c93b511a0dc846b5ed6dc35992cdcf04fce6ad83f5a92440d11d60a07e0fec64f9d6c5e2f27365bdd7a557a35af4ff250b342adbde6193240a95
+DIST mbedtls-2.11.0.tar.gz 2224911 BLAKE2B adbcdb9e002fc2d84e345aec00aaae1cbef67f686895a45e6263339f0d7c9d0453d81d6bf4b30c31d6c4db96ab9d631918fc93e5d361e0b305053462b7fbf64e SHA512 301ddc6757be32aaa8ddbfd6c665a1d78c4869007a5aff954b54479c26f90d25bbfcb8c866dd6ae73a8222123928355e84ca5b59d24512d2bfdf1cdc41050e29
 DIST mbedtls-2.7.2.tar.gz 2127772 BLAKE2B d66c65f0d974baf97ae361e64db5028af6c402ea248a785009b422d993deaa4facee98dd338ee4b5d36087fd07e679069fc4fb57cce548097d1f788cedb825fa SHA512 52455b68744a3c220aed7346d19c7b9bebd3a065406242b446816a3b02325d72005b5c381b158bfff90e2fe5854064629b297fbec95fea3ad203bfae51a15cab
 DIST mbedtls-2.7.3.tar.gz 2145554 BLAKE2B 442d840f7046ae63508528fe76e9a12d438f14eb0468a2617cc18df8223105aa696c0b676193891359c8fbd56771acc2690760259a9ab6345883c63cc634c6dd SHA512 f1eb1ec4d4cdbe26434df6d17d4af72ef5bd2f370177f5ce787ab86ae6bcf200f221ddfdc5948f87e7da9f9e04ffddf8b68e83e203de2f8c0dca8c8594414b23
+DIST mbedtls-2.7.4.tar.gz 2147905 BLAKE2B 74473f53f241969485db0941339b1340f92d4c676d99f92734b9f5b64e76c2849b9a0f1def24e1569af8c78680fd2d26af68cac04f8d3ea916a67251bd6c3094 SHA512 530e2bb7d8dcd0dfcfb1c645f25bab6ca4c2004f988449e189e822223452e237f2ed86b901814c5c80d380701c151e160faea6d7c20cbeb198fe0908c8e534fe
 DIST mbedtls-2.8.0.tar.gz 2132562 BLAKE2B ac0a67c51e4aeb59e947d16039b20de680ccd7daf372652c0a7d1a6694ce8fe213f959b47a4335cda236575d8f491c84a413ae2f408e86600519ac66a31f8c1a SHA512 baa2024e26cb1d772a525348cdcc84e2b5eabf58642d8c792fe88cf6c539b36f14e80d592e85bc474f6be036513ed4b8bc86f5808ad4f5b08f25ca7e43dc3921
 DIST mbedtls-2.9.0.tar.gz 2163543 BLAKE2B b47e6242b5bad4f571bd900960e20ec0266e6f9f25c96df85c7d983dfa3d71f8b842b90f112eb69a09bf99ed3ef7c059c2c2d522ba66e92f4c9097754985323a SHA512 5490822aae18dfb3eb2cc94e673a575daf0cdaf9a4867ff84f0df9749376ea5c54a3f67902b4b86e2a853508af0585684618f9edac8bd92352cd3ca4461bda1c

diff --git a/net-libs/mbedtls/mbedtls-2.11.0.ebuild b/net-libs/mbedtls/mbedtls-2.11.0.ebuild
new file mode 100644
index 00000000000..3172e24a392
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.11.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/11" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs test threads zlib"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake-utils_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED%/}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}

diff --git a/net-libs/mbedtls/mbedtls-2.7.4.ebuild b/net-libs/mbedtls/mbedtls-2.7.4.ebuild
new file mode 100644
index 00000000000..a992986693d
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.7.4.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/10" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs test threads zlib"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake-utils_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED%/}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}