[gentoo-commits] repo/gentoo:master commit in: net-p2p/qbittorrent/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     81428be0199d5d0e6b4cc9846f54a2e730101775
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 14 14:41:08 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Thu Jun 14 14:41:27 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=81428be0

net-p2p/qbittorrent: Version bump

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 net-p2p/qbittorrent/Manifest                 |  1 +
 net-p2p/qbittorrent/qbittorrent-4.1.1.ebuild | 65 ++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index e7f74c0ceae..1e782c2dc82 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1 +1,2 @@
 DIST qbittorrent-4.0.4.tar.xz 4279752 BLAKE2B 6385040d1179814e3290fb1c7b2d1e0b5782144663d12a067c43a2d8a47d0f0cfc0633c69f183db70eab2591ef100f39b07ea2d5e3cbca3a4d149ccb70e4d838 SHA512 ead0a306242d883673e13f9e6dc5ad83d4624c3d7ffb586aff78c03f7685e89b6a6c8640fff6a1b251565892178d37f4a64d45d0ce18935a212ca39302a28969
+DIST qbittorrent-4.1.1.tar.gz 7464014 BLAKE2B be005fbecd1d2c9ee977fbdc6782bbad9708e3c2c6d46deb5831ae4e7457954cb95ae87850b759e81e87e345ca682acfcd23684b7704c437c4261ebb5bb46f5d SHA512 700c084b97556ba85276b42e46f77d5f7896052ce02ba052cd4b3e6967c8a848c27bcf63a289bf8276b38841bb9a80b9ec16335c3feb30dce0851170f54d101e

diff --git a/net-p2p/qbittorrent/qbittorrent-4.1.1.ebuild b/net-p2p/qbittorrent/qbittorrent-4.1.1.ebuild
new file mode 100644
index 00000000000..fac9e4a29be
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-4.1.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="https://www.qbittorrent.org/
+	  https://github.com/qbittorrent/qBittorrent"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+	SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+	S="${WORKDIR}/qBittorrent-release-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug webui +X"
+REQUIRED_USE="dbus? ( X )"
+
+RDEPEND="
+	>=dev-libs/boost-1.62.0-r1:=
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5(+),X?]
+	dev-qt/qtxml:5
+	>=net-libs/libtorrent-rasterbar-1.0.6:0=
+	dev-libs/geoip
+	sys-libs/zlib
+	dbus? ( dev-qt/qtdbus:5 )
+	X? (
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSTEM_QTSINGLEAPPLICATION=ON
+		-DDBUS=$(usex dbus)
+		-DGUI=$(usex X)
+		-DWEBUI=$(usex webui)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}