[gentoo-commits] proj/gnome:master commit in: dev-util/devhelp/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     a5578ea112d3a0574b46f7e43972edca230e66c5
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun May 27 11:00:31 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun May 27 12:47:01 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=a5578ea1

dev-util/devhelp: 3.24.0 → 3.26.1

Various UI changes. Important code refactoing. Improved API
documentation.

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Manifest-Sign-Key: 0x5A56C8CD0C13248A

 dev-util/devhelp/devhelp-3.26.1.ebuild | 68 ++++++++++++++++++++++++++++++++++
 dev-util/devhelp/metadata.xml          | 11 ++++++
 2 files changed, 79 insertions(+)

diff --git a/dev-util/devhelp/devhelp-3.26.1.ebuild b/dev-util/devhelp/devhelp-3.26.1.ebuild
new file mode 100644
index 00000000..092f711b
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.26.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+# gedit-3.8 is python3 only, this also per:
+# https://bugzilla.redhat.com/show_bug.cgi?id=979450
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-2+"
+SLOT="0/3-4" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gedit +introspection"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.38:2[dbus]
+	>=x11-libs/gtk+-3.22:3
+	>=net-libs/webkit-gtk-2.6.0:4
+	gnome-base/gsettings-desktop-schemas
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+[introspection] )
+"
+# libxml2+gdk-pixbuf required for glib-compile-resources
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/libxml2
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	x11-libs/gdk-pixbuf:2
+"
+# eautoreconf requires:
+#  dev-libs/appstream-glib
+#  sys-devel/autoconf-archive
+
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if ! use gedit ; then
+		sed -e '/SUBDIRS/ s/gedit-plugin//' -i misc/Makefile.{am,in} || die
+	fi
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		myconf="--with-compile-warnings=no"
+	fi
+	gnome2_src_configure \
+		$(use_enable introspection) \
+		${myconf}
+}

diff --git a/dev-util/devhelp/metadata.xml b/dev-util/devhelp/metadata.xml
new file mode 100644
index 00000000..04f1a3c9
--- /dev/null
+++ b/dev-util/devhelp/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+<use>
+	<flag name="gedit">Install plugin for <pkg>app-editors/gedit</pkg></flag>
+</use>
+</pkgmetadata>