[gentoo-commits] repo/gentoo:master commit in: app-editors/retext/

["Aaron Bauman" <bman@gentoo.org>]

commit:     44f063eaf8c99bc8db3ed4e23fa13e737fad45df
Author:     Nils Freydank <holgersson <AT> posteo <DOT> de>
AuthorDate: Thu May 24 19:36:01 2018 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Fri May 25 22:31:50 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44f063ea

app-editors/retext: Revbump to backport fixes.

Bug: https://bugs.gentoo.org/show_bug.cgi?id=626824
Package-Manager: Portage-2.3.38, Repoman-2.3.9

 app-editors/retext/retext-7.0.1-r2.ebuild | 62 +++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-editors/retext/retext-7.0.1-r2.ebuild b/app-editors/retext/retext-7.0.1-r2.ebuild
new file mode 100644
index 00000000000..b69ab5bac2a
--- /dev/null
+++ b/app-editors/retext/retext-7.0.1-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+PLOCALES="ca cs cy da de es et eu fr hu it ja pl pt pt_BR ru sk sr sr@latin uk zh_TW"
+
+inherit distutils-r1 virtualx l10n xdg-utils
+
+MY_PN="ReText"
+MY_P="${MY_PN}-${PV/_/~}"
+
+DESCRIPTION="Simple editor for Markdown and reStructuredText"
+HOMEPAGE="https://github.com/retext-project/retext https://github.com/retext-project/retext/wiki"
+
+if [[ ${PV} == *9999 ]]
+	then
+		inherit git-r3
+		EGIT_REPO_URI="https://github.com/retext-project/retext.git"
+	else
+		SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+		KEYWORDS="~amd64 ~x86"
+		S="${WORKDIR}"/${MY_P}
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+spell"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	>=dev-python/markups-2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.3[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,network,printsupport,webengine,widgets,${PYTHON_USEDEP}]
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
+"
+
+remove_locale() {
+	find "${ED}" -name "retext_${1}.qm" -delete || die "Failed to remove locale ${1}."
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}