From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1025920-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2BF9B138330
for <garchives@archives.gentoo.org>; Fri, 25 May 2018 07:19:20 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 3C07FE07C7;
Fri, 25 May 2018 07:19:18 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 0955EE07C7
for <gentoo-commits@lists.gentoo.org>; Fri, 25 May 2018 07:19:17 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id AE8E4335C8C
for <gentoo-commits@lists.gentoo.org>; Fri, 25 May 2018 07:19:16 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 2A1032A3
for <gentoo-commits@lists.gentoo.org>; Fri, 25 May 2018 07:19:15 +0000 (UTC)
From: "Sven Wegener" <swegener@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sven Wegener" <swegener@gentoo.org>
Message-ID: <1527232742.813bc5e21b01b7abf32df1d01ef43a67ded2105f.swegener@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-dns/pdns/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-dns/pdns/Manifest net-dns/pdns/pdns-4.1.3.ebuild
X-VCS-Directories: net-dns/pdns/
X-VCS-Committer: swegener
X-VCS-Committer-Name: Sven Wegener
X-VCS-Revision: 813bc5e21b01b7abf32df1d01ef43a67ded2105f
X-VCS-Branch: master
Date: Fri, 25 May 2018 07:19:15 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 2651c473-c600-4fc8-9ba2-a85767405a97
X-Archives-Hash: acdf907301ba7186e84a5695b900b576
commit: 813bc5e21b01b7abf32df1d01ef43a67ded2105f
Author: Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Fri May 25 07:18:26 2018 +0000
Commit: Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Fri May 25 07:19:02 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=813bc5e2
net-dns/pdns: Version bump
Package-Manager: Portage-2.3.28, Repoman-2.3.9
net-dns/pdns/Manifest | 1 +
net-dns/pdns/pdns-4.1.3.ebuild | 155 +++++++++++++++++++++++++++++++++++++++++
2 files changed, 156 insertions(+)
diff --git a/net-dns/pdns/Manifest b/net-dns/pdns/Manifest
index 42d9a9c27e8..371482ffee5 100644
--- a/net-dns/pdns/Manifest
+++ b/net-dns/pdns/Manifest
@@ -2,3 +2,4 @@ DIST pdns-4.0.5.tar.bz2 1323468 BLAKE2B 7e10cc98177bfa4f81888e2598ab4f0ce83ee45e
DIST pdns-4.1.0.tar.bz2 1116905 BLAKE2B 91ec0f0cfa70966ff71dfb6302ed01355120ca1429d3c610c4abfb1b964cff78a6332700991bc259387e9095be03d3850da41750e93bb3ffe3db0e23562d156c SHA512 4b2b42f4893f8aac3cf07a6c8a3c999cb728a5907a710f1a5c9c8d08377ecb63e202e5eececbefc069c8f1d97a29b2aa607da7cf2bcc6335a72222418e409e77
DIST pdns-4.1.1.tar.bz2 1113659 BLAKE2B 916dd6ad815a867580d36668e70ec62991ccd45abafdcaa282a2d3edf7ea1b1ae4fc8add8f6b1ce5c8a8d76fc5bf6a6fa458202b7623842afabf7da593333585 SHA512 23e62ec39007e39a289945457e9b950cbeabf8581f477397341dfbd3592b7ccdede8f4c9ce653a47add07784d1a23116f9013c755eb11af1df383b49a8ca341d
DIST pdns-4.1.2.tar.bz2 1117225 BLAKE2B 6a4ffc7ea6ccf4dcde63f78c203efe4c17d3769785173211f4d98b9a1891d3d747b95f686c41c6197f28931302eb8389d4fe899409a98d5d83f71fbd15c36d78 SHA512 3fe9f5d8d87bfc77e98915d9019000b6bc0b91ed7ed363ba00a64321cc534290e23627f18a6ba87797a954f7c82b777f746f4f45eb70efb30fa2aa1a80c67a68
+DIST pdns-4.1.3.tar.bz2 1114829 BLAKE2B d379dafc438402df57674686073469aabaa442b174cd6e217d80878a64d103f753cae6b96be32efd841f3ae46cb333b4136b0a33e332f420e83553815f4024e0 SHA512 a5201cf48911188db0c70cb44a27b9a6cebc16f6b740abdadd283dd53feedeed9cfa16ab833b8230f24790f349a0f2ebcca653ca502bb9b2c75d08bd7c60140c
diff --git a/net-dns/pdns/pdns-4.1.3.ebuild b/net-dns/pdns/pdns-4.1.3.ebuild
new file mode 100644
index 00000000000..1dd30fc1895
--- /dev/null
+++ b/net-dns/pdns/pdns-4.1.3.ebuild
@@ -0,0 +1,155 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eutils multilib user toolchain-funcs versionator
+
+DESCRIPTION="The PowerDNS Daemon"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# other possible flags:
+# db2: we lack the dep
+# oracle: dito (need Oracle Client Libraries)
+# xdb: (almost) dead, surely not supported
+
+IUSE="botan debug doc geoip ldap libressl lua luajit mydns mysql opendbx postgres protobuf remote sodium sqlite systemd tools tinydns test"
+
+REQUIRED_USE="mydns? ( mysql )"
+
+RDEPEND="
+ libressl? ( dev-libs/libressl:= )
+ !libressl? ( dev-libs/openssl:= )
+ >=dev-libs/boost-1.35:=
+ botan? ( dev-libs/botan:2= )
+ lua? (
+ !luajit? ( dev-lang/lua:= )
+ luajit? ( dev-lang/luajit:= )
+ )
+ mysql? ( virtual/mysql )
+ postgres? ( dev-db/postgresql:= )
+ ldap? ( >=net-nds/openldap-2.0.27-r4 app-crypt/mit-krb5 )
+ sqlite? ( dev-db/sqlite:3 )
+ opendbx? ( dev-db/opendbx )
+ geoip? ( >=dev-cpp/yaml-cpp-0.5.1 dev-libs/geoip )
+ sodium? ( dev-libs/libsodium:= )
+ tinydns? ( >=dev-db/tinycdb-0.77 )
+ protobuf? ( dev-libs/protobuf )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}"/${P/_/-}
+
+src_configure() {
+ local dynmodules="pipe bind" # the default backends, always enabled
+
+ #use db2 && dynmodules+=" db2"
+ use ldap && dynmodules+=" ldap"
+ use lua && dynmodules+=" lua"
+ use mydns && dynmodules+=" mydns"
+ use mysql && dynmodules+=" gmysql"
+ use opendbx && dynmodules+=" opendbx"
+ #use oracle && dynmodules+=" goracle oracle"
+ use postgres && dynmodules+=" gpgsql"
+ use remote && dynmodules+=" remote"
+ use sqlite && dynmodules+=" gsqlite3"
+ use tinydns && dynmodules+=" tinydns"
+ use geoip && dynmodules+=" geoip"
+ #use xdb && dynmodules+=" xdb"
+
+ econf \
+ --disable-static \
+ --sysconfdir=/etc/powerdns \
+ --libdir=/usr/$(get_libdir)/powerdns \
+ --with-modules= \
+ --with-dynmodules="${dynmodules}" \
+ --with-mysql-lib=/usr/$(get_libdir) \
+ $(use_enable botan) \
+ $(use_enable debug verbose-logging) \
+ $(use_enable test unit-tests) \
+ $(use_enable tools) \
+ $(use_enable systemd) \
+ $(use_enable sodium libsodium) \
+ $(usex lua "$(use_with !luajit lua) $(use_with luajit)" \
+ '--without-lua --without-luajit') \
+ $(use_with protobuf) \
+ ${myconf}
+}
+
+src_compile() {
+ default
+ use doc && emake -C codedocs codedocs
+}
+
+src_install() {
+ default
+
+ mv "${D}"/etc/powerdns/pdns.conf{-dist,}
+
+ fperms 0700 /etc/powerdns
+ fperms 0600 /etc/powerdns/pdns.conf
+
+ # set defaults: setuid=pdns, setgid=pdns
+ sed -i \
+ -e 's/^# set\([ug]\)id=$/set\1id=pdns/g' \
+ "${D}"/etc/powerdns/pdns.conf
+
+ newinitd "${FILESDIR}"/pdns-r1 pdns
+
+ keepdir /var/empty
+
+ use doc && dohtml -r codedocs/html/.
+
+ # Install development headers
+ insinto /usr/include/pdns
+ doins pdns/*.hh
+ insinto /usr/include/pdns/backends/gsql
+ doins pdns/backends/gsql/*.hh
+
+ if use ldap ; then
+ insinto /etc/openldap/schema
+ doins "${FILESDIR}"/dnsdomain2.schema
+ fi
+
+ prune_libtool_files --all
+}
+
+pkg_preinst() {
+ enewgroup pdns
+ enewuser pdns -1 -1 /var/empty pdns
+}
+
+pkg_postinst() {
+ elog "PowerDNS provides multiple instances support. You can create more instances"
+ elog "by symlinking the pdns init script to another name."
+ elog
+ elog "The name must be in the format pdns.<suffix> and PowerDNS will use the"
+ elog "/etc/powerdns/pdns-<suffix>.conf configuration file instead of the default."
+
+ if use ldap ; then
+ ewarn "The official LDAP backend module is only compile-tested by upstream."
+ ewarn "Try net-dns/pdns-ldap-backend if you have problems with it."
+ fi
+
+ local old
+ for old in ${REPLACING_VERSIONS}; do
+ version_compare ${old} 3.2
+ [[ $? -eq 1 ]] || continue
+
+ ewarn "To fix a security bug (bug #458018) had the following"
+ ewarn "files/directories the world-readable bit removed (if set):"
+ ewarn " ${EPREFIX}/etc/powerdns"
+ ewarn " ${EPREFIX}/etc/powerdns/pdns.conf"
+ ewarn "Check if this is correct for your setup"
+ ewarn "This is a one-time change and will not happen on subsequent updates."
+ chmod o-rwx "${EPREFIX}"/etc/powerdns/{,pdns.conf}
+
+ break
+ done
+}