From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1025786-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 5D2D0138330
for <garchives@archives.gentoo.org>; Thu, 24 May 2018 20:29:11 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 6B40BE0819;
Thu, 24 May 2018 20:29:10 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 236E6E0819
for <gentoo-commits@lists.gentoo.org>; Thu, 24 May 2018 20:29:09 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 7BB3F335C57
for <gentoo-commits@lists.gentoo.org>; Thu, 24 May 2018 20:29:08 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 9F4FB27A
for <gentoo-commits@lists.gentoo.org>; Thu, 24 May 2018 20:29:06 +0000 (UTC)
From: "Daniel Pielmeier" <billie@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Daniel Pielmeier" <billie@gentoo.org>
Message-ID: <1527193740.2819b5273b91cc20796ee86057e0792d3bc0d238.billie@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-print/hplip/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-print/hplip/Manifest net-print/hplip/hplip-3.18.3-r1.ebuild
X-VCS-Directories: net-print/hplip/
X-VCS-Committer: billie
X-VCS-Committer-Name: Daniel Pielmeier
X-VCS-Revision: 2819b5273b91cc20796ee86057e0792d3bc0d238
X-VCS-Branch: master
Date: Thu, 24 May 2018 20:29:06 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: c5633325-03c5-49e5-a27a-43a9d8a9fd57
X-Archives-Hash: 7cce540b2ec3045a60b08e25fc458796
commit: 2819b5273b91cc20796ee86057e0792d3bc0d238
Author: Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Thu May 24 20:29:00 2018 +0000
Commit: Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Thu May 24 20:29:00 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2819b527
net-print/hplip: Remove old.
Package-Manager: Portage-2.3.24, Repoman-2.3.6
net-print/hplip/Manifest | 1 -
net-print/hplip/hplip-3.18.3-r1.ebuild | 268 ---------------------------------
2 files changed, 269 deletions(-)
diff --git a/net-print/hplip/Manifest b/net-print/hplip/Manifest
index ef67e300afd..79e49aaa6fc 100644
--- a/net-print/hplip/Manifest
+++ b/net-print/hplip/Manifest
@@ -1,6 +1,5 @@
DIST hplip-3.17.10.tar.gz 23878364 BLAKE2B 0165bcb00159572a16277624db0de4b2ca8421d5cf42418bf406548dd68a7d5087142a74a0e6ca332936b006f6ffeaa4d9202c5332fd1f971923bb142adb244f SHA512 0c1c78730d269ec41f95bbde887a490aebb4c9c3dcb9784052a1c3b537c12093cbc426e1f79266c63dd5e7adecdda0735b9bf964ddc1307b2c6603f3fa0462a8
DIST hplip-3.17.9-patches-1.tar.xz 8484 BLAKE2B 3a1f25d0554af5597266eb5ed3ff9f594560671784a89ade6246e9287661bf17fa16c555391c3f685e59aec8c548560911065a9c4188906c2f00c755f503fe49 SHA512 125f9cfd1c3cad662ce33954b8ab9ab1898368b449c4ad78dfe99f29de8025183773272b9865cd22b976a30c502e38254ce0ac59d685299dff7f9314927d546a
DIST hplip-3.18.3-patches-2.tar.xz 8936 BLAKE2B 58c17f3b6332de1edd88a3b458f1e9f856bc917842f62eee0808469ec14ff5793cd33c7a2ba30593eba624e58c12a6d426fa43a7d375d6ac50b985b895a85b4c SHA512 cbafcd9616f9c86318007b703325d3429ed0698c3fc9d3eddd422e4cd7a16c77320ac168bfa01b5874213e1740cfaae1867d31c3cf96cd57573ad33651a674ed
-DIST hplip-3.18.3.tar.gz 22178733 BLAKE2B 2d5c30d884cd04314ef3727e88abd1a2621e39916c0fa9a558e72ed2d040a5d11847cd82237da33efccd41b23eeb0fad69c84b36fbb736af3def4aa60f00ba71 SHA512 cb51e357cc9def3c087231b01752941b469e5fc4508ec83c6f5875352694249ef72339f2f20c4a6831c49ace7c1f6b902cc11a961c0e1f43ce098b2bf800728f
DIST hplip-3.18.4.tar.gz 22185532 BLAKE2B dceb0213b67a4842db9d30b45d1eb9796ceb5065d0495901af89f359016cc2febb47fd80610d13f2aada69ef8701a56bc6c52065bc68b200f488fcfd739a0d7c SHA512 dfe0e21606498112d57fd76763bcc9457a130896bd86508736422c1d82a8be5b5e4b4277b07e2efd2c777cedb9f573ac9fe8198afcf425386c7d8ac0cd62d086
DIST hplip-3.18.5.tar.gz 22437406 BLAKE2B d32c38209b8a60c6ca7fe89512409d4d32bf095097cdc499a1afeb985c9add2da5e99b12b307f1cf0c4513071f2d4b62291d7624fe982579e8781ace5f533f6a SHA512 2c99bb446af604a2f011f9dd5ddf4bf5019b7cd36a0ecb1cbe6dce0c0358b8472a695ad85d09e52c3e63de8a69e2a3e7081c61ec36f44aae2770b5fef0f67516
diff --git a/net-print/hplip/hplip-3.18.3-r1.ebuild b/net-print/hplip/hplip-3.18.3-r1.ebuild
deleted file mode 100644
index c1bd7d6cc22..00000000000
--- a/net-print/hplip/hplip-3.18.3-r1.ebuild
+++ /dev/null
@@ -1,268 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
-PYTHON_REQ_USE="threads,xml"
-
-# 14 and 15 spit out a lot of warnings about subdirs
-WANT_AUTOMAKE="1.13"
-
-inherit autotools linux-info python-single-r1 readme.gentoo-r1 udev
-
-DESCRIPTION="HP Linux Imaging and Printing - Print, scan, fax drivers and service tools"
-HOMEPAGE="http://hplipopensource.com/hplip-web/index.html"
-SRC_URI="mirror://sourceforge/hplip/${P}.tar.gz
- https://dev.gentoo.org/~billie/distfiles/${PN}-3.18.3-patches-2.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
-
-IUSE="doc fax +hpcups hpijs kde libressl -libusb0 minimal parport policykit qt5 scanner +snmp static-ppds X"
-
-# dependency on dev-python/notify-python dropped due to python 3 incompatibility
-# possible replacement notify2 (https://pypi.org/project/notify2/0.3) not in tree
-
-COMMON_DEPEND="
- net-print/cups
- virtual/jpeg:0
- hpijs? ( net-print/cups-filters[foomatic] )
- !minimal? (
- ${PYTHON_DEPS}
- sys-apps/dbus
- !libusb0? ( virtual/libusb:1 )
- libusb0? ( virtual/libusb:0 )
- scanner? ( media-gfx/sane-backends )
- snmp? (
- !libressl? ( dev-libs/openssl:0= )
- libressl? ( dev-libs/libressl:= )
- net-analyzer/net-snmp
- )
- )
-"
-DEPEND="${COMMON_DEPEND}
- virtual/pkgconfig
-"
-RDEPEND="${COMMON_DEPEND}
- app-text/ghostscript-gpl
- !minimal? (
- >=dev-python/dbus-python-1.2.0-r1[${PYTHON_USEDEP}]
- $(python_gen_cond_dep 'dev-python/pygobject:2[${PYTHON_USEDEP}]' 'python2*')
- $(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]' 'python3*')
- fax? ( dev-python/reportlab[${PYTHON_USEDEP}] )
- kernel_linux? ( virtual/udev )
- qt5? ( >=dev-python/PyQt5-5.5.1[dbus,gui,widgets,${PYTHON_USEDEP}] )
- scanner? (
- >=dev-python/reportlab-3.2[${PYTHON_USEDEP}]
- >=dev-python/pillow-3.1.1[${PYTHON_USEDEP}]
- X? ( || (
- kde? ( kde-misc/skanlite )
- media-gfx/xsane
- media-gfx/sane-frontends
- ) )
- )
- )
- policykit? ( sys-auth/polkit )
-"
-
-REQUIRED_USE="!minimal? ( ${PYTHON_REQUIRED_USE} )"
-
-PATCHES=(
- "${WORKDIR}/patches"
-)
-
-CONFIG_CHECK="~PARPORT ~PPDEV"
-ERROR_PARPORT="Please make sure kernel parallel port support is enabled (PARPORT and PPDEV)."
-
-#DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="
-For more information on setting up your printer please take
-a look at the hplip section of the gentoo printing guide:
-https://wiki.gentoo.org/wiki/Printing
-
-Any user who wants to print must be in the lp group.
-"
-
-pkg_setup() {
- use !minimal && python-single-r1_pkg_setup
-
- use scanner && ! use X && ewarn "You need USE=X for the scanner GUI."
-
- if ! use hpcups && ! use hpijs ; then
- ewarn "Installing neither hpcups (USE=-hpcups) nor hpijs (USE=-hpijs) driver,"
- ewarn "which is probably not what you want."
- ewarn "You will almost certainly not be able to print."
- fi
-
- if use minimal ; then
- ewarn "Installing driver portions only, make sure you know what you are doing."
- ewarn "Depending on the USE flags set for hpcups or hpijs the appropiate driver"
- ewarn "is installed. If both USE flags are set hpijs overrides hpcups."
- else
- use parport && linux-info_pkg_setup
- fi
-}
-
-src_prepare() {
- default
-
- if use !minimal ; then
- python_export EPYTHON PYTHON
- python_fix_shebang .
- fi
-
- # Make desktop files follow the specification
- # Gentoo bug: https://bugs.gentoo.org/show_bug.cgi?id=443680
- # Upstream bug: https://bugs.launchpad.net/hplip/+bug/1080324
- sed -i -e '/^Categories=/s/Application;//' \
- -e '/^Encoding=.*/d' hplip.desktop.in || die
- sed -i -e '/^Categories=/s/Application;//' \
- -e '/^Version=.*/d' \
- -e '/^Comment=.*/d' hplip-systray.desktop.in || die
-
- # Fix for Gentoo bug https://bugs.gentoo.org/show_bug.cgi?id=345725
- # Upstream bug: https://bugs.launchpad.net/hplip/+bug/880847,
- # https://bugs.launchpad.net/hplip/+bug/500086
- local udevdir=$(get_udevdir)
- sed -i -e "s|/etc/udev|${udevdir}|g" \
- $(find . -type f -exec grep -l /etc/udev {} +) || die
-
- # Force recognition of Gentoo distro by hp-check
- sed -i \
- -e "s:file('/etc/issue', 'r').read():'Gentoo':" \
- installer/core_install.py || die
-
- eautoreconf
-}
-
-src_configure() {
- local myconf drv_build minimal_build
-
- if use libusb0 ; then
- myconf="${myconf} --enable-libusb01_build"
- else
- myconf="${myconf} --disable-libusb01_build"
- fi
-
- if use hpcups ; then
- drv_build="$(use_enable hpcups hpcups-install)"
- if use static-ppds ; then
- drv_build="${drv_build} --enable-cups-ppd-install"
- drv_build="${drv_build} --disable-cups-drv-install"
- else
- drv_build="${drv_build} --enable-cups-drv-install"
- drv_build="${drv_build} --disable-cups-ppd-install"
- fi
- else
- drv_build="--disable-hpcups-install"
- drv_build="${drv_build} --disable-cups-drv-install"
- drv_build="${drv_build} --disable-cups-ppd-install"
- fi
-
- if use hpijs ; then
- drv_build="${drv_build} $(use_enable hpijs hpijs-install)"
- if use static-ppds ; then
- drv_build="${drv_build} --enable-foomatic-ppd-install"
- drv_build="${drv_build} --disable-foomatic-drv-install"
- else
- drv_build="${drv_build} --enable-foomatic-drv-install"
- drv_build="${drv_build} --disable-foomatic-ppd-install"
- fi
- else
- drv_build="${drv_build} --disable-hpijs-install"
- drv_build="${drv_build} --disable-foomatic-drv-install"
- drv_build="${drv_build} --disable-foomatic-ppd-install"
- fi
-
- if use minimal ; then
- if use hpijs ; then
- minimal_build="--enable-hpijs-only-build"
- else
- minimal_build="--disable-hpijs-only-build"
- fi
- if use hpcups ; then
- minimal_build="${minimal_build} --enable-hpcups-only-build"
- else
- minimal_build="${minimal_build} --disable-hpcups-only-build"
- fi
- fi
-
- # disable class driver for now
- econf \
- --disable-cups11-build \
- --disable-lite-build \
- --disable-foomatic-rip-hplip-install \
- --disable-shadow-build \
- --disable-qt3 \
- --disable-qt4 \
- --disable-udev_sysfs_rules \
- --with-cupsbackenddir=$(cups-config --serverbin)/backend \
- --with-cupsfilterdir=$(cups-config --serverbin)/filter \
- --with-docdir=/usr/share/doc/${PF} \
- --with-htmldir=/usr/share/doc/${PF}/html \
- ${myconf} \
- ${drv_build} \
- ${minimal_build} \
- --enable-hpps-install \
- --disable-class-driver \
- $(use_enable doc doc-build) \
- $(use_enable fax fax-build) \
- $(use_enable !minimal gui-build) \
- $(use_enable !minimal dbus-build) \
- $(use_enable parport pp-build) \
- $(use_enable policykit) \
- $(use_enable qt5) \
- $(use_enable scanner scan-build) \
- $(use_enable snmp network-build)
-
- # hpijs ppds are created at configure time but are not installed (3.17.11)
-
- # Use system foomatic-rip for hpijs driver instead of foomatic-rip-hplip
- # The hpcups driver does not use foomatic-rip
- #local i
- #for i in ppd/hpijs/*.ppd.gz ; do
- # rm -f ${i}.temp || die
- # gunzip -c ${i} | sed 's/foomatic-rip-hplip/foomatic-rip/g' | \
- # gzip > ${i}.temp || die
- # mv ${i}.temp ${i} || die
- #done
-}
-
-src_install() {
- # Disable parallel install
- # Gentoo Bug: https://bugs.gentoo.org/show_bug.cgi?id=578018
- emake -j1 DESTDIR="${D}" install
- einstalldocs
- # default
-
- # Installed by sane-backends
- # Gentoo Bug: https://bugs.gentoo.org/show_bug.cgi?id=201023
- rm -f "${ED%/}"/etc/sane.d/dll.conf || die
-
- # Remove desktop and autostart files
- # Gentoo Bug: https://bugs.gentoo.org/show_bug.cgi?id=638770
- use qt5 || {
- rm -Rf "${ED}"/usr/share/applications "${ED}"/etc/xdg
- }
-
- rm -f "${ED%/}"/usr/share/doc/${PF}/{copyright,README_LIBJPG,COPYING} || die
- rmdir --ignore-fail-on-non-empty "${ED%/}"/usr/share/doc/${PF}/ || die
-
- # Remove hal fdi files
- rm -rf "${ED%/}"/usr/share/hal || die
-
- find "${D}" -name '*.la' -delete || die
-
- if use !minimal ; then
- python_export EPYTHON PYTHON
- python_optimize "${ED%/}"/usr/share/hplip
- fi
-
- readme.gentoo_create_doc
-}
-
-pkg_postinst() {
- readme.gentoo_print_elog
-}