[gentoo-commits] repo/gentoo:master commit in: x11-misc/redshift/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     926d5f396ef4c65236772b45fe71ad101ac7aff4
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Mon May 21 21:18:28 2018 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Mon May 21 21:20:05 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=926d5f39

x11-misc/redshift: 1.12

Package-Manager: Portage-2.3.38, Repoman-2.3.9

 x11-misc/redshift/Manifest             |  1 +
 x11-misc/redshift/redshift-1.12.ebuild | 86 ++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
index 5cfadbf6375..8641e7f3d96 100644
--- a/x11-misc/redshift/Manifest
+++ b/x11-misc/redshift/Manifest
@@ -1 +1,2 @@
 DIST redshift-1.11.tar.gz 543804 BLAKE2B 9921ed703555fda60c06df9425bf4423ce3891db60f41a1c4c4b4897e2506b8ad79e44f765e49b08db5549406008e12c412c6ecb2a07316cdec4b123fd11ef11 SHA512 bcdb4c120efec3955f4f91f1290db0679e987e25d6610bd90ee8540a96bb11338e36b10680736490ea0b7e9eca5bc195b51767a5badf0b80495dc3da44c4ed8c
+DIST redshift-1.12.tar.gz 659019 BLAKE2B 09339a57fee192e3428ba4387cbea498f2f9f97eb75a418588cdda3289cfa7b7fada4cb299e983e9e6d2ffe3822c8235082e67bdfa542716b6dee9fc853a8dc1 SHA512 6763f6964b577fc146191af1c67a283a60df5bbdd3a74bfc94f66d5f9f3bef8835a479c6ec8a648b650b83a0e245928884a0f628606ace8c3f58d8319d35036f

diff --git a/x11-misc/redshift/redshift-1.12.ebuild b/x11-misc/redshift/redshift-1.12.ebuild
new file mode 100644
index 00000000000..e7b003af9f8
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit systemd autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ayatana geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+	ayatana? ( dev-libs/libappindicator:3 )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--disable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}