From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1024328-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id EEDA81382C5
for <garchives@archives.gentoo.org>; Wed, 16 May 2018 07:27:02 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 3CBB7E0922;
Wed, 16 May 2018 07:27:02 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 04BA0E0922
for <gentoo-commits@lists.gentoo.org>; Wed, 16 May 2018 07:27:01 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id BFA2F335C7D
for <gentoo-commits@lists.gentoo.org>; Wed, 16 May 2018 07:26:58 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 3999629E
for <gentoo-commits@lists.gentoo.org>; Wed, 16 May 2018 07:26:57 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1526455577.1f43e7f35600e96f99a0adb57c6f88094c788010.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-misc/aria2/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-misc/aria2/Manifest net-misc/aria2/aria2-1.34.0.ebuild
X-VCS-Directories: net-misc/aria2/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 1f43e7f35600e96f99a0adb57c6f88094c788010
X-VCS-Branch: master
Date: Wed, 16 May 2018 07:26:57 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: a5c95343-aabf-4540-bd0c-2a0582003693
X-Archives-Hash: 6e62ff2f90d81a6202b2cdd01f228757
commit: 1f43e7f35600e96f99a0adb57c6f88094c788010
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 16 06:35:58 2018 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 16 07:26:17 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f43e7f3
net-misc/aria2: Bump to 1.34.0
net-misc/aria2/Manifest | 1 +
net-misc/aria2/aria2-1.34.0.ebuild | 152 +++++++++++++++++++++++++++++++++++++
2 files changed, 153 insertions(+)
diff --git a/net-misc/aria2/Manifest b/net-misc/aria2/Manifest
index 6cf1f36cc38..fa6823e8615 100644
--- a/net-misc/aria2/Manifest
+++ b/net-misc/aria2/Manifest
@@ -1,2 +1,3 @@
DIST aria2-1.30.0.tar.xz 1497124 BLAKE2B 99bce103f1bd89b94e202cb7b2d9dc427398e0dec3517b25a3870515433b7be35fe2841b5ace049771181e6ce44acb82f8715c72347e7069acd6b003e33522ac SHA512 8c3deb4b58b9db9e8de52f48f6e863e07743ae4af14e2b2d64ddcac94b6aec16ff8d4f27e7d6076426d597af9e6e0988289f3a1c156796c9d79ee7f60f5edc38
DIST aria2-1.33.1.tar.xz 1505208 BLAKE2B fb74add042d0cda81ca1b9c9d9b27b559ba859829c681520d6ece6322411f139667a1eaddc6f8aef23931e301ba4aab599ab17595df8d6ef477000f5e8fa83f0 SHA512 5379768a0960e46ed616a2540508d0dda4172c8d1a05021e50243241adb64448f5fa01878868ea206ec6b462fea39fa82284bb0f78ceec299eb289f94815b94a
+DIST aria2-1.34.0.tar.xz 1525908 BLAKE2B 479145af229f5fe864e54c511197bedb306199dbda608416aa295930a8392c7a118993b5a1634db20b380ab448cc8a397a351b6b64560ca263a0818d47a1ae64 SHA512 80bc43e242c06acc95030021cb347b4ec230729f3d7e512ca1932941b34ef95c312a34007a226869e5d720839a400e66cdb072ccab5d42228d8cf3d828723dcc
diff --git a/net-misc/aria2/aria2-1.34.0.ebuild b/net-misc/aria2/aria2-1.34.0.ebuild
new file mode 100644
index 00000000000..330ad0add54
--- /dev/null
+++ b/net-misc/aria2/aria2-1.34.0.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit bash-completion-r1
+
+DESCRIPTION="A download utility with segmented downloading with BitTorrent support"
+HOMEPAGE="https://aria2.github.io/"
+SRC_URI="https://github.com/aria2/${PN}/releases/download/release-${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="adns bittorrent +gnutls jemalloc libuv +libxml2 metalink +nettle nls sqlite scripts ssh ssl tcmalloc test xmlrpc"
+
+CDEPEND="sys-libs/zlib:0=
+ ssl? (
+ app-misc/ca-certificates
+ gnutls? ( >=net-libs/gnutls-1.2.9:0= )
+ !gnutls? ( dev-libs/openssl:0= ) )
+ adns? ( >=net-dns/c-ares-1.5.0:0= )
+ bittorrent? (
+ ssl? (
+ gnutls? (
+ nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-6:0= )
+ !nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+ !ssl? (
+ nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-6:0= )
+ !nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+ jemalloc? ( dev-libs/jemalloc )
+ libuv? ( >=dev-libs/libuv-1.13:0= )
+ metalink? (
+ libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+ !libxml2? ( dev-libs/expat:0= ) )
+ sqlite? ( dev-db/sqlite:3= )
+ ssh? ( net-libs/libssh2:= )
+ tcmalloc? ( dev-util/google-perftools )
+ xmlrpc? (
+ libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+ !libxml2? ( dev-libs/expat:0= ) )"
+
+DEPEND="${CDEPEND}
+ app-arch/xz-utils
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+ test? ( >=dev-util/cppunit-1.12.0:0 )"
+RDEPEND="${CDEPEND}
+ nls? ( virtual/libiconv virtual/libintl )
+ scripts? ( dev-lang/ruby )"
+
+# xmlrpc has no explicit switch, it's turned out by any XML library
+# so metalink implicitly forces it on
+REQUIRED_USE="?? ( jemalloc tcmalloc )
+ metalink? ( xmlrpc )"
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+ if use scripts && ! use xmlrpc; then
+ ewarn "Please note that you may need to enable USE=xmlrpc to run the aria2rpc"
+ ewarn "and aria2mon scripts against the local aria2."
+ fi
+}
+
+src_prepare() {
+ default
+ sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+}
+
+src_configure() {
+ local myconf=(
+ # threads, epoll: check for best portability
+
+ # do not try to compile and run a test LIBXML program
+ --disable-xmltest
+ # enable the shared library
+ --enable-libaria2
+ # zlib should always be available anyway
+ --with-libz
+ --with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
+
+ # optional features
+ $(use_enable bittorrent)
+ $(use_enable metalink)
+ $(use_enable nls)
+ $(use_with adns libcares)
+ $(use_with jemalloc)
+ $(use_with libuv)
+ $(use_with sqlite sqlite3)
+ $(use_with ssh libssh2)
+ $(use_with tcmalloc)
+ )
+
+ # SSL := gnutls / openssl
+ # USE=ssl
+ # + USE=gnutls -> gnutls
+ # + USE=-gnutls -> openssl
+
+ if use ssl; then
+ myconf+=( $(use_with gnutls) $(use_with !gnutls openssl) )
+ else
+ myconf+=( --without-gnutls --without-openssl )
+ fi
+
+ # message-digest := nettle / gcrypt / openssl
+ # bignum := nettle+gmp / gcrypt / openssl
+ # bittorrent := message-digest + bignum
+ # USE=bittorrent
+ # + USE=(ssl -gnutls) -> openssl
+ # + USE=nettle -> nettle+gmp
+ # + USE=-nettle -> gcrypt
+
+ if use !bittorrent || use ssl && use !gnutls; then
+ myconf+=( --without-libgcrypt --without-libnettle --without-libgmp )
+ else
+ myconf+=( $(use_with !nettle libgcrypt)
+ $(use_with nettle libnettle) $(use_with nettle libgmp) )
+ fi
+
+ # metalink+xmlrpc := libxml2 / expat
+ # USE=(metalink || xmlrpc)
+ # + USE=libxml2 -> libxml2
+ # + USE=-libxml2 -> expat
+
+ if use metalink || use xmlrpc; then
+ myconf+=( $(use_with !libxml2 libexpat) $(use_with libxml2) )
+ else
+ myconf+=( --without-libexpat --without-libxml2 )
+ fi
+
+ # Note:
+ # - always enable gzip/http compression since zlib should always be available anyway
+ # - always enable epoll since we can assume kernel 2.6.x
+ # - other options for threads: solaris, pth, win32
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+ rm -rf "${D}"/usr/share/doc/aria2 \
+ "${D}"/usr/share/doc/${PF}/README{,.html}
+
+ dobashcomp doc/bash_completion/aria2c
+ use scripts && dobin doc/xmlrpc/aria2{mon,rpc}
+}
+
+pkg_postinst() {
+ if use xmlrpc; then
+ elog "If you would like to use the additional aria2mon and aria2rpc tools,"
+ elog "you need to have \033[1mdev-lang/ruby\033[0m installed."
+ fi
+}