[gentoo-commits] repo/gentoo:master commit in: app-editors/notepadqq/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     5fa8108e1d1cc35bef20679f3ef146e62f1084f1
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue May 15 12:18:53 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue May 15 12:30:13 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5fa8108e

app-editors/notepadqq: Added live ebuild.

Package-Manager: Portage-2.3.36, Repoman-2.3.9

 app-editors/notepadqq/notepadqq-9999.ebuild | 59 +++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/app-editors/notepadqq/notepadqq-9999.ebuild b/app-editors/notepadqq/notepadqq-9999.ebuild
new file mode 100644
index 00000000000..9db258a3956
--- /dev/null
+++ b/app-editors/notepadqq/notepadqq-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="Notepad++-like editor for Linux"
+HOMEPAGE="http://notepadqq.altervista.org"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/notepadqq/notepadqq.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwebchannel:5
+	dev-qt/qtwebengine:5
+	dev-qt/qtwidgets:5
+"
+DEPEND="
+	${RDEPEND}
+	dev-qt/qtsvg:5
+"
+
+src_prepare() {
+	default
+
+	# Silence a QA warning
+	sed '/^OnlyShowIn/d' \
+		-i support_files/shortcuts/notepadqq.desktop \
+		|| die
+}
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}/usr" ${PN}.pro
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}