[gentoo-commits] repo/gentoo:master commit in: app-shells/pdsh/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     6a473558dc563d66bc0e47f9070ec4d331dea38a
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Fri May 11 21:52:55 2018 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Fri May 11 21:56:01 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a473558

app-shells/pdsh: EAPI 6 bump.

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 app-shells/pdsh/pdsh-2.26-r1.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/app-shells/pdsh/pdsh-2.26-r1.ebuild b/app-shells/pdsh/pdsh-2.26-r1.ebuild
new file mode 100644
index 00000000000..f9e97334263
--- /dev/null
+++ b/app-shells/pdsh/pdsh-2.26-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="A high-performance, parallel remote shell utility"
+HOMEPAGE="https://computing.llnl.gov/linux/pdsh.html"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt readline rsh static-libs test"
+
+RDEPEND="
+	crypt? ( net-misc/openssh )
+	rsh? ( net-misc/netkit-rsh )
+	readline? ( sys-libs/readline:0= )"
+
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/dejagnu )"
+
+pkg_setup() {
+	PDSH_MODULE_LIST="${PDSH_MODULE_LIST:-netgroup}"
+	MODULE_CONFIG=""
+
+	local m
+	local valid_modules=":xcpu:ssh:exec:qshell:genders:nodeupdown:mrsh:mqshell:dshgroups:netgroup:"
+
+	for m in ${PDSH_MODULE_LIST}; do
+		if [[ "${valid_modules}" == *:${m}:* ]]; then
+			MODULE_CONFIG="${MODULE_CONFIG} --with-${m}"
+		fi
+	done
+
+	elog "Building ${PF} with the following modules:"
+	elog "  ${PDSH_MODULE_LIST}"
+	elog "This list can be changed in /etc/portage/make.conf by setting"
+	elog "PDSH_MODULE_LIST=\"module1 module2...\""
+}
+
+src_configure() {
+	econf ${MODULE_CONFIG} \
+		--with-machines \
+		--enable-shared \
+		$(use_with crypt ssh) \
+		$(use_with rsh) \
+		$(use_with readline) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+}