[gentoo-commits] repo/gentoo:master commit in: games-emulation/mamory/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     065b5fad6b7a57c8dafaa7a9f3f7f5b83214f157
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 29 11:07:15 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Apr 29 11:26:16 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=065b5fad

games-emulation/mamory: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9

 games-emulation/mamory/mamory-0.2.25-r1.ebuild | 52 ++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/games-emulation/mamory/mamory-0.2.25-r1.ebuild b/games-emulation/mamory/mamory-0.2.25-r1.ebuild
new file mode 100644
index 00000000000..3f2f840637e
--- /dev/null
+++ b/games-emulation/mamory/mamory-0.2.25-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic
+
+DESCRIPTION="ROM management tools and library"
+HOMEPAGE="http://mamory.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-libs/expat"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	# Make sure the system expat is used
+	sed -i \
+		-e 's/#ifdef.*SYSEXPAT/#if 1/' \
+		mamory/amlxml.c mamory/amlxml.h || die
+
+	# Remove hardcoded CFLAGS options
+	sed -i \
+		-e '/AC_ARG_ENABLE(debug,/ {N;N;N;d}' \
+		configure.ac || die
+
+	# Make it possible for eautoreconf to fix fPIC etc.
+	sed -i \
+		-e '/libcommon_la_LDFLAGS= -static/d' \
+		common/Makefile.am || die
+
+	AT_M4DIR="config" eautoreconf
+	append-cflags -std=gnu89 # build with gcc5 (bug #570500)
+
+	
+}
+
+src_configure() {
+	econf \
+		--includedir=/usr/include \
+		--disable-static
+}
+
+src_install() {
+	HTML_DOCS="DOCS/mamory.html" default
+	find "${D}" -name '*.la' -delete || die
+}