[gentoo-commits] repo/gentoo:master commit in: games-arcade/missile/

[gentoo-commits] repo/gentoo:master commit in: games-arcade/missile/

[Pacho Ramos]

commit:     07b0993c87a8f36f923e23f998b91c867edc3cad
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 22 19:11:28 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Apr 22 19:39:48 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07b0993c

games-arcade/missile: Drop old

Package-Manager: Portage-2.3.31, Repoman-2.3.9

 games-arcade/missile/missile-1.0.1.ebuild | 53 -------------------------------
 1 file changed, 53 deletions(-)

diff --git a/games-arcade/missile/missile-1.0.1.ebuild b/games-arcade/missile/missile-1.0.1.ebuild
deleted file mode 100644
index 1b7653b64b3..00000000000
--- a/games-arcade/missile/missile-1.0.1.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils gnome2-utils games
-
-DESCRIPTION="The game Missile Command for Linux"
-HOMEPAGE="http://missile.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~x86"
-IUSE=""
-
-DEPEND="media-libs/libsdl[sound,video]
-	media-libs/sdl-image[png]
-	media-libs/sdl-mixer"
-RDEPEND=${DEPEND}
-
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-ldflags.patch
-	sed -i \
-		-e '/^CC/d' \
-		-e "s:\$(game_prefix)/\$(game_data):${GAMES_DATADIR}/${PN}:" \
-		-e "s/-O2/${CFLAGS}/" \
-		-e 's/-lSDL_image $(SND_LIBS)/-lSDL_image -lm $(SND_LIBS)/g' \
-		Makefile || die
-}
-
-src_install() {
-	dogamesbin ${PN}
-	insinto "${GAMES_DATADIR}"/${PN}
-	doins -r data/*
-	newicon -s 48 icons/${PN}_icon_black.png ${PN}.png
-	make_desktop_entry ${PN} "Missile Command"
-	dodoc README
-	prepgamesdirs
-}
-
-pkg_preinst() {
-	games_pkg_preinst
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	games_pkg_postinst
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}

[gentoo-commits] repo/gentoo:master commit in: games-arcade/missile/

[Ionen Wolkens]

commit:     49328b8b0cd28198e81c606e8f68119373611cc2
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 28 03:04:04 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Jun 28 16:42:37 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=49328b8b

games-arcade/missile: replace workarounds, EAPI 6->8, misc fixes

Previously would call cc directly, didn't use pkg-config, needs
patches and sed to respect flags, etc.. Considering it's a single C
file that likely won't get new versions, just compile it directly.

Also no longer install unused zaurus graphics data, fix prefix,
and make sound optional.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-arcade/missile/missile-1.0.1-r2.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/games-arcade/missile/missile-1.0.1-r2.ebuild b/games-arcade/missile/missile-1.0.1-r2.ebuild
new file mode 100644
index 00000000000..1c473e3b58e
--- /dev/null
+++ b/games-arcade/missile/missile-1.0.1-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop flag-o-matic toolchain-funcs
+
+DESCRIPTION="Port of the Atari Missile Command game for Linux"
+HOMEPAGE="http://missile.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~x86"
+IUSE="+sound"
+
+RDEPEND="
+	media-libs/libsdl[sound?,video]
+	media-libs/sdl-image[png]
+	sound? ( media-libs/sdl-mixer )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_compile() {
+	tc-export CC
+
+	local cppargs=(
+		-DDATA="'\"${EPREFIX}/usr/share/${PN}\"'"
+		-DVERSION=\\\"${PV}\\\"
+		$(usev sound -DUSE_SOUND)
+		$($(tc-getPKG_CONFIG) --cflags sdl SDL_image $(usev sound SDL_mixer))
+	)
+	append-cppflags "${cppargs[@]}"
+
+	LDLIBS="$($(tc-getPKG_CONFIG) --libs sdl SDL_image $(usev sound SDL_mixer)) -lm" \
+		emake -f /dev/null ${PN}
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins -r data/{graphics,missile_icon.png,sound}
+
+	einstalldocs
+
+	newicon icons/${PN}_icon_red.png ${PN}.png
+	make_desktop_entry ${PN} "Missile Command"
+}