[gentoo-commits] proj/gnome:master commit in: x11-libs/vte/

["Ole Reifschneider" <tranquility@gentoo.org>]

commit:     9c9916a4a2f309a6ba4c20e8eef514953a8dca5c
Author:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 15 18:47:56 2018 +0000
Commit:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
CommitDate: Sun Apr 15 18:47:56 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=9c9916a4

x11-libs/vte: Bump version to 0.50.2

Package-Manager: Portage-2.3.28, Repoman-2.3.9
Manifest-Sign-Key: 0xE9E568677E8B4D42

 x11-libs/vte/vte-0.50.2.ebuild | 90 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)

diff --git a/x11-libs/vte/vte-0.50.2.ebuild b/x11-libs/vte/vte-0.50.2.ebuild
new file mode 100644
index 00000000..ff5ace3c
--- /dev/null
+++ b/x11-libs/vte/vte-0.50.2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.32"
+
+inherit gnome2 vala
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"
+
+LICENSE="LGPL-2+"
+SLOT="2.91"
+IUSE="+crypt debug glade +introspection vala vanilla"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-solaris ~x86-solaris"
+REQUIRED_USE="vala? ( introspection )"
+
+SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~tranquility/distfiles/${PN}/${P}-command-notify-scroll-speed.patch.xz )"
+
+RDEPEND="
+	>=dev-libs/glib-2.40:2
+	>=dev-libs/libpcre2-10.21
+	>=x11-libs/gtk+-3.16:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses:0=
+	sys-libs/zlib
+
+	crypt?  ( >=net-libs/gnutls-3.2.7:0= )
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/gperf
+	dev-libs/libxml2
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	vala? ( $(vala_depend) )
+"
+RDEPEND="${RDEPEND}
+	!x11-libs/vte:2.90[glade]
+"
+
+src_prepare() {
+	if ! use vanilla; then
+		# First half of http://pkgs.fedoraproject.org/cgit/rpms/vte291.git/tree/vte291-command-notify-scroll-speed.patch
+		# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
+		eapply "${WORKDIR}"/${P}-command-notify-scroll-speed.patch
+	fi
+
+	use vala && vala_src_prepare
+
+	# build fails because of -Werror with gcc-5.x
+	sed -e 's#-Werror=format=2#-Wformat=2#' -i configure || die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+
+	if [[ ${CHOST} == *-interix* ]]; then
+		myconf="${myconf} --disable-Bsymbolic"
+
+		# interix stropts.h is empty...
+		export ac_cv_header_stropts_h=no
+	fi
+
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	gnome2_src_configure \
+		--disable-test-application \
+		--disable-static \
+		--with-gtk=3.0 \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalogue) \
+		$(use_with crypt gnutls) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		${myconf}
+}
+
+src_install() {
+	gnome2_src_install
+	mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
+}