[gentoo-commits] repo/gentoo:master commit in: media-gfx/inkscape/

["Tim Harder" <radhermit@gentoo.org>]

commit:     3473013a4354c9485032d7d12665f533d2d867cd
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 31 05:03:16 2018 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Sat Mar 31 05:11:32 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3473013a

media-gfx/inkscape: version bump to 0.92.3

Closes: https://bugs.gentoo.org/651500

 media-gfx/inkscape/Manifest               |   1 +
 media-gfx/inkscape/inkscape-0.92.3.ebuild | 175 ++++++++++++++++++++++++++++++
 2 files changed, 176 insertions(+)

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index e46b9f48433..f44a0ae2f97 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -2,3 +2,4 @@ DIST inkscape-0.91.tar.bz2 25858909 BLAKE2B 9ca69a10a043efa64d7327ca6ba28d04a650
 DIST inkscape-0.92.1-poppler.patch 44142 BLAKE2B 4431a4185cfeb6c41f08da656db4335017fc08a62e154f75ef4ef1a2ae92dd510f22a4f9cd1cf8bb1fae09770f47a398b7b789c8bad4e47bc4941b9e8f79c1f0 SHA512 4a0504c236c816f413b3bf055754513bb53b52eb5f0323faa28ab445ce3fb83b6f41de5bc6e3865909e50fc9be937e3f99282e8414f4cdc954e04b974d7f15ab
 DIST inkscape-0.92.1.tar.bz2 31222684 BLAKE2B 26364e3ccf447d22d15291b132b44b1abd5ca4efc1df8e5eb4ca494ac9340ed8aa5e2d57d2e14c1859fc202532cf722b4c9c89defa92c630e462b07ce29ec774 SHA512 f8f3bfb812a214216c3ffac7064a4619f847cf9810417c782481dba12e6c6a44123c8b8a9289fbf5287f2e6b6df39a641d94a000d842faee5ff808eec86187a0
 DIST inkscape-0.92.2.tar.bz2 31224100 BLAKE2B c0a7b01220d1b0b0863f71f3e1c8ba7bdb58bd86e79c2d3f214831a344c992a1084d64813de00e6f88d77b1b1f1b8562c7a0ee98824149cb867eba586314d27d SHA512 e790cafb7cc2be2eb75f04ac4c18ae8558ae997f4261c38dac9c2a3383c7a12a0f4a090956770d1341b212fc9698d31d212f2c1609421907255f8af650569b30
+DIST inkscape-0.92.3.tar.bz2 31606442 BLAKE2B bc90dc160ca059395a2951b7b2daeb8730753c551f78e6af88b51b41322a438256499f754fb6b07946d77b80e1ddfe5514944f9b5cbb19d2bfdecb8625328db0 SHA512 af3c0f672a108e583f3c92cde1451b3f1f5319c1669891005c230e73b3485aa8951af6d7b21c7ccd9e4acbca8eaa5a3bb61ae1d828e81885bc7b61a8ae933687

diff --git a/media-gfx/inkscape/inkscape-0.92.3.ebuild b/media-gfx/inkscape/inkscape-0.92.3.ebuild
new file mode 100644
index 00000000000..69b0c27405f
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-0.92.3.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit autotools flag-o-matic gnome2-utils xdg toolchain-funcs python-single-r1
+
+MY_P=${P/_/}
+
+DESCRIPTION="A SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/"
+SRC_URI="https://inkscape.global.ssl.fastly.net/media/resources/file/${P}.tar.bz2
+https://dev.gentoo.org/~jstein/dist/inkscape-0.92.1-poppler.patch"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="cdr dia dbus exif gnome imagemagick openmp postscript inkjar jpeg latex"
+IUSE+=" lcms nls spell static-libs visio wpg"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=app-text/poppler-0.26.0:=[cairo]
+	>=dev-cpp/glibmm-2.48
+	>=dev-cpp/gtkmm-2.18.0:2.4
+	>=dev-cpp/cairomm-1.9.8
+	>=dev-libs/boehm-gc-7.1:=
+	>=dev-libs/glib-2.28
+	>=dev-libs/libsigc++-2.0.12
+	>=dev-libs/libxml2-2.6.20
+	>=dev-libs/libxslt-1.0.15
+	dev-libs/popt
+	dev-python/lxml[${PYTHON_USEDEP}]
+	media-gfx/potrace
+	media-gfx/scour[${PYTHON_USEDEP}]
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/libpng:0
+	sci-libs/gsl:=
+	x11-libs/libX11
+	>=x11-libs/gtk+-2.10.7:2
+	>=x11-libs/pango-1.24
+	cdr? (
+		media-libs/libcdr
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( media-libs/libexif )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	imagemagick? ( media-gfx/imagemagick:=[cxx] )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	spell? (
+		app-text/aspell
+		app-text/gtkspell:2
+	)
+	visio? (
+		media-libs/libvisio
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+	media-gfx/uniconvertor
+	dia? ( app-office/dia )
+	latex? (
+		media-gfx/pstoedit[plotutils]
+		app-text/dvipsk
+		app-text/texlive-core
+	)
+	postscript? ( app-text/ghostscript-gpl )
+"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.36
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.92.1-automagic.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-cppflags.patch"
+	"${FILESDIR}/${PN}-0.92.1-desktop.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-exif.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-sk-man.patch"
+	"${FILESDIR}/${PN}-0.48.4-epython.patch"
+)
+
+S=${WORKDIR}/${MY_P}
+
+RESTRICT="test"
+
+pkg_pretend() {
+	if use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i "s#@EPYTHON@#${EPYTHON}#" \
+		src/extension/implementation/script.cpp || die
+
+	eautoreconf
+
+	# bug 421111
+	python_fix_shebang share/extensions
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable nls) \
+		$(use_enable openmp) \
+		$(use_enable exif) \
+		$(use_enable jpeg) \
+		$(use_enable lcms) \
+		--enable-poppler-cairo \
+		$(use_enable wpg) \
+		$(use_enable visio) \
+		$(use_enable cdr) \
+		$(use_enable dbus dbusapi) \
+		$(use_enable imagemagick magick) \
+		$(use_with gnome gnome-vfs) \
+		$(use_with inkjar) \
+		$(use_with spell gtkspell) \
+		$(use_with spell aspell)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	prune_libtool_files
+	python_optimize "${ED}"/usr/share/${PN}/extensions
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}