[gentoo-commits] repo/gentoo:master commit in: app-cdr/isomaster/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     7ec3a7ebc392b80d2398c410297b5410ec74dcc0
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 28 14:31:08 2018 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Wed Mar 28 14:43:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ec3a7eb

app-cdr/isomaster: 1.3.14 + EAPI 6 + xdg-utils

First release using iniparser 4.x

Bug: https://bugs.gentoo.org/647588
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 app-cdr/isomaster/Manifest                |  1 +
 app-cdr/isomaster/isomaster-1.3.14.ebuild | 69 +++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/app-cdr/isomaster/Manifest b/app-cdr/isomaster/Manifest
index bab4c8e2e8a..6fda7fddad1 100644
--- a/app-cdr/isomaster/Manifest
+++ b/app-cdr/isomaster/Manifest
@@ -1 +1,2 @@
 DIST isomaster-1.3.13.tar.bz2 245085 BLAKE2B ae2333f5511aae8deed76e556cf6055f7ad257d613dcf5c85274946f31f0da879b5fb7953d065046371c6f20faa15663ecb3c5d976c4dff404140cd09d23207c SHA512 dbc6a77fabf8d454bbde25a7540e68820bf773bc991176e5684e87aeb6044ad1bbbcf1c4f537148c18ec8847572949a52d6578a14f68b8ad3f21d542685859ba
+DIST isomaster-1.3.14.tar.bz2 257674 BLAKE2B 7b7abeb586eb8c6964d7959222195c1999f81275dea305e7c4efec1fef6dd9d9d4969552e6a6a4a882a9fe227ea072c6639879896e50799db9e67732e1331ad4 SHA512 5454baa4ce4e09df8ec4331718df3e1d81c0647867a21cfc4c4b15d90e509371a636e8fada7e624c0cf6d1b03b564bf89a2a26e13b5ec1b4cca91407bbc518f5

diff --git a/app-cdr/isomaster/isomaster-1.3.14.ebuild b/app-cdr/isomaster/isomaster-1.3.14.ebuild
new file mode 100644
index 00000000000..aed6f0647fd
--- /dev/null
+++ b/app-cdr/isomaster/isomaster-1.3.14.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils xdg-utils toolchain-funcs
+
+DESCRIPTION="Graphical CD image editor for reading, modifying and writing ISO images"
+HOMEPAGE="http://littlesvr.ca/isomaster"
+SRC_URI="http://littlesvr.ca/${PN}/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="nls"
+
+RDEPEND=">=dev-libs/iniparser-4.1:4
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( >=sys-devel/gettext-0.19.1 )"  # bug 512448
+
+pkg_setup() {
+	myisoconf=(
+		DEFAULT_EDITOR=leafpad
+		MYDOCPATH=/usr/share/doc/${PF}/bkisofs
+		USE_SYSTEM_INIPARSER=1
+		LIB_INIPARSER=iniparser4
+		PREFIX=/usr
+		)
+
+	use nls || myisoconf+=( WITHOUT_NLS=1 )
+}
+
+src_prepare() {
+	rm -R iniparser-4.1 || die
+	eapply_user
+}
+
+src_configure() { :; } #274361
+
+src_compile() {
+	tc-export CC
+	emake "${myisoconf[@]}"
+}
+
+_apply_linguas() {
+	mv "${D}"/usr/share/locale{,_ALL} || die
+	dodir /usr/share/locale || die
+	for lingua in ${LINGUAS}; do
+		[[ -d "${D}"/usr/share/locale_ALL/${lingua} ]] || break
+		mv "${D}"/usr/share/{locale_ALL/${lingua},locale/} || die
+	done
+	rm -R "${D}"/usr/share/locale_ALL || die
+}
+
+src_install() {
+	emake "${myisoconf[@]}" DESTDIR="${D}" install
+	dodoc {CHANGELOG,CREDITS,README,TODO}.TXT *.txt
+
+	use nls && _apply_linguas  # bug 402679, bug 512448
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}