[gentoo-commits] repo/gentoo:master commit in: dev-qt/qt-creator/

["Davide Pesavento" <pesa@gentoo.org>]

commit:     732c263c3b626541d2f838f7012ff61a87aa3740
Author:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 16 20:06:53 2018 +0000
Commit:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
CommitDate: Fri Mar 16 20:07:11 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=732c263c

dev-qt/qt-creator: add 4.5.2

Closes: https://bugs.gentoo.org/650510
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 dev-qt/qt-creator/Manifest                |   1 +
 dev-qt/qt-creator/qt-creator-4.5.2.ebuild | 172 ++++++++++++++++++++++++++++++
 2 files changed, 173 insertions(+)

diff --git a/dev-qt/qt-creator/Manifest b/dev-qt/qt-creator/Manifest
index 02b8cee5840..93809d0a535 100644
--- a/dev-qt/qt-creator/Manifest
+++ b/dev-qt/qt-creator/Manifest
@@ -1,3 +1,4 @@
 DIST qt-creator-opensource-src-4.4.1.tar.xz 20822304 BLAKE2B 23c05b5e86fcbc3387cd9e8a82fb97e3b4e20182b41e2b24de7801126b0d5bbd708ca842ddcd828536fb279b6d2e4954909b8c40bfe14e050baa109095889e6d SHA512 f0e836fd2106f909cb405f75457e0d4158ecdd134ec5cfa97b373e5818b5f715245ac8454a657801251302ef817c1de66580f2e45b12b3e23d3107ccf3985336
 DIST qt-creator-opensource-src-4.5.0.tar.xz 21641628 BLAKE2B 83d8ef57b87278994451d34b69a17a7d6c872b014c82940593c83c53e4a693054bdcfa38c4706083ed2bc0386ae5fa8afcea4747d1dee67a2a9b1e0a3fa6aeed SHA512 9296ebef4a3d5ae40a9fa3a4039e77b8e407dfb52af3a88b4cc615a89e163d92de420d9db614bc689adc695879f0c2e1906e9a218e7a6b96c4b222d52c94912c
+DIST qt-creator-opensource-src-4.5.2.tar.xz 21745192 BLAKE2B 4860c6041542758647d27ae3aaac15dbbc72bbecbcf335e3bceab378c720979a3e89777762936a4b68eacec02a7b285dec08a19003ac3260de1e2e4ee12706c0 SHA512 cc3f20c109e810e8958495fd0d84461bc9ead7b4172600229969a6a331341f0b76069a71893f1ba279550293b131f6cca5b79c112d67f3aebb6244415489c223
 DIST qt-creator-opensource-src-4.6.0-beta1.tar.xz 23559992 BLAKE2B 20a89a2e833fd5f618cc8b7301530abe3cb2f54f687fe3f08a3881e3ffdd90f98cf32ccd7e7461bfb4b80547bd5cfbd732257626ea938a6459a69ba9a72f7958 SHA512 034735898b24884822ede430dd777066a5b93f38c383861d85268d0d65a140116f3a2d639b0c33862768127e3e0881a7b08ff710c5a210ccfa42c5e8a9fe1ff6

diff --git a/dev-qt/qt-creator/qt-creator-4.5.2.ebuild b/dev-qt/qt-creator/qt-creator-4.5.2.ebuild
new file mode 100644
index 00000000000..6581a0d4a74
--- /dev/null
+++ b/dev-qt/qt-creator/qt-creator-4.5.2.ebuild
@@ -0,0 +1,172 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PLOCALES="cs de fr ja pl ru sl uk zh-CN zh-TW"
+
+inherit llvm qmake-utils virtualx xdg
+
+DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
+HOMEPAGE="https://doc.qt.io/qtcreator/"
+LICENSE="GPL-3"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://code.qt.io/${PN}/${PN}.git"
+else
+	MY_PV=${PV/_/-}
+	MY_P=${PN}-opensource-src-${MY_PV}
+	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+	SRC_URI="https://download.qt.io/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+# TODO: unbundle sqlite
+
+QTC_PLUGINS=('android:android|qmakeandroidsupport' autotools:autotoolsprojectmanager baremetal bazaar
+	'clangcodemodel:clangcodemodel|clangrefactoring|clangpchmanager' clangstaticanalyzer clearcase
+	cmake:cmakeprojectmanager cvs designer git glsl:glsleditor ios mercurial modeling:modeleditor
+	nim perforce python:pythoneditor qbs:qbsprojectmanager qnx scxml:scxmleditor subversion valgrind
+	winrt)
+IUSE="doc systemd test +webengine ${QTC_PLUGINS[@]%:*}"
+
+# minimum Qt version required
+QT_PV="5.6.2:5"
+
+CDEPEND="
+	=dev-libs/botan-1.10*[-bindist,threads]
+	>=dev-qt/qtconcurrent-${QT_PV}
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtdeclarative-${QT_PV}[widgets]
+	>=dev-qt/qtgui-${QT_PV}
+	>=dev-qt/qthelp-${QT_PV}
+	>=dev-qt/qtnetwork-${QT_PV}[ssl]
+	>=dev-qt/qtprintsupport-${QT_PV}
+	>=dev-qt/qtquickcontrols-${QT_PV}
+	>=dev-qt/qtscript-${QT_PV}
+	>=dev-qt/qtsql-${QT_PV}[sqlite]
+	>=dev-qt/qtsvg-${QT_PV}
+	>=dev-qt/qtwidgets-${QT_PV}
+	>=dev-qt/qtx11extras-${QT_PV}
+	>=dev-qt/qtxml-${QT_PV}
+	clangcodemodel? ( >=sys-devel/clang-3.9:= )
+	designer? ( >=dev-qt/designer-${QT_PV} )
+	qbs? ( >=dev-util/qbs-1.10.1 )
+	systemd? ( sys-apps/systemd:= )
+	webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
+"
+DEPEND="${CDEPEND}
+	>=dev-qt/linguist-tools-${QT_PV}
+	virtual/pkgconfig
+	doc? ( >=dev-qt/qdoc-${QT_PV} )
+	test? (
+		>=dev-qt/qtdeclarative-${QT_PV}[localstorage,xml]
+		>=dev-qt/qtquickcontrols2-${QT_PV}
+		>=dev-qt/qttest-${QT_PV}
+	)
+"
+RDEPEND="${CDEPEND}
+	sys-devel/gdb[client,python]
+	autotools? ( sys-devel/autoconf )
+	bazaar? ( dev-vcs/bzr )
+	clangstaticanalyzer? ( >=sys-devel/clang-3.9:* )
+	cmake? ( dev-util/cmake[server(+)] )
+	cvs? ( dev-vcs/cvs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? ( dev-vcs/subversion )
+	valgrind? ( dev-util/valgrind )
+"
+# qt translations must also be installed or qt-creator translations won't be loaded
+for x in ${PLOCALES}; do
+	IUSE+=" l10n_${x}"
+	RDEPEND+=" l10n_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
+done
+unset x
+
+pkg_setup() {
+	use clangcodemodel && llvm_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# disable unwanted plugins
+	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
+		if ! use ${plugin%:*}; then
+			einfo "Disabling ${plugin%:*} plugin"
+			sed -i -re "/(^\s+|SUBDIRS\s*\+=\s*)(${plugin#*:})\>/d" \
+				src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
+		fi
+	done
+
+	# avoid building unused support libraries
+	if ! use clangcodemodel; then
+		sed -i -e '/clangbackendipc/d' src/libs/libs.pro || die
+	fi
+	if ! use glsl; then
+		sed -i -e '/glsl/d' src/libs/libs.pro || die
+	fi
+	if ! use modeling; then
+		sed -i -e '/modelinglib/d' src/libs/libs.pro || die
+	fi
+
+	# automagic dep on qtwebengine
+	if ! use webengine; then
+		sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
+	fi
+
+	# disable broken or unreliable tests
+	sed -i -e 's/\(manual\|tools\|unit\)//g' tests/tests.pro || die
+	sed -i -e '/sdktool/ d' tests/auto/auto.pro || die
+	sed -i -e '/\(dumpers\|offsets\)\.pro/ d' tests/auto/debugger/debugger.pro || die
+	sed -i -e '/CONFIG -=/ s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
+	sed -i -e '/timeline\(items\|notes\|selection\)renderpass/ d' tests/auto/timeline/timeline.pro || die
+	sed -i -e 's/\<memcheck\>//' tests/auto/valgrind/valgrind.pro || die
+
+	# fix path to some clang headers
+	sed -i -e "/^CLANG_RESOURCE_DIR\s*=/ s:\$\${LLVM_LIBDIR}:${EPREFIX}/usr/lib:" src/shared/clang/clang_defines.pri || die
+
+	# fix translations
+	local lang languages=
+	for lang in ${PLOCALES}; do
+		use l10n_${lang} && languages+=" ${lang/-/_}"
+	done
+	sed -i -e "/^LANGUAGES\s*=/ s:=.*:=${languages}:" share/qtcreator/translations/translations.pro || die
+
+	# remove bundled qbs
+	rm -rf src/shared/qbs || die
+}
+
+src_configure() {
+	eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
+		IDE_PACKAGE_MODE=1 \
+		$(use clangcodemodel && echo LLVM_INSTALL_DIR="$(get_llvm_prefix)") \
+		$(use qbs && echo QBS_INSTALL_DIR="${EPREFIX}/usr") \
+		CONFIG+=qbs_disable_rpath \
+		CONFIG+=qbs_enable_project_file_updates \
+		$(use systemd && echo CONFIG+=journald) \
+		$(use test && echo BUILD_TESTS=1) \
+		USE_SYSTEM_BOTAN=1
+}
+
+src_test() {
+	cd tests/auto && virtx default
+}
+
+src_install() {
+	emake INSTALL_ROOT="${ED}usr" install
+
+	dodoc dist/{changes-*,known-issues}
+
+	# install documentation
+	if use doc; then
+		emake docs
+		# don't use ${PF} or the doc will not be found
+		insinto /usr/share/doc/qtcreator
+		doins share/doc/qtcreator/qtcreator{,-dev}.qch
+		docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
+	fi
+}