[gentoo-commits] proj/gentoo-mate:master commit in: mate-base/mate-session-manager/

["Ettore Di Giacinto" <mudler@gentoo.org>]

commit:     94f5806a69568bfdc668e8eabda77c5726c21421
Author:     Ettore Di Giacinto <mudler <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 12 16:46:09 2018 +0000
Commit:     Ettore Di Giacinto <mudler <AT> gentoo <DOT> org>
CommitDate: Mon Mar 12 17:07:33 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gentoo-mate.git/commit/?id=94f5806a

mate-base/mate-session-manager: Revbump

- Fixes regression introduced by bad sync between mate overlay and ::gentoo
- Set IUSE="+xtrans", #621358
- Re-add ~arm64 keyword

Package-Manager: Portage-2.3.20, Repoman-2.3.6

 .../mate-session-manager-1.18.2-r1.ebuild          | 85 ++++++++++++++++++++++
 1 file changed, 85 insertions(+)

diff --git a/mate-base/mate-session-manager/mate-session-manager-1.18.2-r1.ebuild b/mate-base/mate-session-manager/mate-session-manager-1.18.2-r1.ebuild
new file mode 100644
index 0000000..3075243
--- /dev/null
+++ b/mate-base/mate-session-manager/mate-session-manager-1.18.2-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="MATE session manager"
+HOMEPAGE="http://mate-desktop.org/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+
+IUSE="debug elibc_FreeBSD gnome-keyring ipv6 systemd +xtrans"
+
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.36:2
+	dev-libs/libxslt
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango
+	virtual/libintl
+	elibc_FreeBSD? ( || ( dev-libs/libexecinfo >=sys-freebsd/freebsd-lib-10.0 ) )
+	systemd? ( sys-apps/systemd )
+	!systemd? ( >=sys-auth/consolekit-0.9.2 )
+	xtrans? ( x11-libs/xtrans )"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xdpyinfo
+	x11-misc/xdg-user-dirs
+	x11-misc/xdg-user-dirs-gtk
+	gnome-keyring? ( gnome-base/gnome-keyring )"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40:*
+	>=dev-lang/perl-5
+	>=sys-devel/gettext-0.10.40:*
+	virtual/pkgconfig:*
+	!<gnome-base/gdm-2.20.4"
+
+MATE_FORCE_AUTORECONF=true
+
+src_configure() {
+	mate_src_configure \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_with systemd) \
+		$(use_with xtrans)  \
+		$(use_enable debug) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	mate_src_install
+
+	dodir /etc/X11/Sessions/
+	exeinto /etc/X11/Sessions/
+	doexe "${FILESDIR}"/MATE
+
+	dodir /usr/share/mate/applications/
+	insinto /usr/share/mate/applications/
+	doins "${FILESDIR}"/defaults.list
+
+	dodir /etc/X11/xinit/xinitrc.d/
+	exeinto /etc/X11/xinit/xinitrc.d/
+	doexe "${FILESDIR}"/15-xdg-data-mate
+
+	# This should be done in MATE too, see Gentoo bug #270852
+	doexe "${FILESDIR}"/10-user-dirs-update-mate
+}