[gentoo-commits] repo/gentoo:master commit in: dev-libs/libsodium/

["Michał Górny" <mgorny@gentoo.org>]

commit:     ade0980cf5912477c6172223d6ff9b679b0da700
Author:     Conrad Kostecki <ck+gentoo <AT> bl4ckb0x <DOT> de>
AuthorDate: Sat Mar  3 22:07:03 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Mar  4 07:54:52 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ade0980c

dev-libs/libsodium: add multilib support

Closes: https://bugs.gentoo.org/622140
Closes: https://github.com/gentoo/gentoo/pull/7310

 dev-libs/libsodium/libsodium-1.0.16-r1.ebuild | 46 +++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-libs/libsodium/libsodium-1.0.16-r1.ebuild b/dev-libs/libsodium/libsodium-1.0.16-r1.ebuild
new file mode 100644
index 00000000000..dd260ff32ea
--- /dev/null
+++ b/dev-libs/libsodium/libsodium-1.0.16-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A portable fork of NaCl, a higher-level cryptographic library"
+HOMEPAGE="https://github.com/jedisct1/libsodium"
+SRC_URI="http://download.libsodium.org/${PN}/releases/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/23"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
+IUSE="+asm minimal static-libs +urandom cpu_flags_x86_sse4_1 cpu_flags_x86_aes"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.10-cpuflags.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local ECONF_SOURCE="${S}"
+	local myconf
+
+	# --disable-pie is needed on x86, see bug #512734
+	if [[ "${MULTILIB_ABI_FLAG}" == "abi_x86_32" ]]; then
+		myconf="${myconf} --disable-pie"
+	fi
+
+	econf \
+		$(use_enable asm) \
+		$(use_enable minimal) \
+		$(use_enable !urandom blocking-random) \
+		$(use_enable static-libs static) \
+		$(use_enable cpu_flags_x86_sse4_1 sse4_1) \
+		$(use_enable cpu_flags_x86_aes aesni) \
+		${myconf}
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name "*.la" -delete || die
+}