[gentoo-commits] repo/gentoo:master commit in: media-libs/libaom/

["Alexis Ballier" <aballier@gentoo.org>]

commit:     fa8ef6b1bdf230f75465f93ca90371abce5f2219
Author:     Alexis Ballier <aballier <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 22 13:40:06 2018 +0000
Commit:     Alexis Ballier <aballier <AT> gentoo <DOT> org>
CommitDate: Thu Feb 22 13:40:15 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa8ef6b1

media-libs/libaom: cleanup ebuild and convert to cmake.

Closes: https://bugs.gentoo.org/645142
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 media-libs/libaom/libaom-9999.ebuild | 128 ++++++++++++-----------------------
 1 file changed, 43 insertions(+), 85 deletions(-)

diff --git a/media-libs/libaom/libaom-9999.ebuild b/media-libs/libaom/libaom-9999.ebuild
index 4a8404db590..f940504046e 100644
--- a/media-libs/libaom/libaom-9999.ebuild
+++ b/media-libs/libaom/libaom-9999.ebuild
@@ -1,40 +1,33 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils multilib toolchain-funcs multilib-minimal
-
-LIBVPX_TESTDATA_VER=1.6.0
+EAPI=6
+inherit cmake-multilib
 
 if [[ ${PV} == *9999* ]]; then
-	inherit git-2
+	inherit git-r3
 	EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
 elif [[ ${PV} == *pre* ]]; then
 	SRC_URI="mirror://gentoo/${P}.tar.bz2"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+	KEYWORDS="~amd64"
 fi
-# generated by: make LIBVPX_TEST_DATA_PATH=libvpx-testdata testdata + tar'ing
-# it.
-#SRC_URI="${SRC_URI}
-#	test? ( mirror://gentoo/${PN}-testdata-${LIBVPX_TESTDATA_VER}.tar.bz2 )"
 
 DESCRIPTION="Alliance for Open Media AV1 Codec SDK"
 HOMEPAGE="http://aomedia.org"
 
-LICENSE="BSD"
-SLOT="0/4"
-IUSE="cpu_flags_x86_avx cpu_flags_x86_avx2 doc cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3 cpu_flags_x86_sse4_1 static-libs test +threads"
+LICENSE="BSD-2"
+SLOT="0/0"
+IUSE="doc examples"
+IUSE="${IUSE} cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3 cpu_flags_x86_sse4_1 cpu_flags_x86_avx cpu_flags_x86_avx2"
+IUSE="${IUSE} cpu_flags_arm_neon"
 
-RDEPEND="abi_x86_32? ( !app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+RDEPEND=""
 DEPEND="abi_x86_32? ( dev-lang/yasm )
 	abi_x86_64? ( dev-lang/yasm )
 	abi_x86_x32? ( dev-lang/yasm )
 	x86-fbsd? ( dev-lang/yasm )
 	amd64-fbsd? ( dev-lang/yasm )
-	doc? (
-		app-doc/doxygen
-		dev-lang/php
-	)
+	doc? ( app-doc/doxygen )
 "
 
 REQUIRED_USE="
@@ -42,75 +35,40 @@ REQUIRED_USE="
 	cpu_flags_x86_ssse3? ( cpu_flags_x86_sse2 )
 "
 
-#src_prepare() {
-#}
-
-multilib_src_configure() {
-	unset CODECS #357487
-
-	# let the build system decide which AS to use (it honours $AS but
-	# then feeds it with yasm flags without checking...) #345161
-	tc-export AS
-	case "${CHOST}" in
-		i?86*) export AS=yasm;;
-		x86_64*) export AS=yasm;;
-	esac
-
-	# https://bugs.gentoo.org/show_bug.cgi?id=384585
-	# https://bugs.gentoo.org/show_bug.cgi?id=465988
-	# copied from php-pear-r1.eclass
-	addpredict /usr/share/snmp/mibs/.index
-	addpredict /var/lib/net-snmp/
-	addpredict /var/lib/net-snmp/mib_indexes
-	addpredict /session_mm_cli0.sem
-
-	# Build with correct toolchain.
-	tc-export CC CXX AR NM
-	# Link with gcc by default, the build system should override this if needed.
-	export LD="${CC}"
-
-	local myconf
-	if [ "${ABI}" = "${DEFAULT_ABI}" ] ; then
-		myconf+=" $(use_enable doc install-docs) $(use_enable doc docs)"
-	else
-		# not needed for multilib and will be overwritten anyway.
-		myconf+=" --disable-examples --disable-install-docs --disable-docs"
-	fi
-
-	# #498364: sse doesn't work without sse2 enabled,
-	"${S}/configure" \
-		--prefix="${EPREFIX}"/usr \
-		--libdir="${EPREFIX}"/usr/$(get_libdir) \
-		--enable-pic \
-		--enable-av1 \
-		--enable-shared \
-		--extra-cflags="${CFLAGS}" \
-		$(use_enable cpu_flags_x86_avx avx) \
-		$(use_enable cpu_flags_x86_avx2 avx2) \
-		$(use_enable cpu_flags_x86_mmx mmx) \
-		$(use cpu_flags_x86_sse2 && use_enable cpu_flags_x86_sse sse || echo --disable-sse) \
-		$(use_enable cpu_flags_x86_sse2 sse2) \
-		$(use_enable cpu_flags_x86_sse3 sse3) \
-		$(use_enable cpu_flags_x86_sse4_1 sse4_1) \
-		$(use_enable cpu_flags_x86_ssse3 ssse3) \
-		$(use_enable static-libs static) \
-		$(use_enable test unit-tests) \
-		$(use_enable threads multithread) \
-		${myconf} \
-		|| die
+src_prepare() {
+	sed -e 's/lib"/lib${LIB_SUFFIX}"/' -i CMakeLists.txt || die
+	cmake-utils_src_prepare
 }
 
-multilib_src_compile() {
-	# build verbose by default and do not build examples that will not be installed
-	emake verbose=yes GEN_EXAMPLES=
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS=$(multilib_native_usex doc ON OFF)
+		-DENABLE_EXAMPLES=$(multilib_native_usex examples ON OFF)
+		-DENABLE_NASM=OFF
+		-DENABLE_TOOLS=ON
+		-DENABLE_WERROR=OFF
+
+		-DENABLE_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DENABLE_NEON_ASM=$(usex cpu_flags_arm_neon ON OFF)
+		# ENABLE_DSPR2 / ENABLE_MSA for mips
+		-DENABLE_MMX=$(usex cpu_flags_x86_mmx ON OFF)
+		-DENABLE_SSE=$(usex cpu_flags_x86_sse ON OFF)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)
+		-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)
+		-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)
+		-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1 ON OFF)
+		-DENABLE_AVX=$(usex cpu_flags_x86_avx ON OFF)
+		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2 ON OFF)
+
+		-DBUILD_SHARED_LIBS=ON
+	)
+	cmake-utils_src_configure
 }
 
-#multilib_src_test() {
-	#LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" \
-	#	emake verbose=yes GEN_EXAMPLES=  LIBVPX_TEST_DATA_PATH="${WORKDIR}/${PN}-testdata" test
-#}
-
 multilib_src_install() {
-	emake verbose=yes GEN_EXAMPLES= DESTDIR="${D}" install
-	[ "${ABI}" = "${DEFAULT_ABI}" ] && use doc && dohtml docs/html/*
+	cmake-utils_src_install
+	if multilib_is_native_abi && use doc ; then
+		docinto html
+		dodoc docs/html/*
+	fi
 }