From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1005054-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 42C901382C5
for <garchives@archives.gentoo.org>; Thu, 22 Feb 2018 10:27:45 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 76096E088C;
Thu, 22 Feb 2018 10:27:44 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 481AFE0882
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Feb 2018 10:27:44 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 30C52335C3E
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Feb 2018 10:27:43 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id BA74222D
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Feb 2018 10:27:41 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1519295253.8694b9f0926fec6a66323f848a40ca7eabcaefc7.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/smplayer/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-video/smplayer/Manifest media-video/smplayer/smplayer-18.2.2.ebuild
X-VCS-Directories: media-video/smplayer/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 8694b9f0926fec6a66323f848a40ca7eabcaefc7
X-VCS-Branch: master
Date: Thu, 22 Feb 2018 10:27:41 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: e2f46627-00d3-4a34-acf3-cc2393ed30e6
X-Archives-Hash: 3c54366369fa624cab7463e98678d4c6
commit: 8694b9f0926fec6a66323f848a40ca7eabcaefc7
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 22 10:18:34 2018 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Feb 22 10:27:33 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8694b9f0
media-video/smplayer: Bump to version 18.2.2
Package-Manager: Portage-2.3.24, Repoman-2.3.6
media-video/smplayer/Manifest | 1 +
media-video/smplayer/smplayer-18.2.2.ebuild | 133 ++++++++++++++++++++++++++++
2 files changed, 134 insertions(+)
diff --git a/media-video/smplayer/Manifest b/media-video/smplayer/Manifest
index d7cfd72dc20..74611611815 100644
--- a/media-video/smplayer/Manifest
+++ b/media-video/smplayer/Manifest
@@ -2,3 +2,4 @@ DIST smplayer-17.11.2.tar.bz2 5033433 BLAKE2B 0fa783172c5b3c68314d656a395db6c953
DIST smplayer-17.12.0.tar.bz2 5040463 BLAKE2B 6171cc0071e35c001678816464c55a9c16a5978ae4cae9a428c609e4940d0d0516e7d4928e961ca1e97469d77776c7e03f8c9a5c1c6ea3597c9724a2f6ea1ada SHA512 7b09ed08cf94f03eb4f992bc1a70ba938d081410044892e55236aec791732ec34bbdd31c6cbd05aa0eeb5cab6c0bf0a7b458373157ba49eed2c6a90e0ac257d1
DIST smplayer-18.1.0.tar.bz2 5033686 BLAKE2B e05a8044e725ddcd1a31c9209fe83abf03553d671570db0affabd55c28fa11ac7c81c853c5ac0ef7e9bb5b0d69e7924e2ef8a8f57fd07e2354b926b887c4cba8 SHA512 f0fb844634fbb22c975744cc4d557503aba7131cb52c5e1165a3ff9eec259bf45ebde5b7dfefa48d5f17e2946c1cfa0cce34429b373918f488e3f51c3398884e
DIST smplayer-18.2.0.tar.bz2 5033848 BLAKE2B 8996707609788f48b92868421d8feee14d267119e8980da57472735bbb66f9d63df20762295d2005e9a0cc572d2c04debff3f5e59ebd0c68b649b849b709df2a SHA512 43be64b82f77b223ef885b63b1bb3302b96cb93897cbf66df6272075bcfb76dbf11091526ae2b1bcde6845e25053a31456361fbd841a4dad8d229bacfab8bdb5
+DIST smplayer-18.2.2.tar.bz2 5037398 BLAKE2B f1f56885307e423488a75ba7a4421d199c060edcb878a3ef421af9cafbbbd3d451885c5209383f6935c4a5393c3985ac894531a139fa76d478414154038c7f13 SHA512 47ce8dd2b59f182e7826c5e7b8193111889441dc7d5145ed8c4df21137625cbe67da7a991d4121d41453127d1413535efbc0d6197d514a03885d652606610275
diff --git a/media-video/smplayer/smplayer-18.2.2.ebuild b/media-video/smplayer/smplayer-18.2.2.ebuild
new file mode 100644
index 00000000000..7c9ad23ef75
--- /dev/null
+++ b/media-video/smplayer/smplayer-18.2.2.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="am ar_SY ar bg ca cs da de el en_GB en en_US es et eu fa fi fr gl
+he_IL hr hu id it ja ka ko ku lt mk ms_MY nl nn_NO pl pt_BR pt ro_RO ru_RU
+sk sl_SI sq_AL sr sv th tr uk_UA uz vi_VN zh_CN zh_TW"
+PLOCALE_BACKUP="en_US"
+
+inherit gnome2-utils l10n qmake-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="Great Qt GUI front-end for mplayer/mpv"
+HOMEPAGE="http://www.smplayer.eu/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux"
+IUSE="autoshutdown bidi debug mpris"
+
+COMMON_DEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5=
+ dev-qt/qtnetwork:5[ssl]
+ dev-qt/qtscript:5
+ dev-qt/qtsingleapplication[X,qt5]
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ sys-libs/zlib
+ autoshutdown? ( dev-qt/qtdbus:5 )
+ mpris? ( dev-qt/qtdbus:5 )
+"
+DEPEND="${COMMON_DEPEND}
+ dev-qt/linguist-tools:5
+"
+RDEPEND="${COMMON_DEPEND}
+ || (
+ media-video/mplayer[bidi?,libass,png,X]
+ (
+ >=media-video/mpv-0.15.0[libass,X]
+ >=net-misc/youtube-dl-2014.11.26
+ )
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-14.9.0.6966-unbundle-qtsingleapplication.patch" # bug 487544
+ "${FILESDIR}/${PN}-17.1.0-advertisement_crap.patch"
+ "${FILESDIR}/${PN}-18.2.0-jobserver.patch"
+)
+
+src_prepare() {
+ use bidi || PATCHES+=( "${FILESDIR}"/${PN}-16.4.0-zero-bidi.patch )
+
+ default
+
+ # Upstream Makefile sucks
+ sed -i -e "/^PREFIX=/ s:/usr/local:${EPREFIX}/usr:" \
+ -e "/^DOC_PATH=/ s:packages/smplayer:${PF}:" \
+ -e '/\.\/get_svn_revision\.sh/,+2c\
+ cd src && $(DEFS) $(MAKE)' \
+ Makefile || die
+
+ # Turn off online update checker, bug #479902
+ sed -e 's:DEFINES += UPDATE_CHECKER:#&:' \
+ -e 's:DEFINES += CHECK_UPGRADED:#&:' \
+ -i src/smplayer.pro || die
+
+ # Turn off intrusive share widget
+ sed -e 's:DEFINES += SHARE_WIDGET:#&:' \
+ -i src/smplayer.pro || die
+
+ # Toggle autoshutdown option which pulls in dbus, bug #524392
+ if ! use autoshutdown ; then
+ sed -e 's:DEFINES += AUTO_SHUTDOWN_PC:#&:' \
+ -i src/smplayer.pro || die
+ fi
+
+ # Turn debug message flooding off
+ if ! use debug ; then
+ sed -e 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
+ -i src/smplayer.pro || die
+ fi
+
+ # MPRIS2 pulls in dbus, bug #553710
+ if ! use mpris ; then
+ sed -e 's:DEFINES += MPRIS2:#&:' \
+ -i src/smplayer.pro || die
+ fi
+
+ # Commented out because it gives false positives
+ #l10n_find_plocales_changes "${S}"/src/translations ${PN}_ .ts
+}
+
+src_configure() {
+ cd src || die
+ eqmake5
+}
+
+gen_translation() {
+ local mydir="$(qt5_get_bindir)"
+
+ ebegin "Generating $1 translation"
+ "${mydir}"/lrelease ${PN}_${1}.ts
+ eend $? || die "failed to generate $1 translation"
+}
+
+src_compile() {
+ emake CC="$(tc-getCC)"
+
+ cd src/translations || die
+ l10n_for_each_locale_do gen_translation
+}
+
+src_install() {
+ # remove unneeded copies of the GPL
+ rm -f Copying* docs/*/gpl.html || die
+ # don't install empty dirs
+ rmdir --ignore-fail-on-non-empty docs/* || die
+
+ default
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}