* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2016-08-12 19:33 Michael Orlitzky
0 siblings, 0 replies; 7+ messages in thread
From: Michael Orlitzky @ 2016-08-12 19:33 UTC (permalink / raw
To: gentoo-commits
commit: 85e49ca2398f187b8a60295fa531a11700cd9bf8
Author: Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 12 19:29:10 2016 +0000
Commit: Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Fri Aug 12 19:32:43 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=85e49ca2
media-tv/dvbstream: new revision respecting LDFLAGS.
This is a new revision with an update to EAPI=6 and a little ebuild
cleanup. Some missing die() statements were added, and some file
copying was avoided by using the newbin/newdoc helpers. Most
importantly, Michael Mair-Keimberger's fix to support LDFLAGS was
incorporated.
I built the package on amd64, so I've keyworded it ~amd64 as well.
Gentoo-Bug: 337327
Package-Manager: portage-2.2.28
.../dvbstream/dvbstream-0.7_pre20080516-r1.ebuild | 66 ++++++++++++++++++++++
1 file changed, 66 insertions(+)
diff --git a/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild b/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
new file mode 100644
index 0000000..93eae02
--- /dev/null
+++ b/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="RTP multicast stream server and other tools for DVB cards"
+HOMEPAGE="https://sourceforge.net/projects/dvbtools"
+MY_P="${PN}-snapshot-20080302"
+SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-lang/perl"
+DEPEND="virtual/linuxtv-dvb-headers"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+ "${FILESDIR}/${P}-update.diff"
+ "${FILESDIR}/${PN}-0.7_pre20080302-telnet-port-switch.diff"
+)
+
+src_prepare() {
+ default
+
+ sed -i Makefile \
+ -e 's:$(CFLAGS):$(CFLAGS) $(CPPFLAGS):' \
+ -e '/CFLAGS.*=.*-g -Wall -O2/s:-g -Wall -O2::' \
+ -e '/CFLAGS.*=/s:CFLAGS:CPPFLAGS:' \
+ -e 's:-I \.\./DVB/include:-I /usr/include:' \
+ -e 's:$(CC):$(CC) $(LDFLAGS):g' \
+ || die 'failed to fix flags in the Makefile'
+
+ sed -e 's:\./svdrpsend.pl:dvbstream-send.pl:' \
+ -i TELNET/*.sh \
+ || die 'failed to rename the svdrpsend.pl command in scripts'
+
+ sed -e 's:^DUMPRTP=.*$:DUMPRTP=dumprtp:' \
+ -e 's:^TS2ES=.*$:TS2ES=ts2es:' \
+ -i *.sh \
+ || die 'failed to set DUMPRTP and TS2ES in scripts'
+}
+
+src_compile() {
+ emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+ dobin dvbstream dumprtp rtpfeed ts_filter
+ newbin TELNET/svdrpsend.pl dvbstream-send.pl
+
+ dodoc README*
+ newdoc TELNET/README README.telnet
+
+ insinto "/usr/share/doc/${PF}/tune"
+ doins TELNET/*.sh
+
+ insinto "/usr/share/doc/${PF}/multicast"
+ doins *.sh
+}
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2018-02-14 13:50 Thomas Deutschmann
0 siblings, 0 replies; 7+ messages in thread
From: Thomas Deutschmann @ 2018-02-14 13:50 UTC (permalink / raw
To: gentoo-commits
commit: 84b1375f1157835ad7f184aaa9648a194deb229b
Author: Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 14 13:40:49 2018 +0000
Commit: Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Wed Feb 14 13:49:46 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84b1375f
media-tv/dvbstream: x86 stable (bug #647526)
Package-Manager: Portage-2.3.24, Repoman-2.3.6
media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild | 4 ++--
1 file changed, 2 insertions(+), 2 deletions(-)
diff --git a/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild b/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
index 376728afc3e..80b5df4b7c5 100644
--- a/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
+++ b/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
@@ -12,7 +12,7 @@ SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 x86"
IUSE=""
RDEPEND="dev-lang/perl"
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2018-02-22 9:14 Michael Palimaka
0 siblings, 0 replies; 7+ messages in thread
From: Michael Palimaka @ 2018-02-22 9:14 UTC (permalink / raw
To: gentoo-commits
commit: ddae8be287bc50862d931922d10398045be0209a
Author: Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 22 09:11:49 2018 +0000
Commit: Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Thu Feb 22 09:14:12 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ddae8be2
media-tv/dvbstream: remove 0.7_pre20080516-r0
Package-Manager: Portage-2.3.19, Repoman-2.3.6
.../dvbstream/dvbstream-0.7_pre20080516.ebuild | 60 ----------------------
1 file changed, 60 deletions(-)
diff --git a/media-tv/dvbstream/dvbstream-0.7_pre20080516.ebuild b/media-tv/dvbstream/dvbstream-0.7_pre20080516.ebuild
deleted file mode 100644
index 2c784607dcc..00000000000
--- a/media-tv/dvbstream/dvbstream-0.7_pre20080516.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-inherit eutils
-
-IUSE=""
-
-DESCRIPTION="simple command line tools for DVB cards. Includes a RTP multicast stream server"
-HOMEPAGE="https://sourceforge.net/projects/dvbtools"
-
-#SRC_URI="mirror://sourceforge/dvbtools/${P}.tar.gz"
-#MY_P=${PN}-snapshot-${PV##*_pre}
-MY_P=${PN}-snapshot-20080302
-SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
-
-S="${WORKDIR}/${PN}"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="x86"
-
-RDEPEND="dev-lang/perl"
-DEPEND="virtual/linuxtv-dvb-headers"
-
-src_unpack() {
- unpack ${A}
-
- cd "${S}"
- epatch "${FILESDIR}/${P}-update.diff"
- epatch "${FILESDIR}/${PN}-0.7_pre20080302-telnet-port-switch.diff"
-
- cd "${S}"
- sed -i Makefile \
- -e 's:$(CFLAGS):$(CFLAGS) $(CPPFLAGS):' \
- -e '/CFLAGS.*=.*-g -Wall -O2/s:-g -Wall -O2::' \
- -e '/CFLAGS.*=/s:CFLAGS:CPPFLAGS:' \
- -e 's:-I \.\./DVB/include:-I /usr/include:'
-
- cp TELNET/svdrpsend.pl dvbstream-send.pl
- cp TELNET/README README.telnet
-
- sed -e 's:\./svdrpsend.pl:dvbstream-send.pl:' \
- -i TELNET/*.sh
-
- sed -e 's:^DUMPRTP=.*$:DUMPRTP=dumprtp:' \
- -e 's:^TS2ES=.*$:TS2ES=ts2es:' \
- -i *.sh
-}
-
-src_install() {
- dobin dvbstream dumprtp rtpfeed ts_filter dvbstream-send.pl
-
- dodoc README*
-
- insinto /usr/share/doc/${PF}/tune
- doins TELNET/*.sh
-
- insinto /usr/share/doc/${PF}/multicast
- doins *.sh
-}
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2024-06-20 20:08 Arthur Zamarin
0 siblings, 0 replies; 7+ messages in thread
From: Arthur Zamarin @ 2024-06-20 20:08 UTC (permalink / raw
To: gentoo-commits
commit: f96f969f7691f00bc21fc3890ea18d0657254721
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 20 20:07:44 2024 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 20:08:32 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f96f969f
media-tv/dvbstream: add 0.8.2
Closes: https://bugs.gentoo.org/879033
Closes: https://bugs.gentoo.org/919183
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
media-tv/dvbstream/Manifest | 1 +
media-tv/dvbstream/dvbstream-0.8.2.ebuild | 61 +++++++++++++++++++++++++++++++
2 files changed, 62 insertions(+)
diff --git a/media-tv/dvbstream/Manifest b/media-tv/dvbstream/Manifest
index 9390f2d260c4..01376f0a2645 100644
--- a/media-tv/dvbstream/Manifest
+++ b/media-tv/dvbstream/Manifest
@@ -1 +1,2 @@
+DIST dvbstream-0.8.2.tar.bz2 60542 BLAKE2B c2e57c9e94cf4b359025e1607e827a1e23330d2caa0ce0788b7366501df66781775a6e4cc3ac4ed670f619ce53b60cf970156257944c3baf1f344ee830ece307 SHA512 06d6fc6c62ee898726b240164a8f9cdd7f2a61dd148db052a6f37c3cf174ef9f3f886c1eafcc3e249fdc9fee057790efbc3baccf71dd6cad98b3fef06a2b7c9a
DIST dvbstream-snapshot-20080302.tar.bz2 58089 BLAKE2B 9dd2fdd5e1dfa3741554b84cd5361697cef16b0ecba6ee5a8a2890959678dfc1497e54003d9b5ebb9e0092e5f3e71a4b5786a2c2e224d31a9243ecaafeea98e1 SHA512 7116310435584b61c51f642d38cfdbbdf706df27448af7824b5a050e374ad72d3d08c2eb03de0d5ed6ec1cb15461e3be90ee8bd3b045b6ba858b5896c5546671
diff --git a/media-tv/dvbstream/dvbstream-0.8.2.ebuild b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
new file mode 100644
index 000000000000..d84aea3032e4
--- /dev/null
+++ b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="RTP multicast stream server and other tools for DVB cards"
+HOMEPAGE="https://www.orcas.net/dvbstream/"
+SRC_URI="http://www.orcas.net/dvbstream/${P}.tar.bz2"
+S=${WORKDIR}/${PN}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-lang/perl"
+BDEPEND="sys-kernel/linux-headers"
+
+src_prepare() {
+ default
+
+ sed -i Makefile \
+ -e 's:$(CFLAGS):$(CFLAGS) $(CPPFLAGS):' \
+ -e '/CFLAGS.*=.*-g -Wall -O2/s:-g -Wall -O2::' \
+ -e '/CFLAGS.*=/s:CFLAGS:CPPFLAGS:' \
+ -e 's:-I \.\./DVB/include:-I /usr/include:' \
+ -e 's:$(CC):$(CC) $(LDFLAGS):g' \
+ || die 'failed to fix flags in the Makefile'
+
+ sed -e 's:\./svdrpsend.pl:dvbstream-send.pl:' \
+ -i TELNET/*.sh \
+ || die 'failed to rename the svdrpsend.pl command in scripts'
+
+ # bug 919183
+ sed -e '/#include "ringbuffy.h"/a #include <string.h>' \
+ -i mpegtools/ringbuffy.c || die 'failed to fix ringbuffy.c'
+
+ sed -e "s:-lcurses:$( $(tc-getPKG_CONFIG) --libs ncurses ):" \
+ -i Makefile || die 'failed to fix ncurses linking in Makefile'
+
+ sed -e 's:^DUMPRTP=.*$:DUMPRTP=dumprtp:' -i *.sh || die 'failed to set DUMPRTP and TS2ES in scripts'
+}
+
+src_compile() {
+ emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+ dobin dvbstream dumprtp rtpfeed ts_filter
+ newbin TELNET/svdrpsend.pl dvbstream-send.pl
+
+ dodoc README*
+ newdoc TELNET/README README.telnet
+
+ insinto "/usr/share/doc/${PF}/tune"
+ doins TELNET/*.sh
+
+ insinto "/usr/share/doc/${PF}/multicast"
+ doins *.sh
+}
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2024-07-05 13:57 Arthur Zamarin
0 siblings, 0 replies; 7+ messages in thread
From: Arthur Zamarin @ 2024-07-05 13:57 UTC (permalink / raw
To: gentoo-commits
commit: f4c7a7bac582bb828276fe70703df617bf53469f
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 5 13:57:54 2024 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 5 13:57:54 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f4c7a7ba
media-tv/dvbstream: Stabilize 0.8.2 amd64, #935546
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
media-tv/dvbstream/dvbstream-0.8.2.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/media-tv/dvbstream/dvbstream-0.8.2.ebuild b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
index d84aea3032e4..86d2221c55aa 100644
--- a/media-tv/dvbstream/dvbstream-0.8.2.ebuild
+++ b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
@@ -12,7 +12,7 @@ S=${WORKDIR}/${PN}
LICENSE="GPL-2"
SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
RDEPEND="dev-lang/perl"
BDEPEND="sys-kernel/linux-headers"
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2024-07-05 13:57 Arthur Zamarin
0 siblings, 0 replies; 7+ messages in thread
From: Arthur Zamarin @ 2024-07-05 13:57 UTC (permalink / raw
To: gentoo-commits
commit: 33b2d17cad72832255de9c65ba1a6a33fd22330d
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 5 13:57:55 2024 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 5 13:57:55 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33b2d17c
media-tv/dvbstream: Stabilize 0.8.2 x86, #935546
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
media-tv/dvbstream/dvbstream-0.8.2.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/media-tv/dvbstream/dvbstream-0.8.2.ebuild b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
index 86d2221c55aa..30868a4e4dea 100644
--- a/media-tv/dvbstream/dvbstream-0.8.2.ebuild
+++ b/media-tv/dvbstream/dvbstream-0.8.2.ebuild
@@ -12,7 +12,7 @@ S=${WORKDIR}/${PN}
LICENSE="GPL-2"
SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
RDEPEND="dev-lang/perl"
BDEPEND="sys-kernel/linux-headers"
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/
@ 2024-07-05 13:58 Arthur Zamarin
0 siblings, 0 replies; 7+ messages in thread
From: Arthur Zamarin @ 2024-07-05 13:58 UTC (permalink / raw
To: gentoo-commits
commit: e2eda316ea0ad7b06c01d6255fbe0fd3174333ee
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 5 13:58:16 2024 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 5 13:58:16 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e2eda316
media-tv/dvbstream: drop 0.7_pre20080516-r1
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
media-tv/dvbstream/Manifest | 1 -
.../dvbstream/dvbstream-0.7_pre20080516-r1.ebuild | 64 ----------------------
2 files changed, 65 deletions(-)
diff --git a/media-tv/dvbstream/Manifest b/media-tv/dvbstream/Manifest
index 01376f0a2645..e42ddb94526a 100644
--- a/media-tv/dvbstream/Manifest
+++ b/media-tv/dvbstream/Manifest
@@ -1,2 +1 @@
DIST dvbstream-0.8.2.tar.bz2 60542 BLAKE2B c2e57c9e94cf4b359025e1607e827a1e23330d2caa0ce0788b7366501df66781775a6e4cc3ac4ed670f619ce53b60cf970156257944c3baf1f344ee830ece307 SHA512 06d6fc6c62ee898726b240164a8f9cdd7f2a61dd148db052a6f37c3cf174ef9f3f886c1eafcc3e249fdc9fee057790efbc3baccf71dd6cad98b3fef06a2b7c9a
-DIST dvbstream-snapshot-20080302.tar.bz2 58089 BLAKE2B 9dd2fdd5e1dfa3741554b84cd5361697cef16b0ecba6ee5a8a2890959678dfc1497e54003d9b5ebb9e0092e5f3e71a4b5786a2c2e224d31a9243ecaafeea98e1 SHA512 7116310435584b61c51f642d38cfdbbdf706df27448af7824b5a050e374ad72d3d08c2eb03de0d5ed6ec1cb15461e3be90ee8bd3b045b6ba858b5896c5546671
diff --git a/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild b/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
deleted file mode 100644
index 9dfe663f071a..000000000000
--- a/media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit toolchain-funcs
-
-DESCRIPTION="RTP multicast stream server and other tools for DVB cards"
-HOMEPAGE="https://sourceforge.net/projects/dvbtools"
-MY_P="${PN}-snapshot-20080302"
-SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-RDEPEND="dev-lang/perl"
-DEPEND="sys-kernel/linux-headers"
-
-S="${WORKDIR}/${PN}"
-
-PATCHES=(
- "${FILESDIR}/${P}-update.diff"
- "${FILESDIR}/${PN}-0.7_pre20080302-telnet-port-switch.diff"
-)
-
-src_prepare() {
- default
-
- sed -i Makefile \
- -e 's:$(CFLAGS):$(CFLAGS) $(CPPFLAGS):' \
- -e '/CFLAGS.*=.*-g -Wall -O2/s:-g -Wall -O2::' \
- -e '/CFLAGS.*=/s:CFLAGS:CPPFLAGS:' \
- -e 's:-I \.\./DVB/include:-I /usr/include:' \
- -e 's:$(CC):$(CC) $(LDFLAGS):g' \
- || die 'failed to fix flags in the Makefile'
-
- sed -e 's:\./svdrpsend.pl:dvbstream-send.pl:' \
- -i TELNET/*.sh \
- || die 'failed to rename the svdrpsend.pl command in scripts'
-
- sed -e 's:^DUMPRTP=.*$:DUMPRTP=dumprtp:' \
- -e 's:^TS2ES=.*$:TS2ES=ts2es:' \
- -i *.sh \
- || die 'failed to set DUMPRTP and TS2ES in scripts'
-}
-
-src_compile() {
- emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
-}
-
-src_install() {
- dobin dvbstream dumprtp rtpfeed ts_filter
- newbin TELNET/svdrpsend.pl dvbstream-send.pl
-
- dodoc README*
- newdoc TELNET/README README.telnet
-
- insinto "/usr/share/doc/${PF}/tune"
- doins TELNET/*.sh
-
- insinto "/usr/share/doc/${PF}/multicast"
- doins *.sh
-}
^ permalink raw reply related [flat|nested] 7+ messages in thread
end of thread, other threads:[~2024-07-05 13:58 UTC | newest]
Thread overview: 7+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2018-02-22 9:14 [gentoo-commits] repo/gentoo:master commit in: media-tv/dvbstream/ Michael Palimaka
-- strict thread matches above, loose matches on Subject: below --
2024-07-05 13:58 Arthur Zamarin
2024-07-05 13:57 Arthur Zamarin
2024-07-05 13:57 Arthur Zamarin
2024-06-20 20:08 Arthur Zamarin
2018-02-14 13:50 Thomas Deutschmann
2016-08-12 19:33 Michael Orlitzky
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox