[gentoo-commits] repo/gentoo:master commit in: sci-biology/phylip/

["Sergei Trofimovich" <slyfox@gentoo.org>]

commit:     0c014a7762f9b51e602420690a6388d33aefce01
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 15 23:22:45 2018 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Thu Feb 15 23:23:15 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c014a77

sci-biology/phylip: block against dev-lang/elixir, bug #537514

Reported-by: Toralf Förster
Bug: https://bugs.gentoo.org/537514
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 sci-biology/phylip/phylip-3.696-r2.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/sci-biology/phylip/phylip-3.696-r2.ebuild b/sci-biology/phylip/phylip-3.696-r2.ebuild
new file mode 100644
index 00000000000..c19085ed6cf
--- /dev/null
+++ b/sci-biology/phylip/phylip-3.696-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit toolchain-funcs
+
+DESCRIPTION=" The PHYLogeny Inference Package"
+HOMEPAGE="http://evolution.genetics.washington.edu/phylip.html"
+SRC_URI="http://evolution.gs.washington.edu/${PN}/download/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD-2"
+IUSE=""
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+# 'mix' tool collides with dev-lang/elixir, bug #537514
+RDEPEND="x11-libs/libXaw
+	!!dev-lang/elixir"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S="${WORKDIR}/${P}/src"
+
+src_prepare() {
+	mv Makefile.unx Makefile || die
+	sed \
+		-e "/ -o /s:\(\$(CC)\):\1 ${LDFLAGS}:g" \
+		-i Makefile || die "Patching Makefile failed."
+	mkdir ../fonts || die
+}
+
+src_compile() {
+	emake -j1 \
+		CC="$(tc-getCC)" \
+		DC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS} -Wno-unused-result" \
+		all put
+}
+
+src_install() {
+	cd "${WORKDIR}/${P}" || die
+
+	mv exe/font* fonts || die "Font move failed."
+	mv exe/factor exe/factor-${PN} || die "Renaming factor failed."
+
+	dolib.so exe/*so && rm exe/*so || die
+	dobin exe/*
+
+	dodoc "${FILESDIR}"/README.Gentoo
+
+	dohtml -r phylip.html doc
+
+	insinto /usr/share/${PN}/
+	doins -r fonts
+}