* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2017-07-30 19:32 Patrice Clement
0 siblings, 0 replies; 10+ messages in thread
From: Patrice Clement @ 2017-07-30 19:32 UTC (permalink / raw
To: gentoo-commits
commit: c2d33f25daa628eccf403e8322c3eb9d7b77a0fb
Author: Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 30 19:31:59 2017 +0000
Commit: Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Sun Jul 30 19:32:13 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c2d33f25
dev-util/global: version bump.
This commit also bumps the ebuild to EAPI version 6.
Gentoo-Bug: https://bugs.gentoo.org/543908
Package-Manager: Portage-2.3.6, Repoman-2.3.1
dev-util/global/Manifest | 1 +
dev-util/global/global-6.5.7.ebuild | 96 +++++++++++++++++++++++++++++++++++++
2 files changed, 97 insertions(+)
diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index 9505a07851c..ccc74805124 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1 +1,2 @@
DIST global-6.3.1.tar.gz 1369634 SHA256 fb10668ef1a2f63d0730564a36ecae7716aed89c09cc5896cd8c579be4ebae6c SHA512 83becd6cda06f8da17ea0c701bb135523ff48cec73b233d24566387d11a35c0b42f410b62753838e2b364a5a485cac033b4aef1159cc6f4cdeca4a7b6c5bb4d6 WHIRLPOOL 1321e131b267f842b68561f04155c06dc11b0adfe177e83113b1884eb629d8e27844de6421c1613efd2ad7472d51140deb5360a6ad78fd25f50844426314de5c
+DIST global-6.5.7.tar.gz 2940567 SHA256 d9c08fa524f9499b54241cb2d72f8a7df01453b6d5e012a63784ded08e3acd32 SHA512 0d33f718839e5e00bdd6d042b415a69c5e1f232d843610870505f8f20635b445810149b1b84ea8b77881f5f64814783ebe3cdcab2f84b8a085223b64293a9045 WHIRLPOOL 0c32bc466652a87661c21bcaee2f2a1b5eee7b3bff5e8f763bd3b1c159daea10c1e3c0f092109d9b92112258f52e88a7bed7eb58923a592013d400b7d6727f4d
diff --git a/dev-util/global/global-6.5.7.ebuild b/dev-util/global/global-6.5.7.ebuild
new file mode 100644
index 00000000000..3d6e4cfa2ed
--- /dev/null
+++ b/dev-util/global/global-6.5.7.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune elisp-common
+
+DESCRIPTION="tag system to find an object location in various sources"
+HOMEPAGE="https://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="doc emacs vim"
+
+RDEPEND="
+ sys-libs/ncurses
+ emacs? ( virtual/emacs )
+ vim? ( || (
+ app-editors/vim
+ app-editors/gvim
+ )
+ )
+ || (
+ dev-libs/libltdl:0
+ sys-devel/libtool:2
+ )"
+
+DEPEND="${DEPEND}
+ doc? (
+ app-text/texi2html
+ sys-apps/texinfo
+ )"
+
+SITEFILE="50gtags-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-6.2.9-tinfo.patch" )
+
+DOCS=( AUTHORS FAQ NEWS README THANKS )
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+ if use doc; then
+ texi2pdf -q -o doc/global.pdf doc/global.texi
+ texi2html -o doc/global.html doc/global.texi
+ fi
+
+ if use emacs; then
+ elisp-compile *.el
+ fi
+
+ emake
+}
+
+src_install() {
+ default
+
+ insinto /etc
+ doins gtags.conf
+
+ if use vim; then
+ insinto /usr/share/vim/vimfiles/plugin
+ doins gtags.vim
+ fi
+
+ if use emacs; then
+ elisp-install ${PN} *.{el,elc}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+
+ if use doc; then
+ # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+ [[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
+ fi
+
+ einstalldocs
+ prune_libtool_files
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2017-12-02 12:52 David Seifert
0 siblings, 0 replies; 10+ messages in thread
From: David Seifert @ 2017-12-02 12:52 UTC (permalink / raw
To: gentoo-commits
commit: 95abfee1907527c524c611a9bb4849209fbba46e
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 2 12:51:38 2017 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Dec 2 12:51:38 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=95abfee1
dev-util/global: [QA] Fix DESCRIPTION.toolong
dev-util/global/global-6.3.1.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/dev-util/global/global-6.3.1.ebuild b/dev-util/global/global-6.3.1.ebuild
index dcefb9fac0a..eb062c9e9b8 100644
--- a/dev-util/global/global-6.3.1.ebuild
+++ b/dev-util/global/global-6.3.1.ebuild
@@ -5,7 +5,7 @@ EAPI="5"
inherit autotools elisp-common eutils
-DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources"
+DESCRIPTION="tag system to find an object location in various sources"
HOMEPAGE="https://www.gnu.org/software/global/global.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2018-02-11 10:53 Michał Górny
0 siblings, 0 replies; 10+ messages in thread
From: Michał Górny @ 2018-02-11 10:53 UTC (permalink / raw
To: gentoo-commits
commit: 3f4f49ecef10946401fee7133716d741c3ece20d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 11 10:46:50 2018 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb 11 10:51:48 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3f4f49ec
dev-util/global: Remove useless maintainer <description/>
Remove useless/redundant maintainer <description/>. It does not benefit
bug wrangling, and only wastes developer's time on reading it. Few tips:
- assignee/CC is implied by ordering, there is no reason to repeat it,
- we know that maintainer is maintainer (la la la la la),
- most of adjectives for maintainer are of no value and/or are obvious.
dev-util/global/metadata.xml | 1 -
1 file changed, 1 deletion(-)
diff --git a/dev-util/global/metadata.xml b/dev-util/global/metadata.xml
index 6a4aed9a8e5..b8ecaba5d8e 100644
--- a/dev-util/global/metadata.xml
+++ b/dev-util/global/metadata.xml
@@ -6,7 +6,6 @@
</maintainer>
<maintainer type="person">
<email>arfrever.fta@gmail.com</email>
- <description>Proxy maintainer</description>
</maintainer>
<maintainer type="project">
<email>proxy-maint@gentoo.org</email>
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2019-12-31 2:40 Naohiro Aota
0 siblings, 0 replies; 10+ messages in thread
From: Naohiro Aota @ 2019-12-31 2:40 UTC (permalink / raw
To: gentoo-commits
commit: 1dfb69d80745eb29ff5a506702eac5d8f9885d28
Author: Naohiro Aota <naota <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 31 02:12:09 2019 +0000
Commit: Naohiro Aota <naota <AT> gentoo <DOT> org>
CommitDate: Tue Dec 31 02:18:21 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1dfb69d8
dev-util/global: version bump
Closes: https://bugs.gentoo.org/701376
Signed-off-by: Naohiro Aota <naota <AT> gentoo.org>
dev-util/global/Manifest | 1 +
dev-util/global/global-6.6.4.ebuild | 96 +++++++++++++++++++++++++++++++++++++
2 files changed, 97 insertions(+)
diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index dca545d4d39..902af58d5dc 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1,2 +1,3 @@
DIST global-6.3.1.tar.gz 1369634 BLAKE2B 8d93222ccbb4a45c0b9f114cd84b342b3f6ab99f7e0bbc18bfe00912ecd53f606be9d32fce1570e027009fd1fbe4752f03dd19c183dfda438d67a329808a6b45 SHA512 83becd6cda06f8da17ea0c701bb135523ff48cec73b233d24566387d11a35c0b42f410b62753838e2b364a5a485cac033b4aef1159cc6f4cdeca4a7b6c5bb4d6
DIST global-6.5.7.tar.gz 2940567 BLAKE2B e0c692e09f9f7ea64ecbe47e18691efd3c641f28826e19751fb812690cd9d64a53af03055de9ec8199637da46dbd6084fec16380d7f295c83ed77553a8e301fd SHA512 0d33f718839e5e00bdd6d042b415a69c5e1f232d843610870505f8f20635b445810149b1b84ea8b77881f5f64814783ebe3cdcab2f84b8a085223b64293a9045
+DIST global-6.6.4.tar.gz 2988969 BLAKE2B 784087537094d27c10d1f2bc992e799c35ab6ce3b86e041c31279e6954b203e80676b3158ba95e7957456b75a213d70998aae9047836cd4d388212236f05a081 SHA512 cb4ed451d3aaf47c4c59cdc3f74c97d3171108177d4846b5dac843589710e66d87c9d7bbe080c3770329e8e40105ac52dcafb4609257347593cca4d94711f483
diff --git a/dev-util/global/global-6.6.4.ebuild b/dev-util/global/global-6.6.4.ebuild
new file mode 100644
index 00000000000..e45daf3d4f7
--- /dev/null
+++ b/dev-util/global/global-6.6.4.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools elisp-common
+
+DESCRIPTION="tag system to find an object location in various sources"
+HOMEPAGE="https://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc emacs vim"
+
+RDEPEND="
+ sys-libs/ncurses
+ emacs? ( >=app-editors/emacs-23.1:* )
+ vim? ( || (
+ app-editors/vim
+ app-editors/gvim
+ )
+ )
+ || (
+ dev-libs/libltdl:0
+ sys-devel/libtool:2
+ )"
+
+DEPEND="${DEPEND}
+ doc? (
+ app-text/texi2html
+ sys-apps/texinfo
+ )"
+
+SITEFILE="50gtags-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-6.2.9-tinfo.patch" )
+
+DOCS=( AUTHORS FAQ NEWS README THANKS )
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+ if use doc; then
+ texi2pdf -q -o doc/global.pdf doc/global.texi
+ texi2html -o doc/global.html doc/global.texi
+ fi
+
+ if use emacs; then
+ elisp-compile *.el
+ fi
+
+ emake
+}
+
+src_install() {
+ default
+
+ insinto /etc
+ doins gtags.conf
+
+ if use vim; then
+ insinto /usr/share/vim/vimfiles/plugin
+ doins gtags.vim
+ fi
+
+ if use emacs; then
+ elisp-install ${PN} *.{el,elc}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+
+ if use doc; then
+ # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+ [[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
+ fi
+
+ einstalldocs
+ find "${ED}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2020-08-01 8:53 Sergei Trofimovich
0 siblings, 0 replies; 10+ messages in thread
From: Sergei Trofimovich @ 2020-08-01 8:53 UTC (permalink / raw
To: gentoo-commits
commit: 0fe6ac0dc8a6f082482d213f8661a71810ab5645
Author: Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 1 08:46:26 2020 +0000
Commit: Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sat Aug 1 08:46:26 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0fe6ac0d
dev-util/global: stable 6.6.4 for ppc
stable wrt bug #646348
Package-Manager: Portage-3.0.1, Repoman-2.3.23
RepoMan-Options: --include-arches="ppc"
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>
dev-util/global/global-6.6.4.ebuild | 4 ++--
1 file changed, 2 insertions(+), 2 deletions(-)
diff --git a/dev-util/global/global-6.6.4.ebuild b/dev-util/global/global-6.6.4.ebuild
index e45daf3d4f7..eaa110afce6 100644
--- a/dev-util/global/global-6.6.4.ebuild
+++ b/dev-util/global/global-6.6.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
@@ -11,7 +11,7 @@ SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
+KEYWORDS="~amd64 ppc ~x86"
IUSE="doc emacs vim"
RDEPEND="
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2020-09-09 16:01 Sam James
0 siblings, 0 replies; 10+ messages in thread
From: Sam James @ 2020-09-09 16:01 UTC (permalink / raw
To: gentoo-commits
commit: 76c1cf9aa7fd7da4311612199fd09ed9caff0290
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 9 16:01:36 2020 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Sep 9 16:01:36 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=76c1cf9a
dev-util/global: security cleanup
Bug: https://bugs.gentoo.org/646348
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/global/Manifest | 2 -
dev-util/global/global-6.3.1.ebuild | 81 -------------------------------
dev-util/global/global-6.5.7.ebuild | 96 -------------------------------------
3 files changed, 179 deletions(-)
diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index 902af58d5dc..40b667bfa42 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1,3 +1 @@
-DIST global-6.3.1.tar.gz 1369634 BLAKE2B 8d93222ccbb4a45c0b9f114cd84b342b3f6ab99f7e0bbc18bfe00912ecd53f606be9d32fce1570e027009fd1fbe4752f03dd19c183dfda438d67a329808a6b45 SHA512 83becd6cda06f8da17ea0c701bb135523ff48cec73b233d24566387d11a35c0b42f410b62753838e2b364a5a485cac033b4aef1159cc6f4cdeca4a7b6c5bb4d6
-DIST global-6.5.7.tar.gz 2940567 BLAKE2B e0c692e09f9f7ea64ecbe47e18691efd3c641f28826e19751fb812690cd9d64a53af03055de9ec8199637da46dbd6084fec16380d7f295c83ed77553a8e301fd SHA512 0d33f718839e5e00bdd6d042b415a69c5e1f232d843610870505f8f20635b445810149b1b84ea8b77881f5f64814783ebe3cdcab2f84b8a085223b64293a9045
DIST global-6.6.4.tar.gz 2988969 BLAKE2B 784087537094d27c10d1f2bc992e799c35ab6ce3b86e041c31279e6954b203e80676b3158ba95e7957456b75a213d70998aae9047836cd4d388212236f05a081 SHA512 cb4ed451d3aaf47c4c59cdc3f74c97d3171108177d4846b5dac843589710e66d87c9d7bbe080c3770329e8e40105ac52dcafb4609257347593cca4d94711f483
diff --git a/dev-util/global/global-6.3.1.ebuild b/dev-util/global/global-6.3.1.ebuild
deleted file mode 100644
index 9d48ee787d8..00000000000
--- a/dev-util/global/global-6.3.1.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="5"
-
-inherit autotools elisp-common eutils ltprune
-
-DESCRIPTION="tag system to find an object location in various sources"
-HOMEPAGE="https://www.gnu.org/software/global/global.html"
-SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 ppc x86"
-IUSE="doc emacs vim"
-
-RDEPEND="|| ( dev-libs/libltdl:0 sys-devel/libtool:2 )
- sys-libs/ncurses
- emacs? ( >=app-editors/emacs-23.1:* )
- vim? ( || ( app-editors/vim app-editors/gvim ) )"
-DEPEND="${DEPEND}
- doc? ( app-text/texi2html sys-apps/texinfo )"
-
-SITEFILE="50gtags-gentoo.el"
-
-src_prepare() {
- epatch "${FILESDIR}/${PN}-6.2.9-tinfo.patch"
- eautoreconf
-}
-
-src_configure() {
- econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
-}
-
-src_compile() {
- if use doc; then
- texi2pdf -q -o doc/global.pdf doc/global.texi
- texi2html -o doc/global.html doc/global.texi
- fi
-
- if use emacs; then
- elisp-compile *.el
- fi
-
- emake
-}
-
-src_install() {
- emake DESTDIR="${D}" install
-
- if use doc; then
- dohtml doc/global.html
- # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
- [[ -f doc/global.pdf ]] && dodoc doc/global.pdf
- fi
-
- dodoc AUTHORS FAQ NEWS README THANKS
-
- insinto /etc
- doins gtags.conf
-
- if use vim; then
- insinto /usr/share/vim/vimfiles/plugin
- doins gtags.vim
- fi
-
- if use emacs; then
- elisp-install ${PN} *.{el,elc}
- elisp-site-file-install "${FILESDIR}/${SITEFILE}"
- fi
-
- prune_libtool_files
-}
-
-pkg_postinst() {
- use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
- use emacs && elisp-site-regen
-}
diff --git a/dev-util/global/global-6.5.7.ebuild b/dev-util/global/global-6.5.7.ebuild
deleted file mode 100644
index 2b19aa0f759..00000000000
--- a/dev-util/global/global-6.5.7.ebuild
+++ /dev/null
@@ -1,96 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools ltprune elisp-common
-
-DESCRIPTION="tag system to find an object location in various sources"
-HOMEPAGE="https://www.gnu.org/software/global/global.html"
-SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE="doc emacs vim"
-
-RDEPEND="
- sys-libs/ncurses
- emacs? ( >=app-editors/emacs-23.1:* )
- vim? ( || (
- app-editors/vim
- app-editors/gvim
- )
- )
- || (
- dev-libs/libltdl:0
- sys-devel/libtool:2
- )"
-
-DEPEND="${DEPEND}
- doc? (
- app-text/texi2html
- sys-apps/texinfo
- )"
-
-SITEFILE="50gtags-gentoo.el"
-
-PATCHES=( "${FILESDIR}/${PN}-6.2.9-tinfo.patch" )
-
-DOCS=( AUTHORS FAQ NEWS README THANKS )
-
-src_prepare() {
- default
- eautoreconf
-}
-
-src_configure() {
- econf \
- "$(use_with emacs lispdir "${SITELISP}/${PN}")"
-}
-
-src_compile() {
- if use doc; then
- texi2pdf -q -o doc/global.pdf doc/global.texi
- texi2html -o doc/global.html doc/global.texi
- fi
-
- if use emacs; then
- elisp-compile *.el
- fi
-
- emake
-}
-
-src_install() {
- default
-
- insinto /etc
- doins gtags.conf
-
- if use vim; then
- insinto /usr/share/vim/vimfiles/plugin
- doins gtags.vim
- fi
-
- if use emacs; then
- elisp-install ${PN} *.{el,elc}
- elisp-site-file-install "${FILESDIR}/${SITEFILE}"
- fi
-
- if use doc; then
- # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
- [[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
- fi
-
- einstalldocs
- prune_libtool_files
-}
-
-pkg_postinst() {
- use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
- use emacs && elisp-site-regen
-}
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2023-07-06 2:11 Sam James
0 siblings, 0 replies; 10+ messages in thread
From: Sam James @ 2023-07-06 2:11 UTC (permalink / raw
To: gentoo-commits
commit: 89e944eed5e50d90cf7802d345c97c2de1016999
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 6 01:57:52 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jul 6 01:57:52 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89e944ee
dev-util/global: add 6.6.10
Closes: https://bugs.gentoo.org/763039
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/global/Manifest | 1 +
dev-util/global/global-6.6.10.ebuild | 101 +++++++++++++++++++++++++++++++++++
2 files changed, 102 insertions(+)
diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index 40b667bfa42e..859a5626f707 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1 +1,2 @@
+DIST global-6.6.10.tar.gz 2999863 BLAKE2B 496bac144c935893b29e23bbb1fa4583a5d6d0ab1b8cd818ff592d7259bb6fa832d79666703f2ac179b5fd39095fd922b8861ad73879c5bac299f9b785797c0b SHA512 babbba6a8dc701b401a12d9961cb7510983e44c7f80836d6d0da165fd0d8cc695e20b7c241526839aef2a70c8bbf97727d910ff17c37751ba3438267139b45d1
DIST global-6.6.4.tar.gz 2988969 BLAKE2B 784087537094d27c10d1f2bc992e799c35ab6ce3b86e041c31279e6954b203e80676b3158ba95e7957456b75a213d70998aae9047836cd4d388212236f05a081 SHA512 cb4ed451d3aaf47c4c59cdc3f74c97d3171108177d4846b5dac843589710e66d87c9d7bbe080c3770329e8e40105ac52dcafb4609257347593cca4d94711f483
diff --git a/dev-util/global/global-6.6.10.ebuild b/dev-util/global/global-6.6.10.ebuild
new file mode 100644
index 000000000000..41abd9d57503
--- /dev/null
+++ b/dev-util/global/global-6.6.10.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+inherit autotools elisp-common python-single-r1
+
+DESCRIPTION="Tag system to find an object location in various sources"
+HOMEPAGE="https://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc emacs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ dev-libs/libltdl
+ dev-db/sqlite
+ sys-libs/ncurses
+ $(python_gen_cond_dep '
+ dev-python/pygments[${PYTHON_USEDEP}]
+ ')
+ emacs? ( >=app-editors/emacs-23.1:* )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ doc? (
+ app-text/texi2html
+ sys-apps/texinfo
+ )
+"
+
+SITEFILE="50gtags-gentoo.el"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-6.2.9-tinfo.patch"
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --with-python-interpreter="${PYTHON}"
+ --with-sqlite3 # avoid using bundled copy
+ $(use_with emacs lispdir "${SITELISP}/${PN}")
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ if use doc; then
+ texi2pdf -q -o doc/global.pdf doc/global.texi || die
+ texi2html -o doc/global.html doc/global.texi || die
+ fi
+
+ if use emacs; then
+ elisp-compile *.el
+ fi
+
+ emake
+}
+
+src_install() {
+ default
+
+ rm -rf "${ED}"/var/lib || die
+
+ insinto /etc
+ doins gtags.conf
+
+ insinto /usr/share/vim/vimfiles/plugin
+ doins gtags.vim
+
+ if use emacs; then
+ elisp-install ${PN} *.{el,elc}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+
+ if use doc; then
+ # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+ [[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
+ fi
+
+ find "${ED}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2023-07-06 4:02 Sam James
0 siblings, 0 replies; 10+ messages in thread
From: Sam James @ 2023-07-06 4:02 UTC (permalink / raw
To: gentoo-commits
commit: 0a79f1772f6549343c6dca87d506782df7fb81ce
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 6 04:01:32 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jul 6 04:01:32 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a79f177
dev-util/global: fix licence
Closes: https://bugs.gentoo.org/881595
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/global/global-6.6.10.ebuild | 2 +-
dev-util/global/global-6.6.4.ebuild | 4 ++--
2 files changed, 3 insertions(+), 3 deletions(-)
diff --git a/dev-util/global/global-6.6.10.ebuild b/dev-util/global/global-6.6.10.ebuild
index 41abd9d57503..ba1e95a1d864 100644
--- a/dev-util/global/global-6.6.10.ebuild
+++ b/dev-util/global/global-6.6.10.ebuild
@@ -10,7 +10,7 @@ DESCRIPTION="Tag system to find an object location in various sources"
HOMEPAGE="https://www.gnu.org/software/global/global.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-LICENSE="GPL-3"
+LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc emacs"
diff --git a/dev-util/global/global-6.6.4.ebuild b/dev-util/global/global-6.6.4.ebuild
index 1343cfa448b5..661f50f612f1 100644
--- a/dev-util/global/global-6.6.4.ebuild
+++ b/dev-util/global/global-6.6.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
@@ -9,7 +9,7 @@ DESCRIPTION="tag system to find an object location in various sources"
HOMEPAGE="https://www.gnu.org/software/global/global.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-LICENSE="GPL-3"
+LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="doc emacs vim"
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2023-07-06 6:54 Sam James
0 siblings, 0 replies; 10+ messages in thread
From: Sam James @ 2023-07-06 6:54 UTC (permalink / raw
To: gentoo-commits
commit: 9015629fc3c1fc54239015b430d997ec8871d7cc
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 6 06:49:46 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jul 6 06:54:33 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9015629f
dev-util/global: add texlive-core dep
Closes: https://bugs.gentoo.org/909751
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/global/global-6.6.10.ebuild | 1 +
1 file changed, 1 insertion(+)
diff --git a/dev-util/global/global-6.6.10.ebuild b/dev-util/global/global-6.6.10.ebuild
index ba1e95a1d864..a26d05c4474f 100644
--- a/dev-util/global/global-6.6.10.ebuild
+++ b/dev-util/global/global-6.6.10.ebuild
@@ -30,6 +30,7 @@ DEPEND="${RDEPEND}"
BDEPEND="
doc? (
app-text/texi2html
+ app-text/texlive-core
sys-apps/texinfo
)
"
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-util/global/
@ 2024-07-30 8:49 Pacho Ramos
0 siblings, 0 replies; 10+ messages in thread
From: Pacho Ramos @ 2024-07-30 8:49 UTC (permalink / raw
To: gentoo-commits
commit: 12726351846f2027d8486882ed3dd9b2f6fe54e3
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 30 08:14:38 2024 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 30 08:48:01 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=12726351
dev-util/global: add 6.6.13
Closes: https://bugs.gentoo.org/929542
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
dev-util/global/Manifest | 1 +
dev-util/global/global-6.6.13.ebuild | 102 +++++++++++++++++++++++++++++++++++
2 files changed, 103 insertions(+)
diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index 859a5626f707..21699ebae4ab 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1,2 +1,3 @@
DIST global-6.6.10.tar.gz 2999863 BLAKE2B 496bac144c935893b29e23bbb1fa4583a5d6d0ab1b8cd818ff592d7259bb6fa832d79666703f2ac179b5fd39095fd922b8861ad73879c5bac299f9b785797c0b SHA512 babbba6a8dc701b401a12d9961cb7510983e44c7f80836d6d0da165fd0d8cc695e20b7c241526839aef2a70c8bbf97727d910ff17c37751ba3438267139b45d1
+DIST global-6.6.13.tar.gz 3003671 BLAKE2B 476c918bad8f6d246ef6b50bcccdee9040ced2b529737e55cd5daa62d2b96d9f5073e1a48d98fe2ec0c2da68b1fb557b0f0f7d7d25eba8c5c5d784dda7b29cb1 SHA512 072d10a6911cef3bf66b5cf17e101f9c1ff29c993bf7db4c99164e5c1b18b4e3ddec31962c77beea2685cb116330919abb9b226d472d0003949a91286d0f1b6d
DIST global-6.6.4.tar.gz 2988969 BLAKE2B 784087537094d27c10d1f2bc992e799c35ab6ce3b86e041c31279e6954b203e80676b3158ba95e7957456b75a213d70998aae9047836cd4d388212236f05a081 SHA512 cb4ed451d3aaf47c4c59cdc3f74c97d3171108177d4846b5dac843589710e66d87c9d7bbe080c3770329e8e40105ac52dcafb4609257347593cca4d94711f483
diff --git a/dev-util/global/global-6.6.13.ebuild b/dev-util/global/global-6.6.13.ebuild
new file mode 100644
index 000000000000..3307ec39c98c
--- /dev/null
+++ b/dev-util/global/global-6.6.13.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit autotools elisp-common python-single-r1
+
+DESCRIPTION="Tag system to find an object location in various sources"
+HOMEPAGE="https://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc emacs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ dev-libs/libltdl
+ dev-db/sqlite
+ sys-libs/ncurses
+ $(python_gen_cond_dep '
+ dev-python/pygments[${PYTHON_USEDEP}]
+ ')
+ emacs? ( >=app-editors/emacs-23.1:* )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ doc? (
+ app-text/texi2html
+ app-text/texlive-core
+ sys-apps/texinfo
+ )
+"
+
+SITEFILE="50gtags-gentoo.el"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-6.2.9-tinfo.patch"
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --with-python-interpreter="${PYTHON}"
+ --with-sqlite3 # avoid using bundled copy
+ $(use_with emacs lispdir "${SITELISP}/${PN}")
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ if use doc; then
+ texi2pdf -q -o doc/global.pdf doc/global.texi || die
+ texi2html -o doc/global.html doc/global.texi || die
+ fi
+
+ if use emacs; then
+ elisp-compile *.el
+ fi
+
+ emake
+}
+
+src_install() {
+ default
+
+ rm -rf "${ED}"/var/lib || die
+
+ insinto /etc
+ doins gtags.conf
+
+ insinto /usr/share/vim/vimfiles/plugin
+ doins gtags.vim
+
+ if use emacs; then
+ elisp-install ${PN} *.{el,elc}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+
+ if use doc; then
+ # doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+ [[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
+ fi
+
+ find "${ED}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
^ permalink raw reply related [flat|nested] 10+ messages in thread
end of thread, other threads:[~2024-07-30 8:50 UTC | newest]
Thread overview: 10+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2018-02-11 10:53 [gentoo-commits] repo/gentoo:master commit in: dev-util/global/ Michał Górny
-- strict thread matches above, loose matches on Subject: below --
2024-07-30 8:49 Pacho Ramos
2023-07-06 6:54 Sam James
2023-07-06 4:02 Sam James
2023-07-06 2:11 Sam James
2020-09-09 16:01 Sam James
2020-08-01 8:53 Sergei Trofimovich
2019-12-31 2:40 Naohiro Aota
2017-12-02 12:52 David Seifert
2017-07-30 19:32 Patrice Clement
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox