[gentoo-commits] proj/gnome:master commit in: net-libs/glib-networking/

["Sobhan Mohammadpour" <sobhan@gentoo.org>]

commit:     6e39185fa12ced96fa6dc3c77a8fe5d272a6ae57
Author:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  6 16:13:05 2018 +0000
Commit:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
CommitDate: Tue Feb  6 16:13:05 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=6e39185f

net-libs/glib-networking: bump

Package-Manager: Portage-2.3.23, Repoman-2.3.6
RepoMan-Options: --force
Manifest-Sign-Key: 0x7DF238CF0AA182E1

 .../glib-networking/glib-networking-2.54.1.ebuild  | 83 ++++++++++++++++++++++
 net-libs/glib-networking/metadata.xml              | 12 ++++
 2 files changed, 95 insertions(+)

diff --git a/net-libs/glib-networking/glib-networking-2.54.1.ebuild b/net-libs/glib-networking/glib-networking-2.54.1.ebuild
new file mode 100644
index 00000000..7eb7f3e2
--- /dev/null
+++ b/net-libs/glib-networking/glib-networking-2.54.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 multilib-minimal virtualx
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://git.gnome.org/browse/glib-networking/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="+gnome +libproxy smartcard +ssl test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.46.0:2[${MULTILIB_USEDEP}]
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
+	smartcard? (
+		>=app-crypt/p11-kit-0.18.4[${MULTILIB_USEDEP}]
+		>=net-libs/gnutls-3:=[pkcs11,${MULTILIB_USEDEP}] )
+	ssl? (
+		app-misc/ca-certificates
+		>=net-libs/gnutls-3:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.19.4
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus[X] )
+"
+# eautoreconf needs >=sys-devel/autoconf-2.65:2.5
+
+src_prepare() {
+	default
+	# Disable SSLv3 requiring fallback test, which fails with net-libs/gnutls[-sslv3], bug 595952
+	# https://bugzilla.gnome.org/show_bug.cgi?id=782853
+	sed -i -e '/\/tls\/connection\/fallback\/SSL/d' "${S}"/tls/tests/connection.c || die
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-static \
+		--with-ca-certificates="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		$(use_with gnome gnome-proxy) \
+		$(use_with libproxy) \
+		$(use_with smartcard pkcs11) \
+		$(use_with ssl gnutls)
+}
+
+multilib_src_test() {
+	# XXX: non-native tests fail if glib-networking is already installed.
+	# have no idea what's wrong. would appreciate some help.
+	multilib_is_native_abi || return 0
+
+	virtx emake check
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	multilib_pkg_postrm() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postrm
+}

diff --git a/net-libs/glib-networking/metadata.xml b/net-libs/glib-networking/metadata.xml
new file mode 100644
index 00000000..a1db58db
--- /dev/null
+++ b/net-libs/glib-networking/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+	<use>
+		<flag name="libproxy">Use <pkg>net-libs/libproxy</pkg> for getting the HTTP/HTTPS/SOCKS proxy configuration</flag>
+		<flag name="gnome">Extract HTTP/HTTPS/SOCKS proxy configuration stored using GSettings</flag>
+	</use>
+</pkgmetadata>